VB.NET dynamic controls deployment - vb.net

Question

Below is a well working VBA code adding controls to whatever object admitting them while drawing the data from a db table. This works so well coz here I have an .Add method admitting 2 string variables defining control type and name. Cannot find anything like that on VB.Net. I can only make separate procedures for each control type. This code is not usable because I cannot build a MSForms.UserForm in abstracto. It must have a prototype build with form designer, while this on VS does not build MSForms.UserForms, but System.Windows.Forms only.
Any solution apart from making my own procedure with plenty of Selects, Ifs and similar? This still worked in VB.6 - there are historical solutions on the WEB and on this platform.
Function formFill(obj As Object, strSQL As String) As String
Dim rs As ADODB.Recordset, cntr As MSForms.Control, c As String
c = ""
On Error GoTo formFill_err
Set rs = ui_cnt.Execute(strSQL)
Do While Not rs.EOF
Set cntr = obj.Controls.Add("Forms." + rs("obj_type") + ".1", rs("obj_name"), True)
cntr.Height = rs("Height")
If Left(cntr.Name, 3) = "lbl" And cntr.Height > 32 Then cntr.WordWrap = True
cntr.Left = rs("Left")
cntr.Top = rs("Top")
cntr.Width = rs("Width")
cntr.Caption = str_convert_null(rs("caption"))
cntr.ControlTipText = str_convert_null(rs("tip"))
cntr.Font.Size = 8
cntr.Visible = True
If Left(cntr.Name, 3) = "txt" Then
cntr.AutoSize = False
Else
cntr.AutoSize = True
End If
c = c + rs("obj_type") + ";" + rs("obj_name") + ";"
rs.MoveNext
Loop
Set rs = Nothing
formFill = c
Exit Function
formFill_err:
If Err.Number = 438 Then Resume Next
End Function

Answer 1

Here's a sample how to create controls in Windows Form.
First, declare a container for your control setup. This is a class which replaces your ADODB.Recordset object.
Public Class MyControl
Public Property obj_type As String
Public Property obj_name As String
Public Property Top As Integer
Public Property Left As Integer
Public Property Height As Integer
Public Property Width As Integer
Public Property caption As String
Public Property tip As String
End Class
Here's a function which return an array of the class I defined before. I hardcoded the values (2 labels and 1 textbox), but you can also fetch the values from other sources like tables in database. You can replace the content of this function with any database technology for .Net, eg. ADO.Net or Entity Framework (EF).
Private Function GetMyControls() As MyControl()
Return {
New MyControl With {
.obj_type = "System.Windows.Forms.Label",
.obj_name = "lblLabel1",
.Top = 20,
.Left = 20,
.Height = 30,
.Width = 100,
.caption = "Label 1 caption",
.tip = "Label 1 tooltip"
},
New MyControl With {
.obj_type = "System.Windows.Forms.Label",
.obj_name = "lblLabel2",
.Top = 60,
.Left = 20,
.Height = 100,
.Width = 100,
.caption = "Lorem ipsum dolor sit amet, consectetur adipiscing elit, sed do eiusmod tempor incididunt ut labore et dolore magna aliqua.",
.tip = "Label 2 tooltip"
},
New MyControl With {
.obj_type = "System.Windows.Forms.TextBox",
.obj_name = "txtTextbox1",
.Top = 200,
.Left = 20,
.Height = 500,
.Width = 500,
.caption = "abcdef",
.tip = "Textbox 1 tooltip"
}
}
End Function
Then create each control from the setup then add it into the form's control collections.
Private Sub BuildMyControls()
'get controls setup
Dim myControls = GetMyControls()
For Each myControl In myControls
'get control type
Dim myControlType = GetType(Control).Assembly.GetType(myControl.obj_type)
'create control
Dim cntr As Control = Activator.CreateInstance(myControlType, True)
'setting properties
With cntr
.Name = myControl.obj_name
.Top = myControl.Top
.Left = myControl.Left
.Height = myControl.Height
.Width = myControl.Width
.Text = myControl.caption
.Font = New Font(.Font.Name, 8.0F, FontStyle.Regular)
End With
'add an event handler (optional), uncomment the if statement if you want to do it for labels only
'If myControl.obj_type = "System.Windows.Forms.Label" Then
AddHandler cntr.Click, AddressOf MyControl_Click
'End If
'add new control into form's control collection
Me.Controls.Add(cntr)
Next
End Sub
Put the control creating method in the form's load event.
Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
BuildMyControls()
End Sub
Last is optional, I add an event handler for the control click event. This method is called in the control creating method above.
Private Sub MyControl_Click(ByVal sender As System.Object, ByVal e As System.EventArgs)
Dim cntr = DirectCast(sender, Control)
'old version (formatted string)
'Dim message = String.Format("You clicked a {0} named {1}", cntr.GetType, cntr.Name)
'new version (interpolated string)
Dim message = $"You clicked a {cntr.GetType} named {cntr.Name}"
MessageBox.Show(message)
End Sub
Full code:
Public Class Form1
Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
BuildMyControls()
End Sub
Private Sub MyControl_Click(ByVal sender As System.Object, ByVal e As System.EventArgs)
Dim cntr = DirectCast(sender, Control)
'old version (formatted string)
'Dim message = String.Format("You clicked a {0} named {1}", cntr.GetType, cntr.Name)
'new version (interpolated string)
Dim message = $"You clicked a {cntr.GetType} named {cntr.Name}"
MessageBox.Show(message)
End Sub
Private Sub BuildMyControls()
'get controls setup
Dim myControls = GetMyControls()
For Each myControl In myControls
'get control type
Dim myControlType = GetType(Control).Assembly.GetType(myControl.obj_type)
'create control
Dim cntr As Control = Activator.CreateInstance(myControlType, True)
'setting properties
With cntr
.Name = myControl.obj_name
.Top = myControl.Top
.Left = myControl.Left
.Height = myControl.Height
.Width = myControl.Width
.Text = myControl.caption
.Font = New Font(.Font.Name, 8.0F, FontStyle.Regular)
End With
'add an event handler (optional), uncomment the if statement if you want to do it for labels only
'If myControl.obj_type = "System.Windows.Forms.Label" Then
AddHandler cntr.Click, AddressOf MyControl_Click
'End If
'add new control into form's control collection
Me.Controls.Add(cntr)
Next
End Sub
Private Function GetMyControls() As MyControl()
Return {
New MyControl With {
.obj_type = "System.Windows.Forms.Label",
.obj_name = "lblLabel1",
.Top = 20,
.Left = 20,
.Height = 30,
.Width = 100,
.caption = "Label 1 caption",
.tip = "Label 1 tooltip"
},
New MyControl With {
.obj_type = "System.Windows.Forms.Label",
.obj_name = "lblLabel2",
.Top = 60,
.Left = 20,
.Height = 100,
.Width = 100,
.caption = "Lorem ipsum dolor sit amet, consectetur adipiscing elit, sed do eiusmod tempor incididunt ut labore et dolore magna aliqua.",
.tip = "Label 2 tooltip"
},
New MyControl With {
.obj_type = "System.Windows.Forms.TextBox",
.obj_name = "txtTextbox1",
.Top = 200,
.Left = 20,
.Height = 500,
.Width = 500,
.caption = "abcdef",
.tip = "Textbox 1 tooltip"
}
}
End Function
End Class
Public Class MyControl
Public Property obj_type As String
Public Property obj_name As String
Public Property Top As Integer
Public Property Left As Integer
Public Property Height As Integer
Public Property Width As Integer
Public Property caption As String
Public Property tip As String
End Class
I don't write code for the wordwrap, autosize and tooltip.