Convert Excel to datatable without using Connection String? - vb.net

Question

Is there a way to convert an excel file into a datatable (without using connection string), so i can show it in a gridview? I already tried something, but I'm getting a System.NullReferenceException and i don't know why. Here's what i did:
If OpenFileDialog1.ShowDialog() = DialogResult.OK Then
If File.Exists(OpenFileDialog1.FileName) Then
If Path.GetExtension(OpenFileDialog1.FileName).ToString = ".xlsx" Then
Dim workbook As Workbook
Dim resourceName As String = "IGExcel.Resources." & OpenFileDialog1.FileName
Using stream As Stream = Me.GetType().Assembly.GetManifestResourceStream(resourceName)
Try
Workbook.Load(stream)
Catch ex As System.NullReferenceException
End Try
End Using
Dim dataTable As New DataTable
Dim sheet As Worksheet = workbook.Worksheets(0)
Dim serviceExcel
For Each row As WorksheetRow In sheet.Rows
serviceExcel = New ISAACServiceExcel()
serviceExcel.AufPos = row.Cells(0).Value.ToString()
serviceExcel.UANR = row.Cells(1).Value.ToString()
serviceExcel.K_Art = row.Cells(2).Value.ToString()
serviceExcel.Ueberbegriff = row.Cells(3).Value.ToString()
serviceExcel.Benennung = row.Cells(5).Value.ToString()
serviceExcel.Einheit = row.Cells(6).Value.ToString()
serviceExcel.Einzelkosten = row.Cells(7).ToString()
serviceExcel.Anzahl = row.Cells(8).ToString()
serviceExcel.Komponente = row.Cells(9).ToString()
serviceExcel.Projektbeteiligter = row.Cells(11).ToString()
serviceExcel.Chefblattposition = row.Cells(13).ToString()
serviceExcel.Total = row.Cells(15).ToString()
Next
dataTable = serviceExcel
dgv1.DataSource = dataTable

Answer 1

I will try to convince you that there is nothing to fear from connection strings. Three little functions here and you are displaying your data. I would bet it is somewhat faster than interop also.
Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
Dim XLPath = GetExcelPath()
If XLPath IsNot Nothing Then
Dim XLSheet = GetSheetName(XLPath)
Dim dt = ExcelToDataTable(XLPath, XLSheet)
DataGridView1.DataSource = dt
Else
MessageBox.Show("No acceptable file selected.")
End If
End Sub
Private Function GetExcelPath() As String
Dim XLPath As String
OpenFileDialog1.Filter = "Excel files (*.xlsx)|*.xlsx"
If OpenFileDialog1.ShowDialog() = DialogResult.OK Then
XLPath = OpenFileDialog1.FileName
Return XLPath
End If
Return Nothing
End Function
Private Function GetSheetName(path As String) As String
Dim sn As String
Dim dt As DataTable
Using cn As New OleDbConnection($"Provider=Microsoft.ACE.OLEDB.12.0;Data Source= {path};Extended Properties='Excel 12.0;HDR=YES;IMEX=1;';")
cn.Open()
dt = cn.GetOleDbSchemaTable(OleDbSchemaGuid.Tables, Nothing)
End Using
sn = dt(0)("Table_Name").ToString
Return sn
End Function
Private Function ExcelToDataTable(path As String, SheetName As String) As DataTable
Dim XLConStr = $"Provider=Microsoft.ACE.OLEDB.12.0;Data Source= {path};Extended Properties='Excel 12.0;HDR=YES;IMEX=1;';"
Dim dt As New DataTable
Using cn As New OleDbConnection(XLConStr),
cmd As New OleDbCommand($"Select * From [{SheetName}];", cn)
cn.Open()
Using reader = cmd.ExecuteReader
dt.Load(reader)
End Using
End Using
Return dt
End Function