How to convert text to date and sum to time by vba? - vba

Question

how are you? Look, I am opening a tab-delimited file which contains information about the day and the time when a sample was analysed. I'd like to sum time and date, in a way that would be possible to sort lines based on this information.
Time and date are stored as strings, in two different cells, just like:
Date: 29/11/2013
13:41:59:546
Because of this, I had to create a formula to remove "Date: " and to convert ":546" to milliseconds and add to the rest of the number. Unfortunately, even removing "Date: ", I can't convert "29/11/2013" to a number, considering that date is interpreted as a number by excel. It's interesting because with the workbook opened, if I select the cell with 29/11/2013 (after "Date: " being removed) and press F2, then enter, excel converts it to a number. Am I missing something when I am trying to do the same by vba?
My result should be a number that with the appropriate format
.numberformat="dd/mm/yyyy hh:mm:ss.000"
should show 29/11/2013 13:41:59.546.
My function is:
Function DateTimeCustomFormat(TimeCell As Range, DateCell As Range, formatTime As String, formatDate As String)
Dim ms As Double 'Means milliseconds
Dim msTOday As Long 'Factor to convert ms to day (ms divided by all milliseconds in a day)
msTOday = 86400000
Select Case formatTime
Case "hh:mm:ss:ms(xxx)"
ms = Val(Right(TimeCell, 3)) / msTOday
TimeCell = Left(TimeCell, Len(TimeCell) - 4)
TimeCell.NumberFormat = "0.00" '"h:mm:ss.000"
TimeCell = TimeCell + ms
End Select
Select Case formatDate
Case "Date: dd/mm/yyyy"
DateCell = Right(DateCell, Len(DateCell) - 6)
DateCell.NumberFormat = "dd:mm:aaaa"
'DateCell = DateCell.Value * 1
End Select
DateTimeCustomFormat = TimeCell + DateCell
End Function

Answer 1

Seems as if you not really familiar with object datatypes such as Range and with what can a user defined function do and what not.
In your code you get the parameter TimeCell as Range but then you overwrite this with a string (TimeCell = Left(TimeCell, Len(TimeCell) - 4)) and then you try setting NumberFormat to this. A string has no NumberFormat ;-). Furthermore a user defined function cannot set NumberFormat to cells and it also cannot set cell values, if this was the goal of the above code line. It only can return a value. This value gets then the value of the cell, which contains the user defined function as a formula.
Same Problem with DateCell.
Your code should get the parts of the cell values which represents the time or the date as strings and then convert them to dates. Therefor some functions are useable.
Easy to use are TimeValue and DateValue. But these functions depend on the system settings for date and time format. So it may be that they don't get the right values. For the date for example with "06/07/2014" is not really clear if it is July the 06. or June the 07. This depends on the system date format settings.
A more general solution is to use TimeSerial and DateSerial. This is the better solution in my opinion because the formates are precisely defined.
Function DateTimeCustomFormat(TimeCell As Range, DateCell As Range, formatTime As String, formatDate As String) As Date
Dim ms As Double 'Means milliseconds
Dim msTOday As Long 'Factor to convert ms to day (ms divided by all milliseconds in a day)
Dim sTime As String, sDate As String 'String parts of the given parameters
Dim dTime As Date, dDate As Date 'Calculated datetime values of the given parameters
msTOday = 86400000
Select Case formatTime
Case "hh:mm:ss:ms(xxx)"
ms = Val(Right(TimeCell.Value, 3)) / msTOday
sTime = Left(TimeCell.Value, Len(TimeCell.Value) - 4)
'dTime = TimeValue(sTime) + ms 'please read help for TimeValue
dTime = TimeSerial(Left(sTime, 2), Mid(sTime, 4, 2), Mid(sTime, 7, 2)) + ms
Case Else
dTime = 0
End Select
Select Case formatDate
Case "Date: dd/mm/yyyy"
sDate = Right(DateCell.Value, Len(DateCell.Value) - 6)
'dDate = DateValue(sDate) 'please read help for DateValue
dDate = DateSerial(Right(sDate, 4), Mid(sDate, 4, 2), Left(sDate, 2))
Case Else
dDate = 0
End Select
DateTimeCustomFormat = dTime + dDate
End Function
Using as a UDF (user defined function):