Using "is default" with Hash of Arrays - raku

Question

Here is the working example:
my %hash;
for 1..4 -> $i {
%hash{$i} = Array.new without %hash{$i};
%hash{$i}.push: $_ for ^$i;
}
say %hash; # OUTPUT: {1 => [0], 2 => [0 1], 3 => [0 1 2], 4 => [0 1 2 3]}
But why the next similar example doesn't work?
my %hash is default(Array.new);
for 1..4 -> $i {
%hash{$i}.push: $_ for ^$i;
}
say %hash; # OUTPUT: {}
This even more confuses me, because the next example works as expected:
my %hash is default(42);
for 1..4 -> $i {
%hash{$i}.=Str;
}
say %hash.raku; # OUTPUT: {"1" => "42", "2" => "42", "3" => "42", "4" => "42"}

Answer 1

It's not immediately clear to me why the result of the second example is an empty hash, however using is default like this is not going to work as you wish. Traits are applied at compile time; thus is default(Array.new), even if it worked correctly, would create a single Array instance at compile time, and reuse it globally. So the output I'd expect is something like:
1 => [0 0 1 0 1 2 0 1 2 3], 2 => [0 0 1 0 1 2 0 1 2 3], 3 => [0 0 1 0 1 2 0 1 2 3], 4 => [0 0 1 0 1 2 0 1 2 3]}
That it doesn't give this is probably a bug.
However, thanks to auto-vivification, the first example can be reduced to:
my %hash;
for 1..4 -> $i {
%hash{$i}.push: $_ for ^$i;
}
say %hash; # {1 => [0], 2 => [0 1], 3 => [0 1 2], 4 => [0 1 2 3]}
The array is created automatically when doing an array operation on an undefined value anyway, thus meaning there's no use for is default in this kind of situation.