SolidWorks API (VBA) To store String in array - vba

Question

I want to store the dimension name (string) in the form of the array so that I can compare another array (dimension name) to the current.
Public Sub WhateverName
Dim swApp As SldWorks.SldWorks
Dim swModel As ModelDoc2
Dim swPart As PartDoc
Dim swFeat As Feature
Dim swDispDim As DisplayDimension
Dim swDim As Dimension
Dim vDimVals As Variant
Dim swDimInfoNameArr As Variant
Dim SKETCH_NAME As String
Dim i As Variant
Dim swDimName As Variant
Dim swDispDimname As String
Set swApp = Application.SldWorks
Set swModel = swApp.ActiveDoc
Set swPart = swModel
SKETCH_NAME = "ISO Standard"
Set swFeat = swPart.FeatureByName(SKETCH_NAME)
Set swDispDim = swFeat.GetFirstDisplayDimension
Do While Not swDispDim Is Nothing
i = 0
'For i = 0 To 4
Set swDim = swDispDim.GetDimension2(Empty)
vDimVals = swDim.GetValue3(swThisConfiguration, Empty)
Debug.Print swDim.Name & "#" & SKETCH_NAME & ": " & Round(vDimVals(0), 6)
Set swDispDim = swFeat.GetNextDisplayDimension(swDispDim)
swDimName = swDim.Name
swDimInfoNameArr(i) = swDimName 'swModel.GetCustomInfoNames2 --> ERROR
i = i + 1
'Next
Loop
End Sub
27th line is throwing the error "Type Mismatch"

Answer 1

You need to declare the size of the array, or use an other object to store. Like a dictionnary:
Option Explicit
Sub main()
Dim swApp As SldWorks.SldWorks
Dim swModel As ModelDoc2
Dim swPart As PartDoc
Dim swFeat As Feature
Dim swDispDim As DisplayDimension
Dim swDim As Dimension
Dim vDimVals As Variant
Dim SKETCH_NAME As String
Dim dict As Object
Set dict = CreateObject("Scripting.Dictionary")
Set swApp = Application.SldWorks
Set swModel = swApp.ActiveDoc
Set swPart = swModel
SKETCH_NAME = "ISO Standard"
Set swFeat = swPart.FeatureByName(SKETCH_NAME)
Set swDispDim = swFeat.GetFirstDisplayDimension
Do While Not swDispDim Is Nothing
Set swDim = swDispDim.GetDimension2(Empty)
vDimVals = swDim.GetValue3(swThisConfiguration, Empty)
Set swDispDim = swFeat.GetNextDisplayDimension(swDispDim)
dict.Add swDim.Name, Round(vDimVals(0), 6)
Debug.Print dict.keys()(dict.Count - 1) & "#" & SKETCH_NAME & ": " & dict.Items()(dict.Count - 1)
Loop
End Sub