How can I write find-instance in def-rule in CLIPS? - syntax-error

Question

What is Wrong with this defrule as it always give me this error
[PRNTUTIL2] Syntax Error: Check appropriate syntax for defrule.
ERROR:
(defrule MAIN::print-university-info
?university <- (object (is-a University)
(universityName $?name)
(numFaculties $?num)
(faculties ?facultyy $?faculties))
?faculty <- (find-instance (
CLIPS>
the rule is
(defrule print-university-info
?university <- (object (is-a University) (universityName $?name) (numFaculties $?num) (faculties ?facultyy $?faculties))
?faculty <- (find-instance ((?facultyInstance Faculty)) (eq ?facultyy ?facultyInstance))
=>
(printout t "University name: " ?name " Number of faculties: " ?num " Faculties: " ?faculty crlf)
)
the classes are
(
defclass University
(is-a USER)
(slot universityName (type SYMBOL))
(slot numFaculties (type INTEGER))
(multislot faculties (type INSTANCE))
)
(
defclass Faculty
(is-a USER)
(slot facultyName (type STRING))
)
and the instances are
(make-instance Cairo of University (universityName "Cairo") (numFaculties 1) (faculties [FCAI]))
(make-instance FCAI of Faculty (facultyName "FCAI"))
I checked the find-instance by adding this to clips
(find-instance ((?facultyInstance Faculty)) (eq ?facultyInstance [FCAI]))
and it returned this
CLIPS> (find-instance ((?facultyInstance Faculty)) (eq ?facultyInstance [FCAI]))
([FCAI])

Answer 1

Find-instance is a function. To call functions from the conditions of a rule, you need to use the test conditional element. The way you've used find-instance in your rule, CLIPS thinks it's the name of a deftemplate. Typically, there's few if any reasons for calling query functions from the conditions of a rule; for most use cases, you'd call them from the actions of a rule. In the conditions of a rule, use a pattern instead:
CLIPS (6.4 2/9/21)
CLIPS>
(defclass University
(is-a USER)
(slot universityName (type SYMBOL))
(slot numFaculties (type INTEGER))
(multislot faculties (type INSTANCE)))
CLIPS>
(defclass Faculty
(is-a USER)
(slot facultyName (type STRING)))
CLIPS>
(definstances initial
(Cairo of University
(universityName "Cairo")
(numFaculties 1)
(faculties [FCAI]))
(FCAI of Faculty
(facultyName "FCAI")))
CLIPS>
(defrule print-university-info
?university <- (object (is-a University)
(universityName $?name)
(numFaculties $?num)
(faculties ?facultyy $?faculties))
?faculty <- (object (is-a Faculty)
(name ?facultyy))
=>
(printout t "University name: " ?name " Number of faculties: " ?num " Faculties: " ?faculty crlf))
CLIPS> (reset)
CLIPS> (run)
University name: Cairo Number of faculties: 1 Faculties: <Instance-FCAI>
CLIPS>