Using/Refresh relational dropdowns - vba

Question

I am trying to set up a dropdown that is dependent on the selection of a previous dropdown in Word using VBA-Code. I watched a bunch of videos and read through forums, but I cannot make it work. I used the Word Legacy dropdowns and labelled them correctly, then I wrote the following code in VBA:
Dim xDirection As FormField
Dim xState As FormField
On Error Resume Next
Set xDirection = ActiveDocument.FormFields("ddType")
Set xState = ActiveDocument.FormFields("ddSelection")
If ((xDirection Is Nothing) Or (xState Is Nothing)) Then Exit Sub
With xState.DropDown.ListEntries
.Clear
Select Case xDirection.Result
Case "Numbers"
.Add "1"
.Add "2"
.Add "3"
.Add "4"
.Add "5"
.Add "6"
Case "Letters"
.Add "A"
.Add "B"
.Add "C"
Case "None"
.Add "Not applicable"
End Select
End With
End Sub
The problem is that this solution only works sometimes and not consistently. It feels like the possible selections are not updated quick enough and I can choose a letter even if only numbers should be available (sometimes I am not able to select anything at all).
I do this in Office 365.
Feedback will be highly appreciated
Thank you in advance!

Answer 1

Assumption: you have a word document with two dropdown content controls.
For both the tag name is set: ccType and ccSelection.
In the class module of ThisDocument you put the following code:
Option Explicit
Private Sub Document_ContentControlOnExit(ByVal ContentControl As ContentControl, Cancel As Boolean)
If ContentControl.Tag = "ccType" Then
fillccSelection ContentControl.Range.Text
End If
End Sub
Private Sub fillccSelection(valueType As String)
Dim cc As ContentControl
Set cc = ThisDocument.SelectContentControlsByTag("ccSelection")(1)
If cc.Title <> valueType Then
With cc
.Title = valueType 'set title to current type so that we now if coming here next time
.Range.Text = vbNullString 'clear content as it has to change with new values
With .DropdownListEntries
.Clear
Select Case valueType
Case "Numbers"
cc.SetPlaceholderText Text:="Please select a number"
.Add "1"
.Add "2"
.Add "3"
Case "Letters"
cc.SetPlaceholderText Text:="Please select a letter"
.Add "A"
.Add "B"
.Add "C"
End Select
End With
End With
End If
End Sub
Whenever you change the value of the first content control (ccType) and exit it the ContentControlOnExit is fired.
If you "left" ccType (and not ccSelection) fillccSelection is called by passing the value selected in ccType.
If this type is not yet set for ccSelection, the dropdown entries are set according to the selected type.