I'm new to AppleScript and I try to make droplet that recursively changes permissions on dropped folder and files within. I wrote this code and it works fine to all items within the root folder but it can't change permissions on the root folder itself. What should I change in this code?
property user_name : "suser_root"
property pass_word : "**********"
on open theDroppedItems
repeat with a from 1 to length of theDroppedItems
set theCurrentDroppedItem to item a of theDroppedItems
do shell script "sudo chmod -R 777 " & quoted form of POSIX path of theCurrentDroppedItem user name user_name password pass_word with administrator privileges
end repeat
end open
You need HOT FOLDER conception instead of DROPPLET:
use AppleScript version "2.4" -- Yosemite (10.10) or later
use framework "Foundation"
use scripting additions
property user_name : "suser_root"
property pass_word : "**********"
on adding folder items to this_folder after receiving theDroppedItems
repeat with a from 1 to length of theDroppedItems
set theCurrentDroppedItem to item a of theDroppedItems
-- make sure dropped item is folder
if (class of item theCurrentDroppedItem of application "Finder") as text is "folder" then
-- unlock dropped folder and its entire contents
tell application "Finder" to set entireContents to (entire contents of folder (theCurrentDroppedItem as text)) as alias list
set end of entireContents to theCurrentDroppedItem
repeat with anAlias in entireContents
set theURL to (current application's class "NSURL"'s fileURLWithPath:(POSIX path of anAlias))
set {theResult, theError} to (theURL's setResourceValue:(false) forKey:(current application's NSURLIsUserImmutableKey) |error|:(reference))
do shell script "chmod -R 777 " & quoted form of POSIX path of anAlias user name user_name password pass_word
end repeat
end if
end repeat
end adding folder items to
Related
Using applescript, I'm trying to create a .patch file in a set of parallel folders for every .recipe file in a target folder and its sub-folders. This also includes creating a parallel folder structure as the script does it's thing. I've got the steps right, but some part of the detailed grammar is wrong and I can't figure out what and how to fix it. Debugging information I've read so far has not helped me, though I'm sure this is a simple matter of incorrect applescript grammar. Here is the code:
use AppleScript version "2.4" -- Yosemite (10.10) or later
use scripting additions
on run
set patchFile to (choose file with prompt "Select patch file...")
set assetsFolder to (choose folder with prompt "Select recipe assets folder...")
set dumpFolder to (choose folder with prompt "Select dump folder...")
makePatches(patchFile, assetsFolder, dumpFolder)
end run
on makePatches(patchFile, targetFolder, dumpFolder)
tell application "Finder"
set recipeCount to count (files in folder (targetFolder) whose name ends with ".recipe")
if (recipeCount > 0) then
set recipeFiles to files in folder (targetFolder) whose name ends with ".recipe"
repeat with eachFile in recipeFiles
set recipePatch to duplicate patchFile to folder dumpFolder
set recipePatch's name to eachFile's name & ".patch"
end repeat
end if
set folderCount to (folders in folder (targetFolder) whose visible is true)
if (folderCount > 0) then
set subFolders to folders in folder (targetFolder)
repeat with eachFolder in subFolders
set newName to folder eachFolder's name
set newFolder to make new folder at folder dumpFolder
set newFolder's name to newName
my makePatches(patchFile, eachFolder, newFolder)
end repeat
end if
end tell
return
end makePatches
Note that if I remove the code for iterating through the folders and simply have it create patches for each .recipe file in a folder, then that code works. Or at least, it does as far as I can tell. So the problem should be somewhere at or after folderCount. The recursion is needed, as is the ability to use choose with prompt. Hopefully that isn't a problem. What is the correct grammar for the iteration section?
After semi-blindly adjusting the code and looking at just about every relevant example I could find, I came up with some code that does exactly what is needed. But I don't really understand what was going wrong with the original, so while I'll post the working code I made, I'd still like to hear what was wrong with the original code explained.
on run
set patchFile to (choose file with prompt "Select patch file...")
set assetsFolder to (choose folder with prompt "Select recipe assets folder...")
set dumpFolder to (choose folder with prompt "Select dump folder...")
makePatches(patchFile, assetsFolder, dumpFolder)
end run
on makePatches(patchFile, targetFolder, dumpFolder)
tell application "Finder"
set recipeFiles to files of targetFolder whose name ends with ".recipe"
repeat with eachFile in recipeFiles
set recipePatch to duplicate patchFile to dumpFolder
set recipePatch's name to eachFile's name & ".patch"
end repeat
end tell
tell application "Finder" to set theseSubFolders to folders of targetFolder
repeat with tSubF in theseSubFolders
set newName to tSubF's name
tell application "Finder" to set newFolder to (make new folder at dumpFolder with properties {name:newName})
my makePatches(patchFile, tSubF, newFolder)
end repeat
end makePatches
I have an AppleScript that is used to programmatically create a test script file in one of these Office 2016 app folders:
~/Library/Application Scripts/com.microsoft.Excel
~/Library/Application Scripts/com.microsoft.Word
~/Library/Application Scripts/com.microsoft.Powerpoint
This is the test.scpt file content which is programmatically generated:
on handlerTest(thisPhrase)
say thisPhrase
end handlerTest
This test.scpt file contains a single handler which speaks the phrase passed to it.
When the script is created in one of these folders, I cannot see the content of the script file in Finder and calling the handler from a Microsoft Office app using the new VBA AppleScriptTask causes the Office app to crash. I think the script is being created as a byte-compiled file because it cannot be viewed in Finder as plain text.
If I then copy the script file generated programmatically by my script creator script to the Documents folder, the plain-text content of the script is viewable in Finder.
Now, if I copy the script file from the Documents folder back to the corresponding com.microsoft folder (without modifying it), I can now see the plain-text content in Finder and calling the handler using the VBA AppleScriptTask function works as expected. I don't understand how the format is apparently changing due to copy/paste actions?
How can I programmatically create the script file in the com.microsoft.xyz folder in plain text format?
Here is my VBA procedure:
Sub TestScript()
AppleScriptTask "test.scpt", "handlerTest", "hello world"
End Sub
Here is my example script creator script which programmatically creates a test.scpt file in the com.microsoft.Powerpoint scripting folder: (kudos to eliteproxy for the original source script)
property theFolders : {"~/Library/'Application Scripts'/com.microsoft.Powerpoint"}
try
tell application "Finder" to set targetFolder to (target of the front window) as alias
on error -- no window
set targetFolder to (choose folder)
end try
# build a parameter string from the folder list
set {tempTID, AppleScript's text item delimiters} to {AppleScript's text item delimiters, space}
set {theFolders, AppleScript's text item delimiters} to {theFolders as text, tempTID}
do shell script "cd " & quoted form of POSIX path of targetFolder & "; mkdir -p " & theFolders
--Write the Script file if it does not exist
if ExistsFile("~/Library/'Application Scripts'/com.microsoft.Powerpoint/test.scpt") is false then
tell application "Finder"
--GET THE WORKING DIRECTORY FOR FILE COPY OF SCRIPT
get folder of (path to me) as Unicode text
set workingDir to POSIX path of result
--Write the new script in the current working directory
set textFile to workingDir & "test.scpt"
--Delete script if it exists
set posixPath to POSIX path of textFile as string
do shell script "rm -rf \"" & posixPath & "\""
--Create Script Interface file for Microsoft PowerPoint VBA Applications
set fd to open for access textFile with write permission
-- Create test handler which speaks the passed phrase parameter
write "on handlerTest(thisPhrase)" & linefeed to fd as «class utf8» starting at eof
write "say thisPhrase" & linefeed to fd as «class utf8» starting at eof
write "end handlerTest" & linefeed to fd as «class utf8» starting at eof
close access fd
--Copy the script file into the MACOS-Specific 'safe' folder
set fromPath to quoted form of POSIX path of (workingDir) & "test.scpt"
set toPath to quoted form of "~/Library/'Application Scripts'/com.microsoft.Powerpoint"
do shell script "cp -R " & fromPath & space & "~/Library/'Application Scripts'/com.microsoft.Powerpoint" with administrator privileges
end tell
end if
--Delete the temp script file from the working directory
set posixPath to POSIX path of textFile as string
do shell script "rm -rf \"" & posixPath & "\""
--Provide confirmation
set theAlertTitle to "TEST"
set theAlertMsg to "The script has been successfully installed."
display alert theAlertTitle message theAlertMsg as informational buttons {"OK"} default button "OK" cancel button "OK"
--For use when checking if a file exists
on ExistsFile(filePath)
tell application "System Events" to return (exists disk item filePath) and class of disk item filePath = file
end ExistsFile
I could be wrong in my interpretation of your question, but it appears as if you are looking to create file “Test.scpt” with your handler “handlerTest” as the code, in a folder named “com.microsoft.Excel” (for example). If that is all you are looking to achieve, I believe this solution should work for you...
script theHandler
on handlerTest(thisPhrase)
say thisPhrase
end handlerTest
end script
storeScript()
on storeScript()
set thisScript to store script theHandler in (path to home folder as text) ¬
& "Library:Application Scripts:com.microsoft.Excel:Test.scpt" replacing yes
end storeScript
I'm looking for a way/code to select a folder within a specific folder that contains part of a string from a variable
I have folderA and within folderA are numerous folders. All the folders within folderA start out with a 5 digit number followed by an "_" and then a short description. ie, 12345_Folder Test 1, 54321_Folder Test 2, 99999_Folder Test 3, etc...
tell application "Finder"
set folderA to folder "FolderA" of folder "Desktop" of folder "MacUser" of folder "Users" of startup disk
set jobNum to text returned of (display dialog "Enter 5 Digits Only:" default answer "")
open folderA
set selected_item to (folder whose name contains jobNum in folderA) -- This is what's failing for me.
-- from here on I would like to do other things such as run other parts of a script.
end tell
---Script Error Message
Can’t get folder whose name contains jobNum of folder "FolderA" of
folder "Desktop" of folder "prepress_js" of folder "Users" of startup
disk of application "Finder". ----
Any help is greatly appreciated!
Try this line:
set selection to item 1 of (get every folder in folderA whose name contains jobNum) -- This is what's failing for me.
I have been trying to cobble together a script to take a list of files from a text document and have applescript go through the list line by line and then do something with the file. In this case it is changing the label on the file, but we would use it in other instances to move files, etc.
It works with a test file on my desktop the files get marked with the purple Label, but when trying to run it in the folder I actually need to it fails with this error message:
error "Finder got an error: Can’t set 1 to 5." number -10006 from 1
The text files are the same except for the length of their content.
Could this be a an issues with filenames, and if so how do I make the script more tolerant.
Here is the script:
set textFileContents to POSIX path of (choose file)
set dataList to paragraphs of (read textFileContents as «class utf8»)
tell application "System Events"
repeat with thisFileName in dataList
tell application "Finder" to set (label index of files whose name is thisFileName) to 5
end repeat
end tell
Any help would be appreciated, thanks.
1080074 3.tif
1080074 2.tif
1080069_A1.tif
Here is the final code from the solution to this problem and some further work I did.
Thanks to #Mark Setchell & #jackjr300 for all of their patient help.
set justpath to POSIX path of (choose folder with prompt "Select the Folder with Files You Want to Use")
set textFileContents to (choose file with prompt "Select the list of files")
set dataList to paragraphs of (read textFileContents as «class utf8»)
tell application "Finder"
repeat with FileName in dataList
try -- need a try block to ignore error, in case that the file has been moved or deleted
set label index of (justpath & FileName as POSIX file as alias) to 5
end try
end repeat
end tell
You seem to have a spurious tell application "System Events" in there. It works like this:
set FileName to POSIX path of (choose file)
set FileRecords to paragraphs of (read FileName)
repeat with ThisFileName in FileRecords
say ThisFileName
tell application "Finder" to set (label index of files whose name is thisFileName) to 5
end repeat
Note that my test file isn't UTF8.
Update
By the way, if all you want do is set the label colour on some files, it may be easier to do that from the Terminal and not worry with Applescript. Say you start the Terminal, and go to your Desktop like this
cd Desktop
you can then change the labels of all files on your Desktop (and in any subdirectories) whose names contain "Freddy" followed by "Frog" (i.e "fileForFreddyFrog.txt", "file from Freddy the Frog.php")
find . -name "*Freddy*Frog*" -exec xattr -wx com.apple.FinderInfo "0000000000000000000700000000000000000000000000000000000000000000" {} \;
You need to specify the folder because the finder has no current folder, except the Desktop if you don't specify a folder.
set textFileContents to choose file
set dataList to paragraphs of (read textFileContents as «class utf8»)
set theFolder to "/Users/jack/Desktop/xxx/yyy" as POSIX file as alias -- change it to the path of your folder
tell application "Finder"
repeat with thisFileName in dataList
try -- need a try block to ignore error, in case that the file has been moved or deleted
set label index of file thisFileName of theFolder to 5
end try
end repeat
end tell
Change the path in the third line of this script
--
If the text file contains the full path of the file, you can use this script.
set textFileContents to choose file
set dataList to paragraphs of (read textFileContents as «class utf8»)
tell application "Finder"
repeat with thisPath in dataList
try -- need a try block to ignore error, in case that the file has been moved or deleted
set label index of (thisPath as POSIX file as alias) to 5
end try
end repeat
end tell
I am very new to using Automator and Applescript.
I would like to use Automator and AppleScript to detect PDF files that are downloaded to the "Downloads" folder and opens a display dialog that allows me to select the file path and move the file. So far, what I have (which isn't right) is something like:
set question to display dialog "Save fileName in..." buttons {"Figuring Relation", "Iconoclasm", "Elsewhere"} default button 3
set answer to button returned of question
if answer is equal to "Figuring Relation" then
tell application "Finder" to move fileName to POSIX file "/Users/mac/Documents/College/Junior/Fall/Art 347 - Figuring Relation"
I want the "Figuring Relation" and "Iconoclasm" buttons to change the file path to a designated file path (I don't want to browse for it), and the "Elsewhere" button to open a Finder window where I can select/browse the path.
If possible, I'm also looking to add the date to the beginning of the file name as "mm-dd_filename".
I am not sure of how to translate the Automator Input to Applescript, or how to include the filename in the display dialog text. Thank you so much for any help.
Here is an example using just applescript. In my example, it assumes you're selecting the file you're wanting to move, but you could easily add something for the script to "Find" all files ending with ".pdf" if you wanted to and then loop through the results.
on run
try
set thisFile to choose file
tell application "Finder" to set currentName to thisFile's name
-- Setting variables for the destinations to be used later
set FiguringRelationPath to (path to documents folder) & "College:Junior:Fall:Art 347 - Figuring Relation:" as string
set IconoclasmPath to (path to documents folder) & "Iconoclasm:" as string
-- Ask the user
set answer to button returned of (display dialog "Save \"" & currentName & "\" in..." buttons {"Figuring Relation", "Iconoclasm", "Elsewhere"} default button 3)
-- Set the destination variable based on the users response to the dialog
if answer is equal to "Figuring Relation" then
set destination to FiguringRelationPath
else if answer is equal to "Iconoclasm" then
set destination to IconoclasmPath
else
set destination to choose folder with prompt "Please select the destination folder" as string
end if
-- Test that the destination directory exists, if not post the error
try
set destination to destination as alias
on error
error ("Destination path " & destination as string) & " doesn't appear to exist"
end try
-- Rename the file with the date prefix
set tDatePrefix to (do shell script "date '+%m-%d'") & "_" as string
tell application "Finder" to set x's name to tDatePrefix & x's name as string
-- Move the file
tell application "Finder" to move thisFile to destination
on error err
activate
display dialog "Error: " & err buttons {"OK"} default button 1
end try
end run