How do I check to see if a BST works in SML? - binary-search-tree

Question

Heyo! I'm trying to construct a Binary Search Tree in SML, and I want to check to see if it correctly constructs a tree. I think the code I have is correct as it does compile without any errors, but without a function to check, I can't be sure. I have a provided checker in my textbook, but I don't know how to apply it to the Binary Search Tree. Here's my code:
datatype 'data tree =
Empty
| Node of 'data tree * 'data * 'data tree;
fun makeBST nil L = Empty
| makeBST (a::b) L =
let
fun insert Empty a = Node(Empty,a,Empty)
| insert (Node(left, root, right)) a =
if L(a, root) then
Node(insert left a, root, right)
else
Node(left, root, insert right a)
in
insert (makeBST b L) a
end;
And here is the checker code:
fun isintree x Empty = false
| isintree x (Node(left,y,right)) =
x = y orelse isintree x left orelse isintree x right;

Answer 1

That's not a very good checker, since it doesn't check the ordering of the tree, or that all the elements you added are in there, or that nothing you didn't add is there.
Let's start with verifying that the tree really is a search tree.
A binary tree is a search tree if and only if
it is empty, or
both its subtrees are search trees, and
all nodes in the left subtree are ordered before its element, and
all nodes in the right subtree are ordered after its element
In order to check whether a predicate holds for all nodes of a tree, we can use
fun all_tree Empty _ = true
| all_tree (Node (l, x, r)) pred = pred x
andalso all_tree l pred
andalso all_tree r pred
and then we can define
fun is_search_tree order Empty = true
| is_search_tree order (Node (l, x, r)) = is_search_tree order l
andalso is_search_tree order r
andalso all_tree l (fn y => order(y, x))
andalso all_tree r (fn y => order(x, y));
Next, we can check completeness by verifying that
All elements in the list are in the tree, and
all elements in the tree are in the list
Putting it all together:
(* This argument order makes this function more usable -
you're more likely to want to look up different values in
the same tree than the same value in different trees.*)
fun isintree Empty _ = false
| isintree (Node(left,y,right)) x =
x = y
orelse isintree left x
orelse isintree right x;
fun test_list order ls =
let val t = makeBST ls order
in
is_search_tree order t
andalso all_tree t (fn x => List.exists (fn y => x = y) ls)
andalso List.all (isintree t) ls
end;
Test:
- test_list op< [];
val it = true : bool
- test_list op< [1];
val it = true : bool
- test_list op< [1,2,3];
val it = true : bool
- test_list op< [3,2,1];
val it = true : bool
- test_list op> [1,2,3];
val it = true : bool
- test_list op< [1,1];
val it = false : bool
Oops. What happened?
- makeBST [1,1] op<;
val it = Node (Empty,1,Node (Empty,1,Empty)) : int tree
There are duplicates in the tree.
Fixing this left as an exercise.

Answer 2

After loading the program, you can try the following commands in REPL:
- val bst = makeBST [2,6,5,4,3] op <;
val bst = Node (Node (Empty,2,Empty),3,Node (Empty,4,Node #)) : int tree
- isintree 4 bst;
val it = true : bool
- isintree 5 bst;
val it = true : bool
- isintree 10 bst;
val it = false : bool