Split a string based on a regex in bash and construct a map of pattern to matched output - awk

Question

I have a string something like
scope1/group1: health check failure; Refer section:1; scope2/group2: config validation failure; Refer section:2
I want the output in form of a map like
{scope1/group1, health check failure; Refer section:1}
{scope2/group2, config validation failure; Refer section:2}
The set of keys (scope1/group1, scope2/group2, etc.) is fixed and I think the best way to achieve the output is to split on the keys itself. Open to suggestions if there's another better way.
To split on keys, I tried using awk with the split function to split on the keys.
echo "$string" | awk '{ split($0, a, /(scope1\/group1:|scope2\/group2:)/); print a[2] }' }'
Output
health check failure; Refer section:1;
However, I don't get the pattern that this value is matched against to construct the map.
gawk split() also populates the separators array(documentation) which will work to find the key associated with the matched value. However, I can't use gawk for some other reasons and looking for alternatives.

Answer 1

You can make semicolon the record separator and colon the field separator to let awk split the tokens for you. To deal with the last record, which ends with a newline character that doesn't belong to the value, include it as an alternation pattern in the field separator:
awk 'BEGIN{FS=": |\n";RS="; "}{print"{\""$1"\": \""$2"\"}"}'
Demo: https://ideone.com/UaqsFO
EDIT: With your edited question now stating that the set of keys are fixed and known in advance, and that values may contain colons and semicolons, you can instead iterate through matches of the known keys, and use RSTART and RLENGTH to extract the key and value, and remove the current record for the next iteration to match a new record:
awk '{
for (;;) {
match($0, "(; )?(scope1/group1|scope2/group2): |$")
if (RSTART > 1) {
value = substr($0, 1, RSTART - 1)
sub("; $", "", value)
print "{" key ", " value "}"
}
if (!RLENGTH)
break
key = substr($0, RSTART, RLENGTH - 2)
sub("^; ", "", key)
$0 = substr($0, RSTART + RLENGTH)
}
}'
Demo: https://ideone.com/gBhVDs

Answer 2

Your edit removing the quotes in the output made things a bit easier. If your field-separator is consistent as "; ", then you can use:
awk -F"; " '{ for (i=2; i<=NF; i+=2) { sub(/[:]/,",",$(i-1)); print "{"$(i-1)"; "$i"}" }}'
With your data, the result would be:
$ echo "scope1/group1: health check failure; Refer section:1; scope2/group2: config validation failure; Refer section:2" |
awk -F"; " '{ for (i=2; i<=NF; i+=2) { sub(/[:]/,",",$(i-1)); print "{"$(i-1)"; "$i"}" }}'
{scope1/group1, health check failure; Refer section:1}
{scope2/group2, config validation failure; Refer section:2}

Answer 3

Using any awk:
$ cat tst.awk
{
while ( match($0,/[^;]+;[^;]+; /) ) {
blocks[++numBlocks] = substr($0,RSTART,RLENGTH-2)
$0 = substr($0,RSTART+RLENGTH)
}
blocks[++numBlocks] = $0
for ( i=1; i<=numBlocks; i++ ) {
sub(/:/,",",blocks[i])
print "{" blocks[i] "}"
}
}
$ awk -f tst.awk file
{scope1/group1, health check failure; Refer section:1}
{scope2/group2, config validation failure; Refer section:2}

Answer 4

Given your string:
s='scope1/group1: health check failure; Refer section:1; scope2/group2: config validation failure; Refer section:2'
You can use perl to capture the strings leading up to \w:\d) with an optional ; :
perl -0777 -lpE 's/(.*?\w+:\d+)(?:;\s*)?/{\1}\n/g' <<<"$s"
Or, use your notion of splitting on scope:
perl -0777 -nE 's/\R//; for $gr (split /;\h+(?=scope)/) {say "{$gr}"}' <<<"$s"
Or GNU grep with sed:
grep -oP "scope.*?(?=scope|$)" <<<"$s" | sed 's/^/{/; s/;*[[:space:]]*$/}/'
Or POSIX sed pipeline:
sed -E 's/(.*:[[:digit:]][[:digit:]]*); /\1\n/g' <<<"$s" | sed 's/^/{/; s/$/}/'
Or (assuming just one split) you could use Bash:
printf "{${s%; scope*}}\n{${s#*:?; }}"
Any of these prints:
{scope1/group1: health check failure; Refer section:1}
{scope2/group2: config validation failure; Refer section:2}