How to output a value channel that has paths using Nextflow - nextflow

Question

Say one has some process that outputs files (e.g., converting sam to bam files) and one wants the output of the process to be a value channel so that it can be reused many times. Can one do this during the output of the channel? Or, does one have to call an operator (first?) on the queue channel after it has been output and that process completed?
Here is an example:
process sam2bam {
input:
path samfile from alignments
output:
path '*sorted.bam' into sam2bam //CAN THIS BE A VALUE CHANNEL
script:
"""
samtools view -b -o ${samfile}.bam ${samfile}
"""
}
So far, I have output the queue channel and then either duplicated it or tried to convert it to a value channel via first. This seems clunky and I figure there must be some way to directly output a value channel that has paths. I can't seem to find a simple answer in the documentation.
Thanks!

Answer 1

Ultimately this depends on if the 'alignments' channel is already a value channel or not:
A value channel is implicitly created by a process when an input
specifies a simple value in the from clause. Moreover, a value channel
is also implicitly created as output for a process whose inputs are
only value channels.
Note that this will create a queue channel:
alignments = Channel.fromPath( 'test.sorted.sam' )
And this will create a value channel:
alignments = file( 'test.sorted.sam' )
So if the 'alignments' channel is a value channel, the downstream 'sam2bam' channel will also be a value channel. If the 'alignments channel' is indeed a queue channel, then yes, you'll need to use one of the channel operators that returns a single value, such as first, last, collect, count, min, max, reduce, sum. The one you want is almost always collect.
Note that you may also be able to use the each input repeater to repeat the execution of a process for each item in a collection. Not sure what your downstream code looks like, but something like this might be convenient:
alignments = Channel.fromPath( '*.sorted.sam' )
chromosomes = Channel.of(1..23, 'X', 'Y')
process sam2bam {
input:
path samfile from alignments
output:
path "${samfile.baseName}.bam" into sam2bam
"""
touch "${samfile.baseName}.bam"
"""
}
process do_something {
echo true
input:
path bam from sam2bam
each chrom from chromosomes
"""
echo "${chrom}: ${bam}"
"""
}