I want To generate all category button - vb.net

Question

I have this pos system i want to generate All category button and display All product list in the FlowLayoutPanel
Private Sub FrmPos_Load(sender As Object, e As EventArgs) Handles MyBase.Load
'Connection()
LoadCategory()
LoadMenu()
Me.KeyPreview = True
End Sub
this code for LoadCategory()
Sub LoadCategory()
cn.Open()
cm = New SqlCommand("Select * From TblCategory", cn)
dr = cm.ExecuteReader
While dr.Read
BtnCategory = New Button
BtnCategory.Width = 100
BtnCategory.Height = 35
BtnCategory.Text = dr.Item("Category").ToString
BtnCategory.FlatStyle = FlatStyle.Flat
BtnCategory.BackColor = Color.FromArgb(55, 176, 213)
BtnCategory.ForeColor = Color.White
BtnCategory.Cursor = Cursors.Hand
BtnCategory.TextAlign = ContentAlignment.MiddleLeft
FlowLayoutPanel1.Controls.Add(BtnCategory)
AddHandler BtnCategory.Click, AddressOf filter_click
End While
dr.Close()
cn.Close()
End Sub
this code for filter_click
Public Sub filter_click(sender As Object, e As EventArgs)
If LblTransNo.Text = String.Empty Then
MsgBox("Click New Order first!", vbCritical)
Return
End If
_filter = sender.text.ToString
LoadMenu()
End Sub

Answer 1

You have 2 different things going on in the LoadCategory method. I moved the database code to a separate method.
Connections, Commands, and DataReaders all need to be disposed. These objects need to be declared locally in Using blocks. They provide a Dispose method where they release unmanaged resources. Using...End Using blocks will call Dispose for you and close the object even if there is an error.
You don't want to hold a connection open while you build your buttons and interact with the user interface. It appears that you are only using a single field called Category. Don't pull down all the fields with Select *. Just return the data you need to use.
Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
LoadFlowPanel()
LoadMenu()
Me.KeyPreview = True
End Sub
Private OPConStr As String = "Your connection string."
Private Function GetCategoryData() As DataTable
Dim dt As New DataTable
Using cn As New SqlConnection(ConStr),
cmd As New SqlCommand("Select Category From TblCategory;", cn)
cn.Open()
Using dr = cmd.ExecuteReader
dt.Load(dr)
End Using
End Using
Return dt
End Function
Private Sub LoadFlowPanel()
Dim dt = GetCategoryData()
Dim BtnAll As New Button
With BtnAll
.Width = 100
.Height = 35
.Text = "All"
.FlatStyle = FlatStyle.Flat
.BackColor = Color.FromArgb(55, 176, 213)
.ForeColor = Color.White
.Cursor = Cursors.Hand
.TextAlign = ContentAlignment.MiddleLeft
End With
FlowLayoutPanel1.Controls.Add(BtnAll)
AddHandler BtnAll.Click, AddressOf filter_click
For Each row As DataRow In dt.Rows
Dim BtnCategory = New Button
With BtnCategory
.Width = 100
.Height = 35
.Text = row("Category").ToString
.FlatStyle = FlatStyle.Flat
.BackColor = Color.FromArgb(55, 176, 213)
.ForeColor = Color.White
.Cursor = Cursors.Hand
.TextAlign = ContentAlignment.MiddleLeft
End With
FlowLayoutPanel1.Controls.Add(BtnCategory)
AddHandler BtnCategory.Click, AddressOf filter_click
Next
End Sub