Printing the Name of Dictionaries inside a Collection - vba

Question

I have created a collection which consists of several dictionaries.
As I try to loop through the collection to print the names of the dictionaries, I get the following error message: 450 - Wrong number of arguments or invalid property argument.
My code reads as follows:
First, create the individual dictionaries and add the data to them:
Dim Cows, Dogs, Goats As Object
Set Cows = CreateObject("scripting.dictionary")
Set Dogs = CreateObject("scripting.dictionary")
Set Goats = CreateObject("scripting.dictionary")
[...Load the dictionaries with the data...]
Once this is done, create the collection of dictionaries and start to loop through it to see the names of each dictionary (the result should give us "Cows, Dogs, Goats" in the immediate window):
Dim TotalAnimals As New Collection
TotalAnimals.Add Cows
TotalAnimals.Add Dogs
TotalAnimals.Add Swans
Here lies the problem:
Dim AnimalType As Variant
For Each AnimalType In TotalAnimals
Debug.Print AnimalType
Next AnimalType
Any help would be greatly appreciated!!

Answer 1

What you are trying to achieve is called 'Reflection'. Unfortunately, the VBA language does not have reflection so you cannot directly achieve what you want.
You could emulate what you want using a 'wrapper' class to allow a name to be associated with a specific dictionary.
The example below implements a simple wrapper class which allows the name to be set, but not changed, and exposes the scripting.dictionary via the Host property.
Class AnimalType
Option Explicit
Private Type Properties
Name As String
Host As Scripting.Dictionary
End Type
Private p As Properties
Private Sub Class_Initialize()
Set p.Host = New Scripting.Dictionary
End Sub
Public Property Get Name() As String
Name = p.Name
End Property
Public Property Let Name(ByVal ipName As String)
If VBA.Len(p.Name) = 0 Then
p.Name = ipName
Else
Err.Raise 17 ' Can't perform the requested action
End If
End Property
Public Property Get Host() As Scripting.Dictionary
Set Host = p.Host
End Property
Thus
Dim Cows, Dogs, Goats As Object
Set Cows = CreateObject("scripting.dictionary")
Set Dogs = CreateObject("scripting.dictionary")
Set Goats = CreateObject("scripting.dictionary")
would become
Edited 30 Jan 2020 to correct the code below
Dim Cows as AnimalType
Dim Dogs as AnimalType
Dim Goats as AnimalType
Set Cows = new AnimalType
Cows.name="Cows"
Set Dogs = New AnimalType
Dogs.Name="Dogs"
Set Goats = New AnimalType
Goats.Name="Goats"
and then
Dim myAnimalType As Variant
For Each myAnimalType In TotalAnimals
Debug.Print myAnimalType.Name
Next

Answer 2

Please adapt your code in the next way. You can give to the dictionary a Name (in fact a Collection key) when add it to Collection:
Sub testDictNameInCollection()
Dim Cows As Object, Dogs As Object, Goats As Object
Dim TotalAnimals As New Collection, i As Long, arrK
Set Cows = CreateObject("scripting.dictionary")
Set Dogs = CreateObject("scripting.dictionary")
Set Goats = CreateObject("scripting.dictionary")
'load here the dictionaries...
TotalAnimals.Add Cows, "Cows"
TotalAnimals.Add Dogs, "Dogs"
TotalAnimals.Add Goats, "Goats"
arrK = Array("Cows", "Dogs", "Goats")
For i = 0 To UBound(arrK)
Debug.Print TotalAnimals.item(arrK(i)).count
Next i
TotalAnimals.item("Cows").Add "Cow 1 ", "a lot of milk"
Debug.Print TotalAnimals("Cows").Items()(TotalAnimals("Cows").count - 1) 'last item of the "Cow" dictionary
End Sub
Since Scripting.Dictionary does not expose a Name property, you can use a class able to wrap a name, in order to use the object and its name:
Copy the next code in a class and name it "AnimalClass":
Option Explicit
Private dictName As String
Private dict As Object
Private Sub Class_Initialize()
Set dict = CreateObject("Scripting.Dictionary")
End Sub
Public Property Get Name() As String
Name = dictName
End Property
Public Property Let obj(dic As Object)
Set dict = dic
End Property
Public Property Let Name(strName As String)
dictName = strName
End Property
Public Property Get obj() As Object
Set obj = dict
End Property
Copy the next code in a standard module:
Sub testDictionaryName()
Dim Cows As Object, Dogs As Object, Goats As Object, i As Long
Dim TotalAnimals As New Collection, animT As AnimalClass
Set animT = New AnimalClass
Set Cows = CreateObject("scripting.dictionary")
For i = 1 To 2: Cows(i) = "Cows " & i: Next i 'load the dictionary
animT.obj = Cows: animT.Name = "Cows"
TotalAnimals.Add animT 'add the class in Collection
Set animT = New AnimalClass
Set Dogs = CreateObject("scripting.dictionary")
For i = 1 To 3: Dogs(i) = "Dog " & i: Next i
animT.obj = Dogs: animT.Name = "Dogs"
TotalAnimals.Add animT
Set animT = New AnimalClass
Set Goats = CreateObject("scripting.dictionary")
For i = 1 To 4: Goats(i) = "Goat " & i: Next i
animT.obj = Goats: animT.Name = "Goats"
TotalAnimals.Add animT
Dim myAnimalType As Variant
For Each myAnimalType In TotalAnimals
Debug.Print myAnimalType.Name, myAnimalType.obj.count, myAnimalType.obj.Items()(myAnimalType.obj.count - 1)
Next
End Sub