How Do I Ignore Variable Not Defined Compile Error - vba

Question

I am trying to create a module that I can copy into various MS Office applications that will return the current project/application/workbook/document path based on what application is running the VBA code. My code (adapted from other code I found in searches) works, but when I try to compile it, I get a "Compile Error: Variable Not Defined" message because it doesn't recognize the property calls for the other Office Apps. Is there some way to trick the compiler into ignoring these other app property calls, or something else I can do to get my module to compile?
Private Function GetActivePath() As String
' function returns the local path of the current active MSO application
' ** MSOffice applications only
On Error GoTo errHandler
Dim errSub As String: errSub = "GetActivePath"
Dim AppName As String
AppName = Application.name
Select Case AppName
Case "Microsoft Access"
GetActivePath = AccessPath
Case "Microsoft Excel"
GetActivePath = ExcelPath
Case "Microsoft Outlook"
GetActivePath = "*** un-defined ***"
Case "Microsoft Powerpoint"
GetActivePath = PowerpointPath
Case "Microsoft Project"
GetActivePath = ProjectPath
Case "Microsoft Visio"
GetActivePath = VisioPath
Case "Microsoft Word"
GetActivePath = WordPath
Case Else
GetActivePath = "*** un-defined ***"
End Select
Exit Function
errHandler:
Debug.Print errSub & ": " & Err.Description
End Function
Private Function AccessPath() As String
' will not compile unless current app is Access
AccessPath = CurrentProject.Path
End Function
Private Function ExcelPath() As String
' will not compile unless current app is Excel
ExcelPath = ActiveWorkbook.Path
End Function
Private Function PowerpointPath() As String
' will not compile unless current app is Powerpoint
PowerpointPath = ActivePresentation.Path
End Function
Private Function ProjectPath() As String
' will not compile unless current app is Project
ProjectPath = ActiveProject.Path
End Function
Private Function VisioPath() As String
' will not compile unless current app is Visio
VisioPath = ActiveDocument.Path
End Function
Private Function WordPath() As String
' will not compile unless current app is Word
WordPath = ActiveDocument.Path
End Function

Answer 1

You can access PowerPoint's ActivePresentation variable (and presumably the corresponding ones for the other Office applications) as a property of the Application object.
Object properties can be accessed dynamically by name using the CallByName function.
So something like this (not tested) should work:
Private Function GetActivePath() As String
Dim DocPropertyName As String
Dim Document as Object
Select Case Application.Name
Case "Microsoft Access"
DocPropertyName = "CurrentProject"
Case "Microsoft Excel"
DocPropertyName = "ActiveWorkbook"
Case "Microsoft Powerpoint"
DocPropertyName = "ActivePresentation"
Case "Microsoft Project"
DocPropertyName = "ActiveProject"
Case "Microsoft Visio"
DocPropertyName = "ActiveDocument"
Case "Microsoft Word"
DocPropertyName = "ActiveDocument"
Case Else
Err.Raise 1000
End Select
Set Document = CallByName(Application, DocPropertyName, vbGet)
GetActivePath = Document.Path
End Function
Alternatively, since we already know what all the possible property names are, we can make use of late binding by declaring a reference of type Object to the Application object:
Private Function GetActivePath() As String
Dim App as Object
Set App = Application
Select Case Application.Name
Case "Microsoft Access"
GetActivePath = App.CurrentProject.Path
Case "Microsoft Excel"
GetActivePath = App.ActiveWorkbook.Path
Case "Microsoft Powerpoint"
GetActivePath = App.ActivePresentation.Path
Case "Microsoft Project"
GetActivePath = App.ActiveProject.Path
Case "Microsoft Visio"
GetActivePath = App.ActiveDocument.Path
Case "Microsoft Word"
GetActivePath = App.ActiveDocument.Path
Case Else
Err.Raise 1000
End Select
End Function

Answer 2

https://learn.microsoft.com/en-us/office/vba/language/reference/user-interface-help/option-explicit-statement
Check if you have the command Option Explicitat the top
Use Option Explicit statement to force explicit declaration of all variables. Attempting to use an undeclared variable causes an error at compile time. The Option Explicit statement is used at the module level only.