Function that returns a query - sql

Question

This is the function :
create or replace function searchbyid (depto in departments.department_id%type)
return sys_refcursor
is result_s sys_refcursor;
begin
open result_s for
SELECT
a.employee_id,
a.first_name,
a.last_name,
a.phone_number,
a.salary,
b.department_id,
b.end_date
FROM
employees a
FULL JOIN job_history b ON a.department_id = b.department_id
WHERE b.department_id = depto;
return result_s;
end;
I'm getting the output in a single line, is it possible to get as a table?
FUNCTION OUTPUT :
Yes, I use SQL Developer

Answer 1

One option is to use ref cursor (as Abra commented). I don't have your tables so I used Scott's.
SQL> create or replace function searchbyid (par_deptno in dept.deptno%type)
2 return sys_refcursor
3 is
4 rc sys_refcursor;
5 begin
6 open rc for
7 select d.deptno, d.dname, e.ename, e.job, e.sal
8 from emp e join dept d on d.deptno = e.deptno
9 where d.deptno = par_deptno;
10
11 return rc;
12 end;
13 /
Function created.
SQL> select searchbyid(10) result from dual;
RESULT
--------------------
CURSOR STATEMENT : 1
CURSOR STATEMENT : 1
DEPTNO DNAME ENAME JOB SAL
---------- -------------- ---------- --------- ----------
10 ACCOUNTING CLARK MANAGER 2450
10 ACCOUNTING KING PRESIDENT 5000
10 ACCOUNTING MILLER CLERK 1300
SQL>
Another option is a pipelined function:
Types first:
SQL> create or replace type t_row as object
2 (deptno number,
3 dname varchar2(10),
4 ename varchar2(10),
5 job varchar2(10),
6 sal number
7 );
8 /
Type created.
SQL> create or replace type t_tab is table of t_row;
2 /
Type created.
Function:
SQL> create or replace function searchbyid (par_deptno in dept.deptno%type)
2 return t_tab pipelined
3 is
4 begin
5 for cur_r in (select d.deptno, d.dname, e.ename, e.job, e.sal
6 from emp e join dept d on d.deptno = e.deptno
7 where d.deptno = par_deptno
8 )
9 loop
10 pipe row (t_row(cur_r.deptno, cur_r.dname, cur_r.ename, cur_r.job, cur_r.sal));
11 end loop;
12 return;
13 end;
14 /
Function created.
SQL> select * from table(searchbyid(10));
DEPTNO DNAME ENAME JOB SAL
---------- ---------- ---------- ---------- ----------
10 ACCOUNTING CLARK MANAGER 2450
10 ACCOUNTING KING PRESIDENT 5000
10 ACCOUNTING MILLER CLERK 1300
SQL>
[EDIT, after you edited the question]
Screenshot shows how data look like when function returns ref cursor in SQL Developer. If you want to see it nicely, scroll far right and click the pencil icon; something like this:
(click on (1) to get result as (2))