multilevel list without indentation in word vba - vba

Question

I have a macro that search [#] in document and make it list number, with multilevel. Each hashtag represent level number. i.e
[#] level 1 - - result - -> 1.
[##] level 2 -- result --> 1.1.
[###] level 3 -- result --> 1.1.1.
So it's working just fine. But I don't want my text to get indented instead remain in their indent level. as my text is in table so its get crazy when indented.
working code is here:
Sub Nummerierung_Numeric()
'Makro Written by M.B.A
Dim Level As Integer
With ActiveDocument.Range.Find 'or Selection.Range.Find
.Text = "\[#*\]"
.MatchWildcards = True
Do While .Execute
If .Parent.Information(wdWithInTable) Then
Level = Len(.Parent.Text) - 2
.Parent.Style = ActiveDocument.Styles("1 / 1.1 / 1.1.1")
.Parent.ListFormat.ListLevelNumber = Level
.Parent.Delete
End If
Loop
.MatchWildcards = False
End With
End Sub

Answer 1

You can modify the 1 / 1.1 / 1.1.1 style setting such that any paragraph using this style will not have indent but note that this might affect paragraphs that you might want the indentation (in this case you will need to define a new style for this purpose):
Const newNumPos As Long = 0
Const newTextPos As Long = 18 'Change as required, this is the Text Indent (in Points)
With ActiveDocument.Styles("1 / 1.1 / 1.1.1").ListTemplate
.ListLevels(1).TextPosition = newTextPos
.ListLevels(1).NumberPosition = newNumPos
.ListLevels(2).TextPosition = newTextPos
.ListLevels(2).NumberPosition = newNumPos
.ListLevels(3).TextPosition = newTextPos
.ListLevels(3).NumberPosition = newNumPos
End With