Target existing IE window tab using VBA - vba

Question

I'm trying to target an existing IE window (one tab only) with my script.
In other words: there's an Internet Explorer window opened with a specific tab and I'm trying to get my script to target that tab using its tab name.
I had a look at these topics, but none worked for me (or I did it wrong):
Get existing IE via VBA
Navigate to new URL in existing Internet Explorer window
VBA Macro For Already Open IE Window
Therefore I created this (which worked for a while until I got a 438 Error for no reason) :
Sub FindingExistingIE()
Dim Application As Object
Dim ApplicationWindows As Object
Dim WindowTitle As Variant
Dim TargetWindow As Object
Set Application = CreateObject("Shell.Application")
Set ApplicationWindows = Application.Windows
For Each Application In ApplicationWindows
WindowTitle = Application.Document.Title
If WindowTitle Like "IE Window Title" Then
Set TargetWindow = Application
Exit For
End If
Next Application
NextSub TargetWindow
End
End Sub
As I said, the script worked fine for a week but now I get the 438 error:
Object doesn't support this property or method (Error 438)
The error highlights the following line:
WindowTitle = Application.Document.Title
Having read the Microsoft Doc related to the error, I tried changing the WindowTitle variable to an object. Didn't work.
Does anyone have an idea?
Thanks!

Answer 1

This works for me - finds IE by looking for an open window with the passed URL:
Sub tester()
Dim w As Object
Set w = FindingExistingIEByUrl("https://www.google.com")
If Not w Is Nothing Then
MsgBox w.document.Title
Else
MsgBox "No IE window found"
End If
End Sub
Function FindingExistingIEByUrl(theUrl)
Dim w As Object
For Each w In CreateObject("Shell.Application").Windows
'Debug.Print w.locationurl
If w.locationurl Like theUrl & "*" Then
Set FindingExistingIEByUrl= w
Exit Function
End If
Next w
End Function
Function FindingExistingIEByTitle(theTitle)
Dim w As Object, t As String
For Each w In CreateObject("Shell.Application").Windows
t = ""
On Error Resume Next 'ignore error if no Document
t = w.Document.Title
On Error Goto 0
If t Like theTitle Then
Set FindingExistingIEByTitle = w
Exit Function
End If
Next w
End Function