View when someone is busy without having full calendar access - vba

Question

I've written the following to get calendar items for a certain date range:
Sub printCal()
Dim sesh As Outlook.NameSpace
Set sesh = ThisOutlookSession.Session
Dim myCal As MAPIFolder
Set myCal = sesh.GetDefaultFolder(olFolderCalendar)
Dim target As Recipient
With sesh.GetSelectNamesDialog
.AllowMultipleSelection = False 'aside: this doesn't seem to force me to select only one
.ForceResolution = True
Debug.Print "displaying: "; .Display
Set target = .Recipients.Item(1)
End With
Dim targetCalendar As MAPIFolder
Set targetCalendar = sesh.GetSharedDefaultFolder(target, olFolderCalendar)
Dim x As Variant
'ISSUE these calendars aren't VBA accessible unless shared all details
'https://social.msdn.microsoft.com/Forums/en-US/bffddb8e-0344-459f-a586-105035eb4192/permission-levels-for-shared-calendars-when-reading-with-vba?forum=outlookdev
For Each x In targetCalendar.Items.Restrict( _
"[Start]>='08/06/2022 1 AM' and [End] <='08/06/2022 10 PM'" _
)
Debug.Print x.Start; x.Duration; "mins", x.Subject
Next
End Sub
This works for my calendar or someone who has shared their calendar publicly/with me specifically. It does not work for a calendar I can see in the scheduling assistant (they are in my organisation) but the titles of meetings are hidden.
I'm trying to write a VBA addin for Outlook that uses an algorithm I came up with to schedule meetings.
I only need to know when people are busy. Can I get it from the raw mail server rather than the Outlook API?

Answer 1

Recipient.FreeBusy does the trick. It shows when someone is marked as busy for the next 30 days in n minute intervals. e.g.
Sub useFreeBusy()
Dim target As Recipient
Set target = ThisOutlookSession.Session.CreateRecipient("Joe Bloggs")
Dim status As String
Const INTERVAL As Long = 60
status = target.FreeBusy(Date, INTERVAL, True) '60 min intervals 00:00 today, True showing all status info
Dim i As Long
For i = 1 To Len(status)
Dim slotTimestamp As Date
slotTimestamp = DateAdd("n", INTERVAL * (i - 1), Date)
Dim statusNumber As String
statusNumber = Mid(status, i, 1)
Debug.Print slotTimestamp ;statusNumber ; "-"; IIf(statusNumber = "0", "Free", "Busy")
Next i
End Sub
Which outputs something like:
14/02/2023 08:00:00 0-Free
14/02/2023 09:00:00 0-Free
14/02/2023 10:00:00 0-Free
14/02/2023 11:00:00 0-Free
14/02/2023 12:00:00 2-Busy
14/02/2023 13:00:00 0-Free
14/02/2023 14:00:00 1-Busy
14/02/2023 15:00:00 0-Free
14/02/2023 16:00:00 0-Free
14/02/2023 17:00:00 0-Free
14/02/2023 18:00:00 0-Free
14/02/2023 19:00:00 0-Free
14/02/2023 20:00:00 0-Free
[etc...]
Graph SDK requires you to have Global Admin permissions in Azure in order to view the calendars of other users. I don't have this.