Set second nested subform check box to true in Access VBA - vba

Question

I have a form that has Work Orders, PK=OrderID. A subform that has the OrderDetails, PK=OrderDetailsID. And a subform on that subform that has OrderDetailAccessories, PK=OrderAccID.
When I set a check box on the main form to True, I want all the check boxes for the subform OrderDetails to change to True and set the CompDate to todays date AND all the check boxes for it's subform OrderDetailsAccessories to change to True and set the CompDate to today's date.
In my code, the recordset rs returns the records expected but I get an empty recordset for rs2. I stepped through the code and orddetid returns the correct value.
Private Sub IsComplete_AfterUpdate()
Dim db As DAO.Database
Dim rs As DAO.Recordset
Dim rs2 As DAO.Recordset
Dim strItemComp As String
Dim strAccComp As String
Dim ordid As Long
Dim orddetid As Long
ordid = Me.txtOrdID
strItemComp = "SELECT OrderDetailID, IsComplete, CompDate FROM tblOrderDetails WHERE OrderID = " & ordid
strAccComp = "SELECT OrderAccID, IsComplete, CompDate FROM tblOrderAcc WHERE OrderDetailID = " & orddetid
Set db = CurrentDb
Set rs = db.OpenRecordset(strItemComp)
If Me.IsComplete = True Then
If MsgBox("Marking main order complete will mark ALL items and accessories for this Order as complete!", vbYesNo, "Are you sure?") = vbYes Then
Me!txtCompletionDate = Date
rs.MoveFirst
Do Until rs.EOF
If rs!IsComplete = False Then
rs.Edit
rs!IsComplete = True
rs!CompDate = Date
rs.Update
End If
orddetid = rs.Fields("OrderDetailID").Value
Debug.Print orddetid
Set rs2 = db.OpenRecordset(strAccComp)
If rs2.RecordCount > 0 Then
rs2.MoveFirst
Do Until rs2.EOF
If rs2!IsComplete = False Then
rs2.Edit
rs2!IsComplete = True
rs2!CompDate = Date
rs2.Update
End If
rs2.MoveNext
Loop
End If
rs.MoveNext
Loop
Me.Dirty = False
Exit Sub
Else
Me.Undo
End If
Else
Me.txtCompletionDate = Null
Exit Sub
End If
Me.Dirty = False
End Sub

Answer 1

You must update strAccComp for each record, something like:
If Me.IsComplete = True Then
If MsgBox("Marking main order complete will mark ALL items and accessories for this Order as complete!", vbYesNo, "Are you sure?") = vbYes Then
Me!txtCompletionDate = Date
Me.Dirty = False
Set rs = Me!NameOfSubformControl.Form.RecordsetClone
rs.MoveFirst
Do Until rs.EOF
If rs!IsComplete = False Then
rs.Edit
rs!IsComplete = True
rs!CompDate = Date
rs.Update
End If
strAccComp = "SELECT OrderAccID, IsComplete, CompDate FROM tblOrderAcc WHERE OrderDetailID = " & rs!orddetid.Value
Set rs2 = CurrentDb.OpenRecordset(strAccComp)
If rs2.RecordCount > 0 Then
rs2.MoveFirst
Do Until rs2.EOF
If rs2!IsComplete = False Then
rs2.Edit
rs2!IsComplete = True
rs2!CompDate = Date
rs2.Update
End If
rs2.MoveNext
Loop
End If
rs2.Close
rs.MoveNext
Loop
rs.Close
End If
End If