Is there a way to shorten these PictureBox Subs? - vb.net

Question

I have 9 PictureBoxes on my form. Every single PictureBox got its own DoubleClick event handler. I haven't yet found a way to combine these 9 subs into one; especially because the bitmap list (List(Of System.Drawing.Bitmap)) must have a different number of .count.
If you click on a PictureBox, only code for this should be executed.
Private Sub PictureBox1_DoubleClick(sender As Object, e As EventArgs) Handles PictureBox1.DoubleClick
If BitmapList IsNot Nothing AndAlso BitmapList.Count > 0 Then
BitmapList.RemoveAt(0)
Path_List.RemoveAt(0)
PictureBox1.Image = Nothing
End If
End Sub
Private Sub PictureBox2_DoubleClick(sender As Object, e As EventArgs) Handles PictureBox2.DoubleClick
If BitmapList IsNot Nothing AndAlso BitmapList.Count > 1 Then
BitmapList.RemoveAt(1)
Path_List.RemoveAt(1)
PictureBox2.Image = Nothing
End If
End Sub
Private Sub PictureBox3_DoubleClick(sender As Object, e As EventArgs) Handles PictureBox3.DoubleClick
If BitmapList IsNot Nothing AndAlso BitmapList.Count > 2 Then
BitmapList.RemoveAt(2)
Path_List.RemoveAt(2)
PictureBox3.Image = Nothing
End If
End Sub
Private Sub PictureBox4_DoubleClick(sender As Object, e As EventArgs) Handles PictureBox4.DoubleClick
If BitmapList IsNot Nothing AndAlso BitmapList.Count > 3 Then
BitmapList.RemoveAt(3)
Path_List.RemoveAt(3)
PictureBox4.Image = Nothing
End If
End Sub
Private Sub PictureBox5_DoubleClick(sender As Object, e As EventArgs) Handles PictureBox5.DoubleClick
If BitmapList IsNot Nothing AndAlso BitmapList.Count > 4 Then
BitmapList.RemoveAt(4)
Path_List.RemoveAt(4)
PictureBox5.Image = Nothing
End If
End Sub
Private Sub PictureBox6_DoubleClick(sender As Object, e As EventArgs) Handles PictureBox6.DoubleClick
If BitmapList IsNot Nothing AndAlso BitmapList.Count > 5 Then
BitmapList.RemoveAt(5)
Path_List.RemoveAt(5)
PictureBox6.Image = Nothing
End If
End Sub
Private Sub PictureBox7_DoubleClick(sender As Object, e As EventArgs) Handles PictureBox7.DoubleClick
If BitmapList IsNot Nothing AndAlso BitmapList.Count > 6 Then
BitmapList.RemoveAt(6)
Path_List.RemoveAt(6)
PictureBox7.Image = Nothing
End If
End Sub
Private Sub PictureBox8_DoubleClick(sender As Object, e As EventArgs) Handles PictureBox8.DoubleClick
If BitmapList IsNot Nothing AndAlso BitmapList.Count > 7 Then
BitmapList.RemoveAt(7)
Path_List.RemoveAt(7)
PictureBox8.Image = Nothing
End If
End Sub
Private Sub PictureBox9_DoubleClick(sender As Object, e As EventArgs) Handles PictureBox9.DoubleClick
If BitmapList IsNot Nothing AndAlso BitmapList.Count > 8 Then
BitmapList.RemoveAt(8)
Path_List.RemoveAt(8)
PictureBox9.Image = Nothing
End If
End Sub

Answer 1

Start by setting the Tag property of each PictureBox to the corresponding number in the designer, i.e. PictureBox1.Tag to 0, etc. You can then combine all those event handlers into one:
Private Sub PictureBoxes_DoubleClick(sender As Object, e As EventArgs) Handles PictureBox1.DoubleClick,
PictureBox2.DoubleClick,
PictureBox3.DoubleClick,
PictureBox4.DoubleClick,
PictureBox5.DoubleClick,
PictureBox6.DoubleClick,
PictureBox7.DoubleClick,
PictureBox8.DoubleClick,
PictureBox9.DoubleClick
Dim pb = DirectCast(sender, PictureBox)
Dim n = CInt(pb.Tag)
If BitmapList?.Count > n Then
BitmapList.RemoveAt(n)
Path_List.RemoveAt(n)
pb.Image.Dispose()
pb.Image = Nothing
End If
End Sub
Note that I added a line to dispose the Image you're removing. Don't do that if you're still using the Image object elsewhere but definitely do it if you're not still using it.
Note that I also threw a null propagation operator in there, negating the need for a separate null check.