Getting Web Element Using VBA - vba

Question

I can't seem to return the web element using this function. Any help would be appreciated.
Function scrape2(id As String)
Set objhttp1 = New WinHttp.WinHttpRequest
Dim doc1 As MSHTML.HTMLDocument
objhttp1.Open "GET", "https://www.axie.tech/axie-pricing/" & id, True
objhttp1.send
Set doc1 = New MSHTML.HTMLDocument
doc1.body.innerHTML = objhttp1.responseText
Set Result = doc1.FindElementByClass("axie-pricing_decodedGenesCapsule__m9R-C")
scrape2 = doc1.Text
End Function
Function Input: 373595
Expected Result:
D
R1
R2
Telescope
Telescope
Sleepless
Sakura
Pink Cheek
Curly
Anemone
Sponge
Blue Moon
Piranha
Piranha
Lam
Lagging
Scaly Spear
Teal Shell
Koi
Nimo
Snake Jar

Answer 1

doc1 is an MSHTML.HTMLDocument instance which does not have a FindElementByClass method. Nor a .text property of any nodes within the DOM. The method you are referencing is one from Selenium Type class where you have an instance of WebDriver.
Then there a variety of other issues. What you see on the page is dynamically rendered, and the data you want comes from XHR POST requests using graphql queries that return JSON. You would need to formulate those requests and use a JSON parser, such as in my example below, on the results.
Also, use Option Explicit, declare all your variables, use meaningful names and make the request synchronous by passing False in the .Open line.
parts is a collection of dictionaries you need to For Each over, then For Each Key, where Key is variant, over the .Keys of each dictionary.
Select the items you want. The key abilities returns a collection, so needs to be handled differently if used.
TODO:
R1 and R2 you need to use the parent ids and extract from requests for those ids info. The code below is for the child id and returns column D of your desired results.
data requests a lot more info that it seems you need so you could remove a lot of the parameters within it.
JSON library:
I use JsonConverter.bas. Download raw code from here and add to standard module called JsonConverter . Remove the top Attribute .... line from the copied code and Option Explicit if already specified.
You then need to go:
VBE > Tools > References > Add references to:
Microsoft Scripting Runtime
Microsoft HTML Object Library
Microsoft WinHTTP Services, version 5.1 Library (or your version).
In VBA for JSON the [] denotes a collection and the {} represents a dictionary.
VBA:
Option Explicit
Public Sub PrintGetAxieDetail()
Dim response As Object
Set response = GetAxieGeneDetail("5016162")
Debug.Print JsonConverter.ConvertToJson(response)
End Sub
Public Function GetAxieGeneDetail(ByVal id As String) As Object
Dim http As WinHttp.WinHttpRequest
Dim doc1 As MSHTML.HTMLDocument
Dim data As String
Set http = New WinHttp.WinHttpRequest
Set doc1 = New MSHTML.HTMLDocument
With http
.Open "POST", "https://axieinfinity.com/graphql-server-v2/graphql", False
.setRequestHeader "content-type", "application/json"
.setRequestHeader "user-agent", "Mozilla/5.0"
.setRequestHeader "referer", "https://www.axie.tech/"
.setRequestHeader "accept-language", "en-GB,en-US;q=0.9,en;q=0.8"
data = "{""operationName"":""GetAxieDetail"",""variables"":{""axieId"":""" & id & """},""query"":""query GetAxieDetail($axieId: ID!)" & _
"{\n axie(axieId: $axieId) {\n ...AxieDetail\n __typename\n }\n}\n\nfragment AxieDetail on Axie {\n id\n image" & _
"\n class\n chain\n name\n genes\n owner\n birthDate\n bodyShape\n class\n sireId\n sireClass\n matronId\n matronClass" & _
"\n stage\n title\n breedCount\n level\n figure {\n atlas\n model\n image\n __typename\n }" & _
"\n parts {\n ...AxiePart\n __typename\n }\n stats {\n ...AxieStats\n __typename\n }" & _
"\n auction {\n ...AxieAuction\n __typename\n }\n ownerProfile {\n name\n __typename\n }" & _
"\n battleInfo {\n ...AxieBattleInfo\n __typename\n }" & _
"\n children {\n id\n name\n class\n image\n title\n stage\n __typename\n }\n __typename" & _
"\n}\n\nfragment AxieBattleInfo on AxieBattleInfo {\n banned\n banUntil\n level\n __typename" & _
"\n}\n\nfragment AxiePart on AxiePart {\n id\n name\n class\n type\n specialGenes\n stage\n abilities" & _
"{\n ...AxieCardAbility\n __typename\n }\n __typename\n}\n\nfragment AxieCardAbility on AxieCardAbility" & _
"{\n id\n name\n attack\n defense\n energy\n description\n backgroundUrl\n effectIconUrl\n __typename\n}" & _
"\n\nfragment AxieStats on AxieStats {\n hp\n speed\n skill\n morale\n __typename\n}\n\nfragment AxieAuction on Auction" & _
"{\n startingPrice\n endingPrice\n startingTimestamp\n endingTimestamp\n duration\n timeLeft\n currentPrice" & _
"\n currentPriceUSD\n suggestedPrice\n seller\n listingIndex\n state\n __typename\n}\n""}"
.send data
Dim axieDetail As Object, geneResults As Object
Set axieDetail = JsonConverter.ParseJson(.responseText)
Set geneResults = axieDetail("data")("axie")("parts") 'this returns a collection to For Each over
Set GetAxieGeneDetail = geneResults
End With
End Function
Sample of JSON: