DMax within Insert Into SQL statement (not working) - sql

Question

I've got a piece of VBA code that pulls data in from a linked table and appends some date columns based on using the DMax function to look up the most recent transaction dates based on SKU and transaction type. I'm getting the following error:
For some reason the DMax function is not seeing the data properly from the SKU field that is in the select statement.
SQLstr = "Insert Into TEMP_ONHAND Select " & _
"COMPANY, WHSE, WHSEDESC, ITEM, ITEMDESC, ESTCOSTPRICE, INVONHAND, CONSIGNINVONHAND, " & _
"QUANTITYINTRANSIT, QTY, COST, LASTINVTRANS, SUPPLIERID, SUPPLIER, " & _
"BUYER, BUYERNAME, PLANNER, PLANNERNAME, BUYFROMBP, BUYFROMBPNAME, " & _
"[COMPANY] & '-' & [WHSE] & '-' & [ITEM] AS SKU, " & _
"Left([WHSEDESC],3) AS TYPE, " & _
"#" & DMax("[TRANSDATE]", "[TEMP_HISTORY]", "[SKU]='" & [SKU] & "' AND [TRANSTYPE] = 3") & "# AS LAST_RCPT, " & _
"#1/1/1950# AS LAST_ISSUE, " & _
"#1/1/2000# AS LAST_ADJUST, " & _
"'TEST' AS TRAN_RANGE, " & _
"'TEST' AS ADJ_RANGE " & _
"From PARTS_ONHAND;"
MsgBox SQLstr
Application.CurrentDb.Execute SQLstr
If I replace the & [SKU] & in the DMax function with an actual text string of a SKU, this code works fine. I'm wondering if the syntax needs to be different somehow within the DMax function in order to reference a field from the select portion of the statement?

Answer 1

The & [SKU] & code is not referencing calculated SKU field of SELECT portion of constructed SQL statement. This concatenation takes place within the VBA procedure, not the SQL statement. Therefore, VBA looks for [SKU] and can't find anything. In fact, that entire DMax() expression is executed in this VBA procedure and if it did succeed it would return a single value for concatenation and every record pulled by the SELECT would have it. If you want to reference calculated SKU field as input to DMax(), then DMax() expression must be embedded in constructed SQL statement.
Embedding domain aggregate functions with dynamic arguments within SQL constructed in VBA is tricky when text fields are the criteria. Try:
"# & DMax('[TRANSDATE]', '[TEMP_HISTORY]', '[TRANSTYPE] = 3 AND [SKU]=' & Chr(39) & [SKU] & Chr(39)) & # AS LAST_RCPT, " & _
Or build a SELECT query object which includes DMax() function then call that object by the VBA procedure.
SQLstr = "Insert Into TEMP_ONHAND Select * FROM queryName"
Or don't save aggregate data, calculate it when needed.

Answer 2

Try this:
SQLstr = "Insert Into TEMP_ONHAND Select " & _
"COMPANY, WHSE, WHSEDESC, ITEM, ITEMDESC, ESTCOSTPRICE, INVONHAND, CONSIGNINVONHAND, " & _
"QUANTITYINTRANSIT, QTY, COST, LASTINVTRANS, SUPPLIERID, SUPPLIER, " & _
"BUYER, BUYERNAME, PLANNER, PLANNERNAME, BUYFROMBP, BUYFROMBPNAME, " & _
"[COMPANY] & '-' & [WHSE] & '-' & [ITEM] AS SKU, " & _
"Left([WHSEDESC],3) AS TYPE, " & _
"DMax(""[TRANSDATE]"", ""[TEMP_HISTORY]"", ""[SKU] = '"" & [SKU] & ""' AND [TRANSTYPE] = 3"") AS LAST_RCPT, " & _
"#1/1/1950# AS LAST_ISSUE, " & _
"#1/1/2000# AS LAST_ADJUST, " & _
"'TEST' AS TRAN_RANGE, " & _
"'TEST' AS ADJ_RANGE " & _
"From PARTS_ONHAND;"