I am struggling in this dataweave language [duplicate] - mule

Question

This question already has answers here:
dataweave transformation
(3 answers)
Closed 4 months ago.
Input :
{
"payload": {
"Field_X": "X",
"Field_Y": 10,
"Field_Z": "Z",
"Field_W" : {
"sub_1": "value_1",
"sub_2": true,
"sub_3": "value_3"
}
},
"mapper": {
"A": "<payload.Field_X>",
"B": "<payload.Field_Y>",
"C": "Fields or text not mapped to payload",
"D": {
"subD_1": "<payload.Field_W.sub_2>",
"subD_2": "<payload.Field_W.sub_4>"
}
}
}
Output
{
"A": "X",
"B": 10,
"C": "Fields or text not mapped to payload",
"D": {
"subD_1": true,
"subD_2": null
}
}
Note: Pls note that hardcoding is not allowed as per the client's request.
Every key-value pair has to be looped.

Answer 1

Based on my understanding of the original question, the following DataWeave script should accomplish the goal. I broke out the work into multiple functions so that it would be easier to follow.
%dw 2.4
output application/json
fun isExpression(value: String): Boolean = ((value startsWith("<")) and (value endsWith(">")))
fun extractExpression(value: String): Any = do {
if (isExpression(value))
dw::core::Strings::unwrap(value, "")
else value
}
fun evaluatePath(context: Object, expression: String): Any = do {
var tokens = expression splitBy "."
---
tokens reduce (val, acc = context) -> acc[val]
}
fun retrieveMappedValue(context: Object, value: String): Any = do {
var retValue = if (isExpression(value))
evaluatePath(context, extractExpression(value))
else value
---
retValue
}
fun remap(context: Object, object: Any, fn): Any = do {
if (object is Object)
entriesOf(object) reduce (val, acc = {}) -> dw::core::Objects::mergeWith(acc, {
(val.key): remap(context, val.value, fn)
})
else fn(context, object)
}
---
remap(payload, payload.mapper, retrieveMappedValue)