How to stop UserControl inside panel from opening new instance - vb.net

Question

I have form formmain. Inside panel2 of formmain I want to open UserControl named create_item using Button Button2. The code is:
Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
Dim uc = New create_item
Panel2.Controls.Add(uc)
uc.BringToFront()
End Sub
Problem is if I click Button2 two times, two different UserControls open. If Button2 is clicked and UserControl create_item is already open then I want it to show it in front of the other controls. How can I do that? Please help. Thank you in advance.

Answer 1

Try the following:
Create a Windows App (.NET Framework)
Open Solution Explorer
In VS menu, click View
Select Solution Explorer
Open the Toolbox
In VS menu, select View
Select Toolbox
Add 2 Buttons to Form1 (ButtonShowUserControl1 and ButtonShowUserControl2)
Double-click each button to add the event handler to the form
Add a Panel to Form1 (name: Panel2)
Create 2 UserControls (name: UserControl1 and UserControl2) - design as desired.
For testing, one can add a label to each UserControl and set the text property to a unique value such as "This is UserControl 1" or "This is UserControl 2".
Rename Form1.vb to FrmMain.vb
In Solution Explorer, right-click Form1.vb
Select Rename (name: FrmMain.vb)
When prompted You are renaming a file. Would you also like to perform a rename in this project of all references to the code element "Form1.vb", select Yes
Select one of the options below:
Option 1 (FrmMain.vb)
This option creates an instance of each type of UserControl and adds it to the Panel when the corresponding Button is clicked. To ensure that only 1 instance of each type of UserControl is added, it uses Find (which searches based on the name of the UserControl) to check if an instance already exists. Since more than 1 UserControl may exist on the Panel, it uses BringToFront to ensure that the desired UserControl is shown.
Public Class FrmMain
Private Function BringDesiredUserControlToFront(ucName As String) As Boolean
'check if UserControl already exists on the Panel
If Panel2.Controls.Count > 0 Then
'find Controls matching the specified name
Dim ctls As Control() = Panel2.Controls.Find(ucName, False)
If ctls IsNot Nothing AndAlso ctls.Count > 0 Then
'there should only be 1 instance of this Control
Dim ctl As Control = ctls(0)
'bring UserControl to front
ctl.BringToFront()
Return True
End If
End If
Return False
End Function
Private Sub ButtonShowUserControl1_Click(sender As Object, e As EventArgs) Handles ButtonShowUserControl1.Click
Debug.WriteLine($"Panel2.Controls.Count: {Panel2.Controls.Count}")
If Not BringDesiredUserControlToFront("UserControl1") Then
'create new instance
Dim uc As UserControl1 = New UserControl1()
'set property
uc.Name = "UserControl1"
'add to Panel
Panel2.Controls.Add(uc)
'show
uc.Show()
'in case other controls exist, bring this one to front
'if desired, one can check if other controls exist
'and only execute the following statement if other controls exist
uc.BringToFront()
End If
End Sub
Private Sub ButtonShowUserControl2_Click(sender As Object, e As EventArgs) Handles ButtonShowUserControl2.Click
Debug.WriteLine($"Panel2.Controls.Count: {Panel2.Controls.Count}")
If Not BringDesiredUserControlToFront("UserControl2") Then
Debug.WriteLine("Creating new instance of UserControl2")
'create new instance
Dim uc As UserControl2 = New UserControl2()
'set property
uc.Name = "UserControl2"
'add to Panel
Panel2.Controls.Add(uc)
'show
uc.Show()
'in case other controls exist, bring this one to front
'if desired, one can check if other controls exist
'and only execute the following statement if other controls exist
uc.BringToFront()
End If
End Sub
End Class
Option 2 (FrmMain.vb)
This option creates an instance of each type of UserControl and adds it to the Panel when the corresponding Button is clicked. To ensure that only 1 instance of each type of UserControl is added, it uses a For Each to loop through all of the controls and check if an instance already exists. Since more than 1 UserControl may exist on the Panel, it uses BringToFront to ensure that the desired UserControl is shown.
Public Class FrmMain
Private Sub ButtonShowUserControl1_Click(sender As Object, e As EventArgs) Handles ButtonShowUserControl1.Click
Dim uc As UserControl1 = Nothing
Debug.WriteLine($"Panel2.Controls.Count: {Panel2.Controls.Count}")
'check if UserControl already exists on the Panel
If Panel2.Controls.Count > 0 Then
For Each ctl In Panel2.Controls
If TypeOf (ctl) Is UserControl1 Then
'create reference
uc = CType(ctl, UserControl1)
Exit For
End If
Next
End If
If uc Is Nothing Then
'UserControl doesn't exist on Panel
'create new instance
uc = New UserControl1()
'add to Panel
Panel2.Controls.Add(uc)
'show
uc.Show()
End If
'show
uc.BringToFront()
End Sub
Private Sub ButtonShowUserControl2_Click(sender As Object, e As EventArgs) Handles ButtonShowUserControl2.Click
Dim uc As UserControl2 = Nothing
Debug.WriteLine($"Panel2.Controls.Count: {Panel2.Controls.Count}")
'check if UserControl already exists on the Panel
If Panel2.Controls.Count > 0 Then
For Each ctl In Panel2.Controls
If TypeOf (ctl) Is UserControl2 Then
'create reference
uc = CType(ctl, UserControl2)
Exit For
End If
Next
End If
If uc Is Nothing Then
'UserControl doesn't exist on Panel
'create new instance
uc = New UserControl2()
'add to Panel
Panel2.Controls.Add(uc)
'show
uc.Show()
End If
'show
uc.BringToFront()
End Sub
End Class
Option 3 (FrmMain.vb)
This option only has 1 UserControl on the Panel at a time. If a UserControl already exists on the Panel, it is removed and disposed prior to adding a different one.
Public Class FrmMain
Private _currentUserControl As UserControl = Nothing
Private Sub ShowDesiredUserControl(uc As UserControl)
If _currentUserControl IsNot Nothing Then
'remove existing UserControl
Panel2.Controls.Remove(_currentUserControl)
'dispose
_currentUserControl.Dispose()
End If
'add UserControl to Panel
Panel2.Controls.Add(uc)
'set value
_currentUserControl = uc
'show
uc.Show()
Debug.WriteLine($"Panel2.Controls.Count: {Panel2.Controls.Count}")
End Sub
Private Sub ButtonShowUserControl1_Click(sender As Object, e As EventArgs) Handles ButtonShowUserControl1.Click
ShowDesiredUserControl(New UserControl1())
End Sub
Private Sub ButtonShowUserControl2_Click(sender As Object, e As EventArgs) Handles ButtonShowUserControl2.Click
ShowDesiredUserControl(New UserControl2())
End Sub
End Class
Option 4 (FrmMain.vb)
This option only has 1 UserControl on the Panel at a time. If a UserControl already exists on the Panel, it is removed and disposed prior to adding a different one. It's similar to Option 3.
Public Class FrmMain
Private _currentUserControl As UserControl = Nothing
Private Sub ButtonShowUserControl1_Click(sender As Object, e As EventArgs) Handles ButtonShowUserControl1.Click
If _currentUserControl IsNot Nothing Then
'remove existing UserControl
Panel2.Controls.Remove(_currentUserControl)
'dispose
_currentUserControl.Dispose()
End If
'create new instance
_currentUserControl = New UserControl1()
'add UserControl to Panel
Panel2.Controls.Add(_currentUserControl)
'show
_currentUserControl.Show()
End Sub
Private Sub ButtonShowUserControl2_Click(sender As Object, e As EventArgs) Handles ButtonShowUserControl2.Click
If _currentUserControl IsNot Nothing Then
'remove existing UserControl
Panel2.Controls.Remove(_currentUserControl)
'dispose
_currentUserControl.Dispose()
End If
'create new instance
_currentUserControl = New UserControl2() 'create new instance
'add UserControl to Panel
Panel2.Controls.Add(_currentUserControl)
'show
_currentUserControl.Show() 'show
End Sub
End Class
Resources
Scope in Visual Basic