Change two columns to one column? - vba

Question

I am composing a word .doc using access VBA. Doc starts in one column. I split the next section into 3 columns using:
.InsertBreak wdSectionBreakContinuous
With w.ActiveDocument.Sections(2).PageSetup.TextColumns
.SetCount numcolumns:=2
.Add EvenlySpaced:=True
End With
Then I split to 2 columns using:
.InsertBreak wdSectionBreakContinuous
With w.ActiveDocument.Sections(3).PageSetup.TextColumns
.SetCount numcolumns:=1
.Add EvenlySpaced:=True
End With
Now I want to go back to a single column, but the following:
.InsertBreak wdSectionBreakContinuous
w.ActiveDocument.Sections(4).PageSetup.TextColumns.SetCount numcolumns:=0
does not work. Any tips on how to convert back to a single column?
FWIW all of this happens on a single page in word.
Thanks!

Answer 1

This works for me:
Sub ColumnsDemo()
Dim Rng As Range
With ActiveDocument
With .Sections(1)
.PageSetup.TextColumns.SetCount NumColumns:=1
Set Rng = .Range.Paragraphs(10).Range
Rng.Collapse
Rng.InsertBreak wdSectionBreakContinuous
End With
With .Sections(2)
With .PageSetup.TextColumns
.SetCount NumColumns:=2
.EvenlySpaced = True
.LineBetween = False
End With
Set Rng = .Range.Paragraphs(10).Range
Rng.Collapse
Rng.InsertBreak wdSectionBreakContinuous
End With
With .Sections(3)
With .PageSetup.TextColumns
.SetCount NumColumns:=3
.EvenlySpaced = True
End With
Set Rng = .Range.Paragraphs(10).Range
Rng.Collapse
Rng.InsertBreak wdSectionBreakContinuous
End With
With .Sections(4)
With .PageSetup.TextColumns
.SetCount NumColumns:=2
.EvenlySpaced = True
.LineBetween = False
End With
Set Rng = .Range.Paragraphs(10).Range
Rng.Collapse
Rng.InsertBreak wdSectionBreakContinuous
End With
With .Sections(5)
.PageSetup.TextColumns.SetCount NumColumns:=1
End With
End With
End Sub

Answer 2

You need at least to use
w.ActiveDocument.Sections(4).PageSetup.TextColumns.SetCount numcolumns:=1
rather than numcolumns:=0
Here, using numcolumns:=1 raises error 5148 "The number must be between 1 and 45", which suggests that you may have switched off error checking while testing your code.
Also, if you compare with your first two pieces of code, you are
setting the number of columns to 2, then Adding a column to make 3
setting the number of columns to 1, then Adding a column to make 2
whereas in your third piece of code you aren't Adding a column, suggesting that you would need in any case to set the count to 1 rather than 0.
New material
Your original code snippets don't say what objects/ranges your .InsertBreak method calls are applied to. If you start with a blank document, you might well be inserting all your section breaks at the beginning of the document, which would definitel cause problems.
Another possible problem is that when you have multiple columns, it isn't necessarily obvious which paragraphs are in which section.
macropod's code works fine here, and I get the 1,2,3,2,1 column sections you would expect, not the 2,3,4,3,2 that you are seeing. There's no reason to believe that it would be any different running the code from Access (in fact I tried it with the necessary changes, just to be sure).
But maybe the following code will make some things clearer.
Sub BuildDoc()
Dim r As Word.Range
' Assume we're starting from a completely blank document.
With ActiveDocument
' Let's ensure it has 1 column
.PageSetup.TextColumns.SetCount NumColumns:=1
' Let's work with a range variable
Set r = .Content
' add a bit of text and some paragraphs
' to create a visible section 1
'
r.Text = "Start section 1"
r.Paragraphs.Add
r.Paragraphs.Add
r.Paragraphs.Add
r.Paragraphs.Add
r.Paragraphs.Add
' At this point, r still has the same start and end as .content
' If we inserted a section break now using r or .COntent,
' it would be inserted at the beginning of the document
' So let's just collapse r to its and and add a bit more text
' before starting the new section
' We can "get to the right place" this way
r.Collapse WdCollapseDirection.wdCollapseEnd
r.Text = "End section 1"
r.Collapse WdCollapseDirection.wdCollapseEnd
' This inserts the break before the final paragraph mark
r.InsertBreak wdSectionBreakContinuous
' r now starts *after* the break
With r.PageSetup.TextColumns
.SetCount NumColumns:=3
.EvenlySpaced = True
End With
' add some text and paras
r.Text = "Start section 2"
r.Paragraphs.Add
r.Paragraphs.Add
r.Paragraphs.Add
r.Paragraphs.Add
r.Paragraphs.Add
' and repeat for a 2-column section
r.Collapse WdCollapseDirection.wdCollapseEnd
r.Text = "End section 2"
r.Collapse WdCollapseDirection.wdCollapseEnd
r.InsertBreak wdSectionBreakContinuous
' r now starts *after* the break
With r.PageSetup.TextColumns
.SetCount NumColumns:=2
.EvenlySpaced = True
End With
' add some text and paras
r.Text = "Start section 3"
r.Paragraphs.Add
r.Paragraphs.Add
r.Paragraphs.Add
r.Paragraphs.Add
r.Paragraphs.Add
' and back to 1 column
r.Collapse WdCollapseDirection.wdCollapseEnd
r.Text = "End section 3"
r.Collapse WdCollapseDirection.wdCollapseEnd
r.InsertBreak wdSectionBreakContinuous
' r now starts *after* the break
With r.PageSetup.TextColumns
.SetCount NumColumns:=1
End With
' add some text and paras
r.Text = "Start section 4"
r.Paragraphs.Add
r.Paragraphs.Add
r.Paragraphs.Add
r.Paragraphs.Add
r.Paragraphs.Add
r.Collapse WdCollapseDirection.wdCollapseEnd
r.Text = "End section 4"
End With
End Sub
If you run that in Word, you should get the section layout you were trying to achieve. If you don't, combined with the result you had with macropod's code, I'd suggest that something else is going on, such as document or template corruption.
Here, that ends up looking like this:
WHen I first looked at this I thought "why is there an extra paragraph at the beginning of section 4, before the text "Start section 4" ? CLick in it, check the column count, and it says "2".
But of course the paragraph isn't in Section 4, it's in the first column ofSection 3. It's just my eyesight playing tricks.