How to write a Cplex constraint for product types - optimization

Question

I am trying to write a constraint in Cplex that will only allow certain types of items to be packed together (recipe) in a bin. I have all my product data in a tuple with the recipes represented by either "1" "2" or "3". My code so far:
{string} product = ...;
tuple ItemInfo {
int width;
float amps;
int recipe;
int demand;
}
ItemInfo Items[product] = ...;
dvar boolean x[Bin][product];
dvar boolean y[Bin];
minimize sum(b in Bin) y[b];
subject to {
forall(b in Bin) sum(j in product) Items[j].width*x[b][j] <= Width*y[b];
forall(b in Bin) sum(j in product) Items[j].amps*x[b][j] >= MinAmps*y[b];
forall(b in Bin) sum(j in product) Items[j].amps*x[b][j] <= MaxAmps*y[b];
forall(j in product) sum(i in Bin) x[i][j] == Items[j].demand;
}
Any ideas on how to ensure there is only one recipe per bin would be greatly appreciated! Thank you!

Answer 1

if you compute
{int} recipes={Items[i].recipe | i in product};
then you can write the constraint
forall(b in Bin) 1>=sum(r in recipes) (1<=sum(p in product:Items[p].recipe==r) x[b][p]);
which makes sure that you have max one recipe per bin
Full working example:
.mod
{string} product = ...;
tuple ItemInfo {
int width;
float amps;
int recipe;
int demand;
}
int Width=10;
int MinAmps=0;
int MaxAmps=20;
range Bin=1..3;
ItemInfo Items[product] = ...;
{int} recipes={Items[i].recipe | i in product};
dvar boolean x[Bin][product];
dvar boolean y[Bin];
minimize sum(b in Bin) y[b];
subject to {
forall(b in Bin) sum(j in product) Items[j].width*x[b][j] <= Width*y[b];
forall(b in Bin) sum(j in product) Items[j].amps*x[b][j] >= MinAmps*y[b];
forall(b in Bin) sum(j in product) Items[j].amps*x[b][j] <= MaxAmps*y[b];
forall(j in product) sum(i in Bin) x[i][j] == Items[j].demand;
forall(b in Bin) 1>=sum(r in recipes) (1<=sum(p in product:Items[p].recipe==r) x[b][p]);
}
and .dat
product={"A","B","C"};
Items=[<1,1,1,1>,<2,2,2,2>,<3,3,1,1>];