Classic problem: Wait until the webpage has fully loaded and rendered in Safari.
Most snippets I found date years back and of course macOS and Safari have been upgraded, so I am looking how to TARGET this Reload this page button
I am on macOS Big Sur 11.7.2 with Safari v16.2, attached a screenshot (Note the beta Translate button)
This snipped should have been working on macOS High Sierra
tell application "Safari" to make new document with properties {URL:"https://nytimes.com"}
tell application "System Events"
repeat until (accessibility description of ¬
button 1 of UI element 2 of every group of toolbar 1 of window 1 of ¬
process "Safari" whose name = "Reload this page") contains "Reload this page"
delay 0.5
end repeat
end tell
log "Finished loading"
I tried to change button 1 of UI element 2 to button 2 assuming button 1 could be the Translate button but no go.
Ahhh, I just found it, with a better Google search, on
https://apple.stackexchange.com/questions/424629/applescript-to-prompt-for-url-input-open-url-in-safari-then-open-bookmark-with
So just for a reference:
tell application "Safari" to make new document with properties {URL:"https://nytimes.com"}
my waitForSafariPageToFinishLoading()
to waitForSafariPageToFinishLoading()
-- # Wait for page to finish loading in Safari.
-- # This works in **macOS Catalina** and
-- # macOS Big Sur and may need adjusting for
-- # other versions of macOS.
log "page is loading...."
tell application "System Events" to repeat until ¬
exists (buttons of groups of toolbar 1 of window 1 of ¬
process "Safari" whose name = "Reload this page")
delay 0.5
end repeat
log "page is LOADED"
end waitForSafariPageToFinishLoading
Related
how do we reset the size of safari dev-tools with apple-script for simulators? The url can be random and anything(any site). As can be seen from the screenshot, there is a setting option we get in safari devtools for simulators, where we can set the devtools size with "zoom" option. I wanted it to set to 100% with applescript doing the same job.
This script i was trying as shown below is trying to activate safari, then go the simulator device and click on the url. Then i am stuck on how to click on the settings tab on safari devtools and finally on zoom option to resize devtools with applescript
Below is the image:
Please see this image
tell application "System Events"
tell application process "Safari"
if not (exists menu bar item "Develop" of menu bar 1) then return
tell menu 1 of menu bar item "Develop" of menu bar 1
set simulatorMenuName to the name of (menu items whose name starts with "Simulator") as string
if simulatorMenuName is equal to "" then return
set simulatorMenuNameMenuItems to the name of menu items of menu 1 of menu item simulatorMenuName
if item 1 of simulatorMenuNameMenuItems is not "Safari" then return
repeat with i from 1 to count simulatorMenuNameMenuItems
if item i of simulatorMenuNameMenuItems is equal to missing value then
set menuItemNumber to i - 1
exit repeat
end if
end repeat
tell menu 1 of menu item simulatorMenuName to click menu item menuItemNumber
end tell
end tell
end tell
I am not able to test in the same environment as you at the present time, however, he example AppleScript code, shown below, was tested in Script Editor under macOS Catalina and Safari version 14.0.3 (15610.4.3.1.6, 15610) with Language & Region settings in System Preferences set to English (US) — Primary and worked for me without issue1.
1 Assumes necessary and appropriate settings in System Preferences > Security & Privacy > Privacy have been set/addressed as needed.
Example AppleScript code:
tell application "Safari" to activate
delay 0.2
tell application "System Events"
tell front window of application process "Safari"
if (value of pop up button 1 of group 19 of ¬
group 4 of UI element 1 of scroll area 1 of ¬
group 1 of group 1) is not "100%" then
click ¬
pop up button 1 of group 19 of ¬
group 4 of UI element 1 of ¬
scroll area 1 of group 1 of group 1
delay 0.1
click ¬
menu item "100%" of menu 1 of group 1
end if
end tell
end tell
Notes:
The example AppleScript code assumes that the front window of Safari is already loaded to the target page and or Web Inspector tab/window.
The target tab of the Web Inspector does not appear to be JavaScript scriptable via AppleScript, however, it can be scripted using UI Scripting. Note that UI Scripting is kludgy at best and prone to failure due to changes in the hierarchical UI element structure of the OS and or application being scripted. Changes to the example AppleScript code presented may need to be made to your use in macOS Big Sur, or any other version of macOS and or Safari other than what it was tested and worked under.
You can use Accessibility Inspector to check the hierarchical UI element structure under the current version of macOS and Safari your are using. You can also use AppleScript to query the various hierarchical UI element structures to ascertain which it the right one for the pop up button button.
Note: The example AppleScript code is just that and sans any included error handling does not contain any additional error handling as may be appropriate. The onus is upon the user to add any error handling as may be appropriate, needed or wanted. Have a look at the try statement and error statement in the AppleScript Language Guide. See also, Working with Errors. Additionally, the use of the delay command may be necessary between events where appropriate, e.g. delay 0.5, with the value of the delay set appropriately.
I'm trying to create a script that will click in Safari on a Favorites folder in the FAVORITES-BAR (just below the toolbar) to open it. Unfortunately without success. Does anyone know help?
Andy
Here is an option that works for me on the latest version of Mac OS high Sierra. To start with, if you don't already know which Favorite you would like to automate clicking, the code in this option supplies you with a list of your Favorites to choose from. This is also assuming that your Favorites bar is already visible in Safari.
tell application "Safari" to activate
tell application "System Events"
delay 0.1
set yourFaves to name of buttons of group 1 of window 1 ¬
of application process "Safari"
delay 0.1
set theURL to (choose from list yourFaves ¬
with title ¬
"FAVORITES BUTTONS" with prompt ¬
"Which Favorite Would You Like To Visit?" OK button name ¬
"GO THERE" cancel button name ¬
"CANCEL" without empty selection allowed) as text
click UI element theURL of group 1 of window 1 ¬
of application process "Safari"
end tell
This solution has its limits though. This version will only retrieve the Favorites that are actually visible in the browser window. I'm working on another solution which may get better results. Will update this post shortly
I need an applescript to open safari in full screen an to hide the toolbar on mavericks.
it sounds easy but it isnt!
i need to open safari then open google in full screen mode an then hide the toolbar.
it would be the equivilent to the below sample but instead for safari
tell application "Google Chrome"
open location "http://internet.ceo.wa.edu.au/Pages/default.aspx"
end tell
tell application "Google Chrome" to activate
tell application "System Events"
keystroke "f" using {command down, shift down}
end tell
Could be simple as this:
tell application "Safari"
activate
if (count of windows) is 0 then -- Remove "if" statement if you don't want to make a new window if there is none
make new document at front
end if
tell application "System Events" to keystroke "f" using {command down, control down}
end tell
Not sure if you can make it with no toolbar at all.
Update 4/4
not sure what you can do with it but look into this program. If it works the way you want. Add a system events to use the drop downs to select the item.
The Barbarian Group has a freeware app called "Plainview", which seems to be just a wrapper around Webkit. It works as a "Fullscreen kiosk-style presentation content viewer", similar to what Chrome presentation mode does.
Anyways, it's a free download, so no risk in trying. Scroll almost to the bottom of this page:
http://barbariangroup.com
Direct download:
http://s3.amazonaws.com/plainviewapp/plainview_1.0.178.zip
Easy way:
set MyApps to {"Google Chrome", "Skype", "Finder"}
repeat with MyApp in MyApps
tell application MyApp
activate
delay 3
tell application "System Events" to tell process MyApp
set value of attribute "AXFullScreen" of window 1 to true
end tell
end tell
end repeat
I'm using Safari's remote debugging to inspect a webview in an iPhone app in my simulator. The problem is that the remote debugging window closes as soon as the app does.
I have an action which switches to another app and back but I can't read console.log messages from immediately before the switch because I'm not quick enough and I can't read logs from immediately after coming back to my app because I have to re-open the console first.
Is there a way to keep it open so I can at least see the last logs from before switching apps?
Here is an AppleScript that launches Safari Inspector. You can export it as an executable application and have it sitting in your dock to get into Inspector with a single click or launch it in a build phase in Xcode.
tell application "Safari"
activate
delay 2
tell application "System Events"
tell process "Safari"
set frontmost to true
click menu item 2 of menu 1 of menu item "iPad Simulator" of menu 1 of menu bar item "Develop" of menu bar 1
end tell
end tell
end tell
This is James' answer wrapped in an Alfred Workflow, -g- ... check it
ALSO WORKS FOR IPHONE BRAH
on alfred_script(q)
tell application "Safari"
activate
delay 0.5
tell application "System Events"
tell process "Safari"
set frontmost to true
try
click menu item 2 of menu 1 of menu item "iPhone Simulator" of menu 1 of menu bar item "Develop" of menu bar 1
end try
try
click menu item 2 of menu 1 of menu item "iPad Simulator" of menu 1 of menu bar item "Develop" of menu bar 1
end try
end tell
end tell
end tell
end alfred_script
I have to close and reopen it for development purposes like 100 times a day and the extra time it takes to open the web inspector disable cache, clear cache, start debugging javascript, and occasionally clear local databases is getting to be tedious.
Here is an AppleScript I wrote that launches Safari Inspector. You can export it as an executable application and have it sitting in your dock to get into Inspector with a single click. You could also launch it in a build phase in Xcode to have it run when your app is sent to simulator. Change "iPad Simulator" to "iPone Simulator" or connected device as needed.
tell application "Safari"
activate
delay 2
tell application "System Events"
tell process "Safari"
set frontmost to true
click menu item 2 of menu 1 of menu item "iPad Simulator" of menu 1 of menu bar item "Develop" of menu bar 1
end tell
end tell
end tell