On Column B I'm trying to get a TEXTJOIN with delimiter "," of INDEX MATCH to the price range you see on Table B. Because cell A5 contains "Apple" then "$$$" is one of the values I need, also A6 contains "Banana" then "$$" is the second value i need. Finally cell A7 contains "Pineapple" but because "$$$" is already was selected because of apple then no need to add it again.
Related
On cell B5 I'm trying to get a TEXTJOIN with delimiter "," of INDEX MATCH to the price range you see on Table B. Because cell A5 contains "Apple" then "$$$" is one of the values I need, also A5 contains "Banana" then "$$" is the second value i need. Finally cell A5 contains "Pineapple" but because "$$$" is already was selected because of apple then no need to add it again.
Any help will be much appreciated.
What would I do if instead of 1 cell like A5, I will have multiple rows like this:
What would I do if I have a SKU that has only some of the Fruits and I have to use the formula based on the SKU?
With Excel 365, you can do:
=TEXTJOIN(",", 1, UNIQUE( XLOOKUP( FILTERXML( "<m><s>" & SUBSTITUTE( [#Fruits], "|", "</s><s>" ) & "</s></m>", "//s" ),
TableB[Fruit], TableB[Price Range],0)) )
I want to fill empty cells with value from upper non-empty cells, ms excel have ctrl+d for doing that. but i want one step further I want to do multi hop ctrl+d.
For Example
A1, A3, A9, A25, A28 have some value and all other cells of column A are empty I want to fill cell A2 with value of A1,cells A4 to A8 with value of A3,cells A10 to A25 with value A9,cells A26 to A27 with value of A25
Other columns also have such empty cells and I want to fill them like I want for column A.
Folowing are images of sample excel:
I can fill the empty cells by grading cell down for each hop.
For given example I can fill cells by dragging down A1, A3, A9, A25, A28 each.
But I want to do that in one go because I have this type of empty cells and filled cells in between empty cell in thousands.
how can I do that?
Assuming the 1st table content is in A1:C15, put :
=IF(A2="",E1,A2) in E2
=IF(B2="",F1,B2) in F1
=IF(C2="",G1,C2) in G1
and drag downwards..
Hope it solves..
You might like this trick
Just use simple formula and Ctrl+Shift+V (Paste Special - Skip Empty Cells)
I have to create a macro which will:
Get the value from the cell A1 search this value in column C.
If the value in cell A1 exists in column C, the macro needs to be compare the value in cell B1 with values in column D.
If the value in cell A1 exists in column C AND the value in cell B1 exists in column D, then the text "Values found" should appear in cell E1.
The above needs to happen for all non empty rows in column A.
I was trying to use the following formula:
=IF(ISERROR(MATCH(A2,$C$2:$C$138,0)),"Load number not found","Load number found")
But it not working as I want. I have limited access to internet so I can't check all web sites. Would you please help me. Thanks a lot.
To check if A1 is in column C and if B1 is in column D (in the same row A1 was found in column C), then you need to do the following:
=IF(ISERROR(MATCH(A1,$C:$C,0)),"Load number not found",IF(B1=INDEX($D:$D,MATCH(A1,$C:$C,0),1),"Load number found","Load number not found"))
The first IF checks if A1 is in column C, the second IF checks if B1 is in column D (in the same row A1 was found in column C)
It will return "Load number found" only if both conditions are true. Otherwise it will return "Load number not found".
You can write a macro to do the same thing. But the easier way is to lock the cells in column E only and protect the sheet so that users will not accidentally change any of the formulas.
Update:
Since Column C can have duplicates, need to use the following array formula:
=IF(ISERROR(MATCH(1,(A1=$C:$C)*(B1=$D:$D),0)),"Load number not found","Load number found")
When you paste this formula to E1, make sure to press CTRL + Shift + Enter instead of just pressing the Enter key.
If I understand, a conventional solution with formulae is to concatenate your C and D column data and then search that. If you insert a new columnC with:
=D2&E2
copied down to suit you could apply (but say in ColumnF rather than ColumnE) your existing formula with only slight modification:
=IF(ISERROR(MATCH(A1&B1,$C$2:$C$138,0)),"Load number not found","Load number found")
subject to quite what is in which row.
Please see my image
I am have two questions:
Do you know what is the proper function to count number of rows that have F column value don't exist in range J3:J15 (expect result is 3, as the image)
List/or show values in Column A, B of above rows (the rows that have F column value don't existing)
Way №1
In cell H2 use:
=IF(ISNUMBER(MATCH(F2,$J$3:$J$15,0));"exist in list","not exist in list")
and drag it down.
Then in C12 you can use:
=COUNTIF(H2:H8;"not exist in list")
Way №2
In C12 use:
=SUMPRODUCT(1*NOT(ISNUMBER(MATCH($F$2:$F$8,$J$3:$J$15,0))))
This is an array formula, so type the formula then press CTRL+SHIFT+ENTER. Curly brackets will automatically appear at the start and end of the formula.
Then for returning list of corresponding values in column A use, say, in F12:
=IFERROR(INDEX(A:A,SMALL(IF(NOT(ISNUMBER(MATCH($F$2:$F$8,$J$3:$J$15,0))),ROW($F$2:$F$8)),ROW()-ROW($F$12)+1)),"")
this is also array formula, so press CTRL+SHIFT+ENTER to evaluate it and then drag formula down.
and in G12 for returning corresponding values from column B:
=IFERROR(INDEX(B:B,SMALL(IF(NOT(ISNUMBER(MATCH($F$2:$F$8,$J$3:$J$15,0))),ROW($F$2:$F$8)),ROW()-ROW($F$12)+1)),"")
also with array entry(CTRL+SHIFT+ENTER).
How we can get value from a cell in google spreadsheet?
I have row and column index from ROW() and COLUMN() - 1.
In other words what is the other way to do "=B1" i have row as 1 and column as 2.
Any suggestion, a single spreadsheet query. other than add function to spreadsheet.
Say the row number is in A1, and the column number is in A2, any of these should work:
=OFFSET(A1;A1-1;A2-1)
=INDIRECT("R"&A1&"C"&A2)
=INDEX(A1:400000;A1;A2)
To do so use indirect() as such:
=indirect("'PAGE ASD'!"&A2&A3)
where A2 contains the letters to column like "D" or "AA"
where A3 contains the number to row like "2" or "35"
and the page you are calling the data from is called "PAGE ASD"