equivalent to cut -f1-3,5 in awk - awk

Question

I want fields 1,2,3,5
With cut I do:
cut -f1-3,5
However with awk I would do:
awk '{for (i=0;i<=5;i++) {if (i!=4) {print $i}} }'
But I want to make it more succinct. Moreover, in other cases I could have more fields with varying distances. awk '{for (i in 1 2 3 5) {print $i}}' doesn't work. How can I do this

Answer 1

For the job of picking fields by position number and field ranges etc cut does the job better. If you really want to mimic this behavior in awk assuming you have other tasks to do in awk as well, you may consider following code:
cat fcut.awk
BEGIN {
n = split(f, a, /,/)
for (i=1; i<=n; ++i) {
if (split(a[i], b, /-/) == 2) {
for (j=b[1]; j<=b[2]; ++j)
fld[j]
}
else
fld[a[i]]
}
}
{
for (i=1; i<=NF; ++i) {
if (i in fld)
s = (st++ ? s OFS : "") $i
}
print s
s = st = ""
}
Now run it as:
awk -v f='1-3,5' -f fcut.awk file

Answer 2

This does what cut does and a bit more:
$ echo 'a b c d e f g' |
awk -v ranges='1-3,5' '
BEGIN {
split(ranges,r,/,/)
for ( i=1; i in r; i++ ) {
n = split(r[i],range,/-/)
for ( j=range[1]; j<=range[n]; j++ ) {
f[++onf] = j
}
}
}
{
for ( i=1; i<=onf; i++ ) {
printf "%s%s", $(f[i]), (i<onf ? OFS : ORS)
}
}
'
a b c e
The above assumes if you specify the same field number multiple times then you want it printed that many times, and you want the fields printed in the order you specify so you can, for example, rearrange order and/or duplicate fields, e.g.:
$ echo 'a b c d e f g' |
awk -v ranges='6,1-3,5,2,1' '
BEGIN {
split(ranges,r,/,/)
for ( i=1; i in r; i++ ) {
n = split(r[i],range,/-/)
for ( j=range[1]; j<=range[n]; j++ ) {
f[++onf] = j
}
}
}
{
for ( i=1; i<=onf; i++ ) {
printf "%s%s", $(f[i]), (i<onf ? OFS : ORS)
}
}
'
f a b c e b a