How to use entries in a listA to refer other lists with names that have prefixes same as ListA's entries - scripting

Question

#Suppose i have a list name
set modules [list]
lappend modules moduleA
lappend modules moduleB
lappend modules moduleC
#and i have other list naming
set moduleA_sig [list]
lappend moduleA......
set moduleB_sig [list]
lappend moduleB_sig ....
set moduleC_sig [list]
lappend moduleC_sig ....
#How can I use my "modules" list entries to access though the other list, eg:
foreach mod $modules
{
llength ${mod}_sig
}

Answer 1

An alternative to using upvar is to use set <var_name> to retrieve the value of var_name. When <var_name> is ${mod}_sig, then you can use set to retrieve the value of the variable without the possibility of altering the value of the original variable (like upvar)
set modules {moduleA moduleB moduleC}
set moduleA_sig {1 2 3 4}
set moduleB_sig {11 22 33 44}
set moduleC_sig {111 222 333 444}
foreach mod $modules {
# Get the value of the variable named ${mod}_sig.
puts "$mod: [set ${mod}_sig]"
}

Answer 2

Another approach is to use an array (Or dict) to hold values instead of trying to compose variable names on the fly at runtime.
Array:
#!/usr/bin/env tclsh
set modules {moduleA moduleB moduleC}
set sig(moduleA) {1 2 3 4}
set sig(moduleB) {11 22 33 44}
set sig(moduleC) {111 222 333 444}
foreach mod $modules {
puts "$mod: $sig($mod)"
}
Or with a dict:
#!/usr/bin/env tclsh
set modules {moduleA moduleB moduleC}
dict set sig moduleA {1 2 3 4}
dict set sig moduleB {11 22 33 44}
dict set sig moduleC {111 222 333 444}
foreach mod $modules {
puts "$mod: [dict get $sig $mod]"
}

Answer 3

This is where you want the upvar command
to "alias" one variable to another.
set modules {moduleA moduleB moduleC}
set moduleA_sig {1 2 3 4}
set moduleB_sig {11 22 33 44}
set moduleC_sig {111 222 333 444}
foreach mod $modules {
upvar 0 ${mod}_sig this
puts [list $mod $this]
}
outputs
moduleA {1 2 3 4}
moduleB {11 22 33 44}
moduleC {111 222 333 444}
Here, use level 0 to indicate the current stack frame.
Any modifications you make to $this will be reflected in $moduleX_sig.
set x 42
upvar 0 x y
incr y
puts $x ;# => 43