I'm new to pl/SQL, and I'm trying to create a procedure that displays the values from the table 'BUS'. Please help me out here.
I'm using SQL*Plus as a command-line interface tool for Oracle Database 10g Enterprise Edition Release 10.2.0.1.0.
SQL> create or replace procedure get_bus_table
2 in
3 begin
4 select * from bus;
5 end;
6 /
Warning: Procedure created with compilation errors.
There are various errors (there's no in but is or as; PL/SQL requires an INTO clause, but that probably wouldn't help here; you didn't say how would you want to display data contained in the table).
Sample data:
SQL> select * from bus;
ROUTENO SOURCE DESTINATION
---------- ------- -----------
1 chennai bangalore
101 PUNE CHENNAI
102 PUNE BANGALORE
103 CHENNAI PUNE
Here's one option: a procedure that loops through the table and uses dbms_output.put_line:
SQL> create or replace procedure get_bus_table is
2 begin
3 for cur_r in (select routeno, source, destination
4 from bus)
5 loop
6 dbms_output.put_line(cur_r.routeno ||' - '|| cur_r.source ||' - '||
7 cur_r.destination);
8 end loop;
9 end;
10 /
Procedure created.
Testing:
SQL> set serveroutput on
SQL> begin
2 get_bus_table;
3 end;
4 /
1 - chennai - bangalore
101 - PUNE - CHENNAI
102 - PUNE - BANGALORE
103 - CHENNAI - PUNE
PL/SQL procedure successfully completed.
SQL>
Or, maybe you wanted to use a function (instead of a procedure):
SQL> create or replace type t_row as object
2 (routeno number,
3 source varchar2(20),
4 destination varchar2(20));
5 /
Type created.
SQL> create or replace type t_tab as table of t_row;
2 /
Type created.
SQL> create or replace function f_get_bus_table
2 return t_tab
3 is
4 l_tab t_tab;
5 begin
6 select t_row(routeno, source, destination)
7 bulk collect into l_tab
8 from bus;
9 return l_tab;
10 end;
11 /
Function created.
Let's try it:
SQL> select * from table(f_get_bus_table);
ROUTENO SOURCE DESTINATION
---------- -------------------- --------------------
1 chennai bangalore
101 PUNE CHENNAI
102 PUNE BANGALORE
103 CHENNAI PUNE
SQL>
There's also a ref cursor procedure in another answer to your question; I suggest you check it.
Use:
select * from bus;
and do not use a procedure.
If you want to use a procedure then you will need to SELECT into something; that could be variable(s), collection(s) or a cursor. For example:
CREATE PROCEDURE get_bus_table(
o_cur OUT SYS_REFCURSOR
)
IS
BEGIN
OPEN o_cur FOR
select * from bus;
END get_bus_table;
/
Then, when you call the procedure, you can process the returned cursor.
db<>fiddle here
A select clause in procedure needs INTO with it and a variable to store the data in. You can use record for Bus table or you can use cursor. Both should be fine.
Related
how to call function from package by creating own collection of same collection type which is being used in package? can we use our own created collection to call function from packages? getting error while calling function.
create or replace package pk
is
type e_list is table of emp%rowtype index by pls_integer;
function pro1 return e_list;
end;
create or replace package body pk
is
x number;
function pro1 return e_list
is
v_emp e_list;
begin
for x in 100..110 loop
select * into v_emp(x) from employees where employee_id=x;
end loop;
return v_emp;
end;
end;
to call function check below code plzz.
declare
type p_list is table of emp%rowtype index by pls_integer;
r_cur p_list;
x number;
begin
r_cur:=pk.pro1;
x:=r_cur.first;
for i in 1..10 loop
dbms_output.put_line(r_cur(x).salary);
x:=r_cur.next(x);
end loop;
end;
If you'll be using that type outside of the package, create it at SQL level. Something like this:
Sample data:
SQL> SELECT * FROM employees;
EMPLOYEE_ID ENAME SALARY
----------- ---------- ----------
100 SMITH 800
101 ALLEN 1600
102 WARD 1250
103 JONES 2975
Types:
SQL> CREATE OR REPLACE TYPE e_list_t IS OBJECT
2 (
3 employee_id NUMBER,
4 ename VARCHAR2 (20),
5 salary NUMBER
6 );
7 /
Type created.
SQL> CREATE OR REPLACE TYPE e_list IS TABLE OF e_list_t;
2 /
Type created.
Package specification and its body:
SQL> CREATE OR REPLACE PACKAGE pk
2 IS
3 FUNCTION pro1
4 RETURN e_list;
5 END;
6 /
Package created.
SQL> CREATE OR REPLACE PACKAGE BODY pk
2 IS
3 FUNCTION pro1
4 RETURN e_list
5 IS
6 v_emp e_list := e_list ();
7 BEGIN
8 SELECT e_list_t (employee_id, ename, salary)
9 BULK COLLECT INTO v_emp
10 FROM employees;
11
12 RETURN v_emp;
13 END;
14 END;
15 /
Package body created.
Testing:
SQL> DECLARE
2 r_cur e_list;
3 BEGIN
4 r_cur := pk.pro1;
5
6 FOR x IN 1 .. r_cur.LAST
7 LOOP
8 DBMS_OUTPUT.put_line (r_cur (x).ename || ': ' || r_cur (x).salary);
9 END LOOP;
10 END;
11 /
SMITH: 800
ALLEN: 1600
WARD: 1250
JONES: 2975
PL/SQL procedure successfully completed.
SQL>
I'm using a DB 'A' to output a list of numbers :
123455
123456
123457
And I'm looking to build a dynamic statement to look into a DB 'B' with those results as a filter
a. Build an array with the values from DB 'A'
SELECT * FROM my_table
WHERE number in &array;
How can I achieve this ?
The DB 'B' is an Oracle DB.
Thanks
Hm. Looks like your "background" is not Oracle, because there are no "DB"s there. I mean, there are, but not in a context you're using them. If "DB" stands for a "Database", to me it looks as if you're actually talking about tables here.
Also, I don't understand what
The DB 'B' is in PLSQL means.
If "database" is a table, how is it in PL/SQL?
Anyway, to get you started: I'm fetching some data from Scott's EMP and DEPT tables. For collections, I'm using Oracle's built-in types.
These are employees in departments 10 and 20:
SQL> select deptno, ename
2 from emp
3 where deptno in (10, 20)
4 order by deptno, ename;
DEPTNO ENAME
---------- ----------
10 CLARK
10 KING
10 MILLER
20 ADAMS
20 FORD
20 JONES
20 SCOTT
20 SMITH
8 rows selected.
PL/SQL procedure which does something with them (the way I understood the question):
SQL> declare
2 l_a sys.odcinumberlist;
3 l_b sys.odcivarchar2list;
4 begin
5 select deptno
6 bulk collect into l_a
7 from dept
8 where deptno in (10, 20);
9
10 select ename
11 bulk collect into l_b
12 from emp
13 where deptno in (select * from table(l_a))
14 order by ename;
15
16 for i in l_b.first .. l_b.last loop
17 dbms_output.put_line(l_b(i));
18 end loop;
19 end;
20 /
ADAMS
CLARK
FORD
JONES
KING
MILLER
SCOTT
SMITH
PL/SQL procedure successfully completed.
SQL>
Lines #1 - 3 - declaration section
lines #5 - 8 - inserting values (departments) into l_a collection
Lines #10 - 14 - inserting values (employees) into l_b collection, based on values stored in l_a
Lines #16 - 18 - displaying contents of l_b
See if it helps.
[EDIT] After seeing your comment: as far as I can tell, you can't do what you wanted, not as simple as you'd want it to. This is how it works - you enter a comma-separated values as a parameter (that's your "array"), split it into rows and use the result as a subquery:
SQL> SELECT *
2 FROM dept
3 WHERE deptno IN ( SELECT REGEXP_SUBSTR ( '&&par_depts',
4 '[^,]+',
5 1,
6 LEVEL)
7 FROM DUAL
8 CONNECT BY LEVEL <= REGEXP_COUNT ( '&&par_depts', ',') + 1);
Enter value for par_depts: 10,20
DEPTNO DNAME LOC
---------- -------------- -------------
10 ACCOUNTING NEW YORK
20 RESEARCH DALLAS
SQL>
This is a SQL*Plus example; you'll probably have to substitute '&&par_depts' with :par_depts (depending on a tool you use).
Use the MEMBER operator.
First create a collection type in SQL:
CREATE TYPE int_list IS TABLE OF INT;
Then just use it in an SQL statement:
SELECT *
FROM my_table
WHERE value MEMBER OF int_list(123455, 123456, 123457);
Which, for the sample data:
CREATE TABLE my_table ( id, value ) AS
SELECT LEVEL, 123453 + LEVEL FROM DUAL CONNECT BY LEVEL <= 5;
Outputs:
ID
VALUE
2
123455
3
123456
4
123457
If you want it in PL/SQL then:
DECLARE
items int_list := int_list(123455, 123456, 123457);
BEGIN
FOR row IN (
SELECT *
FROM my_table
WHERE value MEMBER OF items
)
LOOP
DBMS_OUTPUT.PUT_LINE( row.id || ', ' || row.value );
END LOOP;
END;
/
Which, for the same data, outputs:
2, 123455
3, 123456
4, 123457
db<>fiddle here
However, if you just want to connect two databases then setup a database link.
First of all, I know the question is vague, so feel free to edit it if you can describe it better.
There are some sets of table like TEST_201812, TEST_201901, etc. . I have another table that stores these values:
TEST_DATE:
ID DATE
1 201810
2 201811
3 201812
4 201901
Now what I want is to select the tables mentioned above (e.g.TEST_201812) by using TEST_DATE. I know it's wrong, but something like this:
select * from TEST_(select DATE from TEST_DATE where ID = 1)
Does anyone know how to achieve this?
Seriously, such a data model is a disaster. If you want to keep separate months separately, use one - partitioned - table.
Anyway, here's one option of how to do that:
Sample tables and a function that returns refcursor:
SQL> create table test_201812 as select * From dept;
Table created.
SQL> create table test_date (id number, datum number);
Table created.
SQL> insert into test_date values (1, 201812);
1 row created.
SQL> create or replace function f_test (par_id in test_date.id%type)
2 return sys_refcursor
3 is
4 l_datum test_date.datum%type;
5 l_str varchar2(200);
6 l_rc sys_refcursor;
7 begin
8 select datum
9 into l_datum
10 from test_date
11 where id = par_id;
12
13 l_str := 'select * from test_' || l_datum;
14 open l_rc for l_str;
15 return l_rc;
16 end;
17 /
Function created.
Testing:
SQL> select f_test(1) from dual;
F_TEST(1)
--------------------
CURSOR STATEMENT : 1
CURSOR STATEMENT : 1
DEPTNO DNAME LOC
---------- -------------- -------------
10 ACCOUNTING NEW YORK
20 RESEARCH DALLAS
30 SALES CHICAGO
40 OPERATIONS BOSTON
SQL>
I have PL/SQL function looking like:
FUNCTION get_agent_statistics ( id NUMBER
RETURN agent_stats_t
PIPELINED;
And I select from it (iBatis code):
SELECT * FROM table(pkg.get_agent_statistics(#id#))
How should I change this select if I'll remove PIPELINED statement from function?
If you'll get working compiled procedure without PIPELINED statement, you don't need to change your SELECT. See this - http://www.oracle-base.com/articles/misc/pipelined-table-functions.php
When you remove PIPELINED clause from the function declaration, function ceases to be a PIPELINED table function and as a result you will have to modify the body of the function to convert it to a TABLE function, if you still want to use it the from clause of the query, or a simple function, which you wont be able to use in the from clause of a query.
Addendum
Could I select something from non-pipelined function?
Yes, if you have a TABLE function, otherwise no. Here is a couple of examples:
-- prerequisites
SQL> create or replace type T_rows as object(
2 e_name varchar2(21),
3 e_lname varchar2(21)
4 )
5 /
Type created
SQL> create or replace type T_tab is table of t_rows
2 /
Type created
-- PIPELINED TABLE function
SQL> create or replace function GetEnames
2 return T_Tab
3 pipelined
4 is
5 l_etab t_tab := t_tab();
6 begin
7 for i in (select first_name
8 , last_name
9 from employees)
10 loop
11 pipe row(t_rows(i.first_name, i.last_name));
12 --l_etab.extend;
13 --l_etab(l_etab.last) := t_rows(i.first_name, i.last_name);
14 end loop;
15 return ;--l_etab;
16 end;
17 /
Function created
SQL> select *
2 from table(getenames)
3 where rownum <= 5;
E_NAME E_LNAME
--------------------- ---------------------
Steven King
Neena Kochhar
Lex De Haan
Alexander Hunold
Bruce Ernst
-- non-pipelined table function
SQL> create or replace function GetEnames
2 return T_Tab
3
4 is
5 l_etab t_tab := t_tab();
6 begin
7 for i in (select first_name
8 , last_name
9 from employees)
10 loop
11 --pipe row(t_rows(i.first_name, i.last_name));
12 l_etab.extend;
13 l_etab(l_etab.last) := t_rows(i.first_name, i.last_name);
14 end loop;
15 return l_etab;
16 end;
17 /
Function created
SQL> select *
2 from table(getenames)
3 where rownum <= 5;
E_NAME E_LNAME
--------------------- ---------------------
Steven King
Neena Kochhar
Lex De Haan
Alexander Hunold
Bruce Ernst
SQL>
I'm doing the following but it doesnt work
select package_name.function_name(param,param) from dual
I'm calling a function that returns a cursor so im guessing "from dual" is the problem
is there another way of doing it?
I presume you mean a Ref Cursor. This is a PL/SQL construct which acts as a pointer to a set of records returned by a query. This means it has to be interpreted by the client which runs the query. For instance, we can map a Ref Cursor to a JDBC or ODBC ResultSet.
There is certainly nothing wrong with your basic statement. Here is a function similar to your own:
SQL> desc get_emps
FUNCTION get_emps RETURNS REF CURSOR
Argument Name Type In/Out Default?
------------------------------ ----------------------- ------ --------
P_DNO NUMBER(2) IN
P_SORT_COL VARCHAR2 IN DEFAULT
P_ASC_DESC VARCHAR2 IN DEFAULT
SQL>
I can easily call this in a wider PL/SQL block:
SQL> declare
2 rc sys_refcursor;
3 begin
4 rc := get_emps(50);
5 end;
6 /
PL/SQL procedure successfully completed.
SQL>
However, SQL*PLus can handle CURSOR constructs natively:
SQL> select get_emps(50) from dual
2 /
GET_EMPS(50)
--------------------
CURSOR STATEMENT : 1
CURSOR STATEMENT : 1
EMPNO ENAME JOB MGR HIREDATE SAL COMM DEPTNO
---------- ---------- --------- ---------- --------- ---------- ---------- ----------
8060 VERREYNNE PLUMBER 8061 08-APR-08 4000 50
8061 FEUERSTEIN PLUMBER 7839 27-FEB-10 4500 50
8085 TRICHLER PLUMBER 8061 08-APR-10 3500 50
8100 PODER PLUMBER 8061 3750 50
SQL>
This statement also runs in SQL Developer, although the result set is laid out in an ugly fashion.
So, if you are having problems with your function, the questions are:
What client environment are you using?
In what precise fashion does it "not work"? Please describe the observed behaviour, including any error messages?
Also give us environment details such as the version of the database, the OS, etc.
Having read your other question on this topic I thought the problem might be due to the use of a User-Defined Ref Cursor (rather than the built-in). However, that doesn't make any difference. This packaged function:
SQL> create or replace package emp_rc_utils as
2
3 type emp_rc is ref cursor return emp%rowtype;
4
5 function get_emps
6 ( p_dno in emp.deptno%type
7 )
8 return emp_rc;
9 end;
10 /
Package created.
SQL> create or replace package body emp_rc_utils as
2
3 function get_emps
4 ( p_dno in emp.deptno%type
5 )
6 return emp_rc
7 is
8 return_value emp_rc_utils.emp_rc;
9 begin
10
11 open return_value for select * from emp where deptno = p_dno;
12
13 return return_value;
14 end get_emps;
15
16 end emp_rc_utils;
17 /
Package body created.
SQL>
Still works...
SQL> declare
2 rc sys_refcursor;
3 begin
4 rc := emp_rc_utils.get_emps(50);
5 end;
6 /
PL/SQL procedure successfully completed.
SQL> select emp_rc_utils.get_emps(50) from dual
2 /
EMP_RC_UTILS.GET_EMP
--------------------
CURSOR STATEMENT : 1
CURSOR STATEMENT : 1
EMPNO ENAME JOB MGR HIREDATE SAL COMM DEPTNO
---------- ---------- --------- ---------- --------- ---------- ---------- ----------
8085 TRICHLER PLUMBER 8061 08-APR-10 3500 50
8060 VERREYNNE PLUMBER 8061 08-APR-08 4000 50
8061 FEUERSTEIN PLUMBER 7839 27-FEB-10 4500 50
8100 PODER PLUMBER 8061 3750 50
SQL>
You can do this via a refcursor call or populate a user defined table and return it as follows:
create or replace
function getRef return sys_refcursor
is
l_ref sys_refcursor;
begin
open l_ref for
select 1 a, 'a' c from dual
union all
select 2 a, 'b' c from dual
union all
select 3 a, 'c' c from dual
union all
select 4 a, 'd' c from dual;
return l_ref;
end getRef;
/
select getref() from dual;
GETREF()
--------
A C
---------------------- -
1 a
2 b
3 c
4 d
--you'll notice this isn't the most user-friendly result set if you look at it in SQL Developer or whatno
--drop function getRef;
you can also use the 'table' if you are passing back a table collection as such
create or replace type lookup_row as
object ( a number, c varchar2(20) );
/
create or replace type lookups_tab as
table of lookup_row;
/
create or replace
function getUserDefinedTableType return lookups_tab
is
lTestTypeTable lookups_tab;
begin
SELECT lookup_row(a,c)
bulk collect INTO lTestTypeTable
from
(select 1 a, 'a' c from dual
union all
select 2 a, 'b' c from dual
union all
select 3 a, 'c' c from dual
union all
select 4 a, 'd' c from dual);
return lTestTypeTable;
end getUserDefinedTableType;
/
select * from table(getUserDefinedTableType());
--this returns it in a more user friendly manner
--http://www.oreillynet.com/pub/a/network/2003/01/22/feuerstein.html?page=2
--http://stackoverflow.com/questions/3150137/converting-oracle-query-into-user-defined-types-in-pl-sql/3152885#3152885
A C
---------------------- --------------------
1 a
2 b
3 c
4 d
have you tried:
myCursor := package_name.function_name(param,param);
this would have to be from within a test block or a stored procedure.