VB.NET Deserialize XML sub nodes by attribute text - vb.net

Question

Trying to deserialize an XML file but having trouble with sub nodes.
I need to collect these by there ID value eg ConNum, class, recid.
Currently I can get one value back but it's giving me the name of the ID and not the value.
eg: xData.TRAN_DATEX.theTarget = ConNum where I require 20190910 instead.
Here's the XML:
<?xml version="1.0" encoding="UTF-8"?>
<targets>
<target id="ConNum">20190910</target>
<target id="class">Third</target>
<target id="recid">123 </target>
</targets>
Here's my class:
Imports System.Xml.Serialization
<Serializable, XmlRoot("targets")>
Public Class XmlFile
<XmlElement("target")> Public Property TRAN_DATEX As myTarget
End Class
<Serializable, XmlRoot("target")>
Public Class myTarget
<XmlAttribute("id")> Public theTarget As String
End Class
And here is the deserialize method:
Dim fFile As FileInfo = New FileInfo("C:\Temp\TARGETS.metadata")
Dim s As New XmlSerializer(GetType(XmlFile))
Using sr As New StreamReader(fFile.FullName)
xData = s.Deserialize(sr)
Stop
End Using

Answer 1

theTarget is getting the value of the id attribute. You want the XmlText of that element:
<Serializable, XmlRoot("target")>
Public Class myTarget
<XmlAttribute("id")> Public theTarget As String
<XmlText> Public Property theValue As String
End Class
Then, instead of xData.TRAN_DATEX.theTarget, you can use xData.TRAN_DATEX.theValue
Edit: In response to the comment.
As there are multiple <target> elements, TRAN_DATEX will need to be a list:
<Serializable, XmlRoot("targets")>
Public Class XmlFile
<XmlElement("target")> Public Property TRAN_DATEX As New List(Of myTarget)
End Class
LINQ can be used to access the data that is required:
Dim reqValueTarget = xData.TRAN_DATEX.FirstOrDefault(Function(x) x.theTarget = "ConNum")
If reqValueTarget IsNot Nothing then
Dim reqValue = reqValueTarget.theValue
End If