Move NDR messages to a folder not in the inbox - vba

Question

I want to move NDR messages to a folder which is not in the inbox.
I found working code online which moves the NDRs but not where I want it. I assume that the problem is with the path:
Set Folders = Session.GetDefaultFolder(olFolderInbox).Folders
Set Folder = Folders.Item("NDR")
How can I move the NDRs to the "nem_kezbesitheto" subfolder in "x_spam"?
Outlook folder structure
Private WithEvents Items As Outlook.Items
Private Sub Application_Startup()
Set Items = Session.GetDefaultFolder(olFolderInbox).Items
End Sub
Private Sub Items_ItemAdd(ByVal Item As Object)
On Error Resume Next
If UCase(Item.MessageClass) = "REPORT.IPM.NOTE.NDR" Then
Set Folders = Session.GetDefaultFolder(olFolderInbox).Folders
Set Folder = Folders.Item("NDR")
If Folder Is Nothing Then
Folder = Folders.Add("NDR")
End If
Item.Move Folder
End If
End Sub

Answer 1

It seems the target folder is located in a separate store. Use the NameSpace.Stores property which returns a Stores collection object that represents all the Store objects in the current profile. For example:
Sub EnumerateFoldersInStores()
Dim colStores As Outlook.Stores
Dim oStore As Outlook.Store
Dim oRoot As Outlook.Folder
On Error Resume Next
Set colStores = Application.Session.Stores
For Each oStore In colStores
Set oRoot = oStore.GetRootFolder
Debug.Print (oRoot.FolderPath)
EnumerateFolders oRoot
Next
End Sub
Private Sub EnumerateFolders(ByVal oFolder As Outlook.Folder)
Dim folders As Outlook.folders
Dim Folder As Outlook.Folder
Dim foldercount As Integer
On Error Resume Next
Set folders = oFolder.folders
foldercount = folders.Count
'Check if there are any folders below oFolder
If foldercount Then
For Each Folder In folders
Debug.Print (Folder.FolderPath)
EnumerateFolders Folder
Next
End If
End Sub
So, instead of using the following line of code:
Session.GetDefaultFolder(olFolderInbox).Folders
You will have to use the following one:
Store.GetDefaultFolder(olFolderInbox).Folders
Where the store object represents the target store. You will have to find it using the Stores collection returned from the corresponding property of the Namespace class.

Answer 2

Navigate the folder tree from the top level Session to "nem_kezbesitheto".
It looks like x_spam is at the mailbox level. If not adjust to step from Session to mailbox to folder to folder to folder, one at a time.
Option Explicit ' Consider this mandatory
' Tools | Options | Editor tab
' Require Variable Declaration
' If desperate declare as Variant
Private WithEvents Items As Items
Private Sub Application_Startup()
Set Items = Session.GetDefaultFolder(olFolderInbox).Items
End Sub
Private Sub Items_ItemAdd(ByVal Item As Object)
Dim x_spamMailbox As folder
Dim myFolder As folder
If UCase(Item.MessageClass) = "REPORT.IPM.NOTE.NDR" Then
'Navigate the folder tree
' Assuming x_spam is at the mailbox level
Set x_spamMailbox = Session.folders("x_spam")
' Step from mailbox to folder (to folder to folder as needed)
Set myFolder = x_spamMailbox.folders("nem_kezbesitheto")
Item.Move myFolder
End If
End Sub