Conducting Calculation on Selected Task's Custom Field Upon Change Event - vba

Question

I am wondering whether it is possible to create a script that runs a calculation for a selected task's field after a change event. I currently have a script that runs calculations for every task in my ms project file. I want to move away from this method by implementing code that isolates a task and computes a respective value.
Can someone please let me know if this is possible?
I do not have a bock of code at the moment because I have been struggling on where to start. I have referenced this thread (Microsoft Project VBA to update Custom field on task change) but have not been able to implement it with success.
My cm_Events class module:
Public WithEvents MyMSPApp As MSProject.Application
Private Sub Class_Initialize()
Set MyMSPApp = Application
End Sub
Private Sub MyMSPApp_ProjectBeforeAssignmentChange(ByVal Assgn As Assignment, ByVal Field As PjField, ByVal NewVal As Variant, Cancel As Boolean)
If EnableEvents Then
EnableEvents = False
Dim X As Integer
X = 5
Debug.Print X
EnableEvents = True
End If
End Sub
My m_Events Module:
Public oMSPEvents As New cm_Events
Public EnableEvents As Boolean
Sub StartEvents()
Set oMSPEvents.MyMSPApp = Application ' MSProject.Application
EnableEvents = True
End Sub
My Project Code Block:
Private Sub Project_Open(ByVal pj As Project)
Call m_Events.StartEvents
End Sub
What I Would Place Into Before Assignment Change Script:
tsk.Cost5 = 0
Dim Assgn As Assignment
For Each Assgn In tsk.Assignments
If Assgn.Resource.Text1 = "Labor" Then
tsk.Cost5 = tsk.Cost5 + Assgn.Cost
Assgn.Cost5 = Assgn.Cost5 + Assgn.Cost
End If
Next Assgn

Answer 1

This code will track costs for Labor resources using the Cost5 field and will update automatically when either the task or the assignment is updated, using the respective event handlers.
For the cm_Events class module:
Option Explicit
Public WithEvents MyMSPApp As MSProject.Application
Private Sub Class_Initialize()
Set MyMSPApp = Application
End Sub
Private Sub MyMSPApp_ProjectBeforeAssignmentChange(ByVal asg As Assignment, ByVal Field As PjAssignmentField, ByVal NewVal As Variant, Cancel As Boolean)
If EnableEvents Then
EnableEvents = False
Dim tsk As Task
Set tsk = asg.Task
tsk.Cost5 = 0
UpdateCost5 tsk
EnableEvents = True
End If
End Sub
Private Sub MyMSPApp_ProjectBeforeTaskChange(ByVal tsk As Task, ByVal Field As PjField, ByVal NewVal As Variant, Cancel As Boolean)
If EnableEvents Then
EnableEvents = False
tsk.Cost5 = 0
UpdateCost5 tsk
EnableEvents = True
End If
End Sub
Private Sub UpdateCost5(tsk As Task)
tsk.Cost5 = 0
Dim Assgn As Assignment
For Each Assgn In tsk.Assignments
If Assgn.Resource.Text1 = "Labor" Then
tsk.Cost5 = tsk.Cost5 + Assgn.Cost
Assgn.Cost5 = Assgn.Cost
Else
Assgn.Cost5 = 0
End If
Next Assgn
End Sub
For the m_Events module:
Public oMSPEvents As New cm_Events
Public EnableEvents As Boolean
Sub StartEvents()
Set oMSPEvents.MyMSPApp = Application ' MSProject.Application
EnableEvents = True
End Sub
For the ThisProject module:
Private Sub Project_Open(ByVal pj As Project)
Call m_Events.StartEvents
End Sub
Tips:
make sure cm_Events is a class module and not a regular module.
any time you make a change to the code the events will stop running--always run the StartEvents procedure after making any changes.
Start with simple code in the ProjectBeforeTaskChange event like a debug statement to verify the event is getting triggered.
the TaskChange event is just that--triggered by changes to the task, but not to a resource or assignment.