Can't get innertext from object - vba

Question

I am using below code, to retrive the total number of products on a given page, but get a runt-time error 428 on gg = ohtml.innertext
Sub testp()
numpage = GetNumberofPages("https://sheetmaterialswholesale.co.uk/sheet-materials/")
End Sub
Function GetNumberofPages(numpage As String)
Set xhr = New MSXML2.XMLHTTP60
Set html = New MSHTML.HTMLDocument
With xhr
.Open "GET", numpage, False
.setRequestHeader "User-Agent", "Mozilla/5.0"
.send
html.body.innerHTML = .responseText
End With
Dim ohtml As Object
Set ohtml = html.querySelectorAll(".noOfProducts")
Dim gg As String
gg = ohtml.innerText
gg = Replace(gg, ",", "")
nmpage = Round(Val(gg) / 36, 0) + 1
'nmpage = Val(Mid(Text, aa + 66, 5))
GetNumberofPages = nmpage
End Function
Any tips how to solve this?

Answer 1

The class you are using doesn't exist on the page and querySelectorAll returns a nodeList which doesn't have a .innerText property.
You can retrieve the page specific product count with the following css selector list which identifies the li elements associated with each product. Take the .Length property of the returned nodeList to get the number of products on the page
Debug.Print oHtml.querySelectorAll(".products li.product").Length
If you actually want the number of pages, calculated using the total product results count, then you can extract this total result count, as shown below, and use the results per page count as the denominator in the page count calculation.
Option Explicit
Public Sub testp()
MsgBox GetNumberOfPages("https://sheetmaterialswholesale.co.uk/sheet-materials/")
End Sub
Public Function GetNumberOfPages(ByVal numpage As String) As Long
Dim xhr As MSXML2.XMLHTTP60
Dim html As MSHTML.HTMLDocument
Set xhr = New MSXML2.XMLHTTP60
Set html = New MSHTML.HTMLDocument
With xhr
.Open "GET", numpage, False
.setRequestHeader "User-Agent", "Mozilla/5.0"
.send
html.body.innerHTML = .responseText
End With
'Dim ohtml As Object
Dim ohtml As MSHTML.IHTMLDOMChildrenCollection
Set ohtml = html.querySelectorAll(".products li.product")
Dim numProductsPerPage As Long, numProducts As Long, numPages As Long
numProductsPerPage = ohtml.Length 'assuming page you pass into function is representative
numProducts = CInt(html.querySelector(".cat-parent .count").innerText)
numPages = WorksheetFunction.Ceiling_Math(numProducts / numProductsPerPage)
GetNumberOfPages = numPages
End Function