awk to rename txt files using partial match in another file, appending the partial match to the txt files - awk

Question

I am trying to use awk to rename all txt files in a directory based on a partial match to $2 of file. The txt files in the directory are then have the $2 string in file used to rename them. The txt files only need to have the string that matches replaced. That is the portion after the - remains. The awk below, thank you #markp-fuso, executes but returns the attempts I made return the original txt file unchanged. Thank you :).
current directory structure
123_1_000.txt
456_2_101.txt
789_3_200.txt
file
aaa 123_1
bbb 456_2
ccc 789_3
desired directory
aaa_000.txt
bbb_101.txt
ccc_200.txt
awk
t=$(ls *.txt) | echo $t | awk '{sub(/([_^]*:){2}/,"")}1' | # list all txt files in directory
awk '
FNR==NR { map[$2]=$1; next } # store $2 from file in map array, goto next
{ split($0,a,".") # split on . using txt files and read in string into [a]
if (a[1] in map) # if [a] matches map
print "mv \"" $0 "\" \"" map[a[1]]* ".txt\"" # rename txt with map[a] string
}
' file - # read stdin as 2nd input

Answer 1

You were very close, whether you use bash, or other advanced shell, that provides process substitution or you pipe and read from -, the following will rename the files in the current directory removing the prefix [[:digit:]]+_[[:digit:]] and replacing with the $1 value from file that corresponds to the prefix.
The key is to provide a relationship between the array index holding the replacement and the value of the array holding the prefix as its index. Below the a[] array saves the $1 values from file indexed by line-number while the b[] array holds the prefix as index with the line-number stored as its value (you can use a counter if you like, e.g. ++n).
The match() command is used to create the c[] array which holds the prefix taken from the current filename and if the prefix exists in the b[] array the filename is saved and the new filename is created by sub() on $1 and the is moved to the new filename using the system() command with the command string built by concatenation in cmd.
awk '
FNR==NR { # reading from file
a[NR] = $1 # save $1 to array indexed by NR
b[$2] = NR # save $2 as index to array with NR as value
}
NR>FNR { # handling filenames
match($1,/^[[:digit:]]+_[[:digit:]]+/,c) # save up to last _ in c array
if (c[0] in b) { # if prefix present in b array
fname=$1 # save current filename
sub(c[0], a[b[c[0]]], $1) # sub a array with prefix for new filename
cmd="mv "fname" "$1 # create move command string
system(cmd) # move current to new filename
}
}
' file <(ls -1 *.txt)
(note: the redirected command substitution <(ls -1 *.txt) is used to provide the filenames. If your shell does not provide that capability, then pipe the filenames to the command and add - as a filename causing awk to read stdin -- as you have done)
Example Results
With your original filenames in the present directory and the contents in file, e.g.
$ cat file
aaa 123_1
bbb 456_2
ccc 789_3
the result of the above is:
$ ll
total 4
-rw-r--r-- 1 david david 0 Jan 6 16:09 aaa_000.txt
-rw-r--r-- 1 david david 0 Jan 6 16:09 bbb_101.txt
-rw-r--r-- 1 david david 0 Jan 6 16:09 ccc_200.txt
-rw-r--r-- 1 david david 30 Jan 6 16:09 file
Note, if you don't care about matching [[:digit:]] you can remove the prefix with /^[^_]+_[^_]+/ to match anything in the prefix up to the second '_'.