PL/SQL DEVELOPER 10.2 create triggers [closed] - sql

Question

Closed. This question does not meet Stack Overflow guidelines. It is not currently accepting answers.
This question does not appear to be about programming within the scope defined in the help center.
Closed 8 years ago.
Improve this question
create or replace trigger TDB_TRIGGER1
before insert on KTOVOT
for each row
declare
begin
insert into TEMPORARY_DATA(MIS_ZEHUT,TA_RISHUM, SHEM_TAVLA)
values(:new.id, sysdate, user_tables.table_name);
end TDB_TRIGGER1
I get this error:
PL/SQL: ORA-00984: column not allowed here
What I want to do here is to write into table:
TEMPORARY_DATA mis_zehut, ta_rishum, user_tables.table_name
I want to write the table name ktovot to the third field of table TEMPORARY_DATA with no success.
If I do it hardcoded it will work:
values(:new.id, sysdate, 'ktovot' );

Answer 1

PL/SQL does not support reflection - or rather it supports an extremely limited level of reflection. Nothing like Java. But we can find out the name of the current program unit using the $$PLSQL_UNIT inquiry directive. Find out more.
Triggers are program units, so we can find out the name of the currently executing trigger. And with that piece of information we can look up the name of the table which owns the trigger:
create or replace function get_table_name
( i_trigger_name in varchar2)
return varchar2
is
return_value varchar2(30);
begin
select table_name
into return_value
from user_triggers
where trigger_name = i_trigger_name;
return return_value;
end;
/
So, here is a journal table:
create table jrnl1 (id number
, action varchar2(20)
, ts timestamp
, table_name varchar2(30));
Here is a trigger to populate that journal, getting the table name dynamically:
create or replace trigger t23_trg
before insert on t23 for each row
begin
insert into jrnl1 values
(:new.id
, 'INSERT'
, systimestamp
, get_table_name($$PLSQL_UNIT));
end;
/
And here is the proof of the pudding:
SQL> select * from jrnl1;
no rows selected
SQL> insert into t23 values ('TEST', 42);
1 row created.
SQL> select * from jrnl1;
ID ACTION TS TABLE_NAME
---------- -------- ---------------------------- ------------------------------
42 INSERT 17-AUG-14 10.14.30.688672 AM T23
SQL>
I'm afraid it's not the elegant solution you might have hoped for. And in fact, given that you have to write a separate trigger for each table I'm not sure it saves you much in the way of hard-coding.
But I think it makes an interesting toy which serves to illustrate how PL/SQL works.