Saving as plain text - vba

Question

I have a code which guys on here helped me with.
This issue is it saves to a shared drive and the info in the cells is still linked to the master copy of the workbook. Is there way to save it as text and not a link?
Sub Sample()
Dim i As Long
Dim DateString As String
Dim wbName As String
If Val(Application.Version) < 12 Then
FileExtStr = ".xls": FileFormatNum = -4143
Else
Select Case ThisWorkbook.FileFormat
Case 51:
FileExtStr = ".xlsx": FileFormatNum = 51
Case 52:
If Application.ActiveWorkbook.HasVBProject Then
FileExtStr = ".xlsm": FileFormatNum = 52
Else
FileExtStr = ".xlsx": FileFormatNum = 51
End If
Case 56:
FileExtStr = ".xls": FileFormatNum = 56
Case Else:
FileExtStr = ".xlsb": FileFormatNum = 50
End Select
End If
'~~> Get file name without extension
wbName = Left(ThisWorkbook.Name, (InStrRev(ThisWorkbook.Name, ".", -1, vbTextCompare) - 1))
DateString = Format(Now, "yyyy-mm-dd hh-mm-ss")
'~~> Final folder path
FolderPath = "F:\Orders" & "\" & wbName
'~~> Check if folder exists. If it doesn't then create it
If Not FolderExists(FolderPath) Then MkDir FolderPath
'~~> Loop through the worksheets and save them
For i = 3 To 18
If ThisWorkbook.Sheets(i).Visible Then
RenameAndSaveSheet ThisWorkbook.Sheets(i)
End If
Next i
End Sub
Here is the renameandsave
Private Sub RenameAndSaveSheet(ws As Worksheet)
Dim FlName As String
Dim wbNew As Workbook
With ws
.Copy
.Name = .Range("B1").Value2
FlName = FolderPath & "\" & ws.Name & FileExtStr
Set wbNew = Application.Workbooks.Item(Application.Workbooks.Count)
wbNew.SaveAs FlName, FileFormat:=FileFormatNum
wbNew.Close False
End With
End Sub
Thanks for any help.

Answer 1

If you just want to break all the links make a Function that does that:
' Break all Excel Links found in given worksheet
Public Sub BreakAllLinks(ByVal thisWorkbook As Workbook)
Dim theseLinks As Variant
theseLinks = thisWorkbook.LinkSources(Type:=xlLinkTypeExcelLinks)
If Not IsEmpty(theseLinks) Then
Dim i As Long
For i = 1 To UBound(theseLinks)
thisWorkbook.BreakLink Name:=theseLinks(i), Type:=xlLinkTypeExcelLinks
Next i
End If
End Sub
Then you call that before you save it:
Public Sub RenameAndSaveSheet(ws As Worksheet)
Dim FlName As String
Dim wbNew As Workbook
With ws
.Copy
.Name = .Range("B1").Value2
FlName = FolderPath & "\" & .Name & FileExtStr
End With
Set wbNew = ActiveWorkbook
BreakAllLinks wbNew
wbNew.SaveAs FlName, FileFormat:=FileFormatNum
wbNew.Close False
End Sub