How to center a logo image into Word 2016 footer? - vba

Question

I want to center a logo image in the footer of a Word 2016 document.
Based on code from Word footer image alignment in VBA, I can get the logo into the footer but cannot get it centered.
Sub Main()
'Based on https://stackoverflow.com/questions/58257052/word-footer-image-alignment-in-vba
Dim FIRMADOC As String
Dim SHP As InlineShape
Dim rng As Word.Range
FIRMADOC = "C:\Users\" & Environ("username") & "\Documents\Invoice\footer.png"
Set rng = ActiveDocument.Sections(1).Footers(wdHeaderFooterPrimary).Range
rng.Collapse wdCollapseStart
rng.Text = vbTab & vbTab 'position at second, right-aligned tab in the footer)
‘(Note: I have tried removing the tabs to no useful effect)
Set SHP = rng.InlineShapes.AddPicture(FileName:=FIRMADOC, LinkToFile:=False, SaveWithDocument:=True, Range:=rng)
'Based on Record Macro
ActiveWindow.ActivePane.View.SeekView = wdSeekCurrentPageFooter
Application.Templates( _
"C:\Users\Brian\AppData\Roaming\Microsoft\Document Building Blocks\1033\16\Built-In Building Blocks.dotx" _
).BuildingBlockEntries("Bold Numbers 3").Insert Where:=Selection.Range, _
RichText:=True
End Sub
The image ('FIRMADOC') ends up left justified. Manually changing alignment from Home Tab works. Recording that manual change comes up empty.

Answer 1

For example:
Dim Shp As Shape
With ActiveDocument
Set Shp = .Shapes.AddPicture(FileName:="C:\Users\" & Environ("username") & "\Documents\Invoice\footer.png", _
LinkToFile:=False, SaveWithDocument:=True, Anchor:=.Sections(1).Footers(wdHeaderFooterPrimary).Range)
Shp.RelativeHorizontalPosition = wdRelativeHorizontalPositionMargin
Shp.Left = wdShapeCenter
End With
or, if you want the logo formatted as in-line:
With ActiveDocument.Sections(1).Footers(wdHeaderFooterPrimary).Range
.InlineShapes.AddPicture FileName:="C:\Users\" & Environ("username") & "\Documents\Invoice\footer.png", _
LinkToFile:=False, SaveWithDocument:=True, Range:=.Characters.Last
.ParagraphFormat.Alignment = wdAlignParagraphCenter
End With