Install header files respecting subdirectories with CMake - cmake

Question

I have a set of header files under several subdirectories
|- A
| | - a.h
| | - b.h
| | - a.cpp
| | - b.cpp
|
| B
| - c.h
| - d.h
| - c.cpp
| - d.cpp
I have a variable with the paths of each file
set(HEADERS A/a.h A/b.h C/c.h B/d.h)
and I populate the PUBLIC_HEADER property of a target with that variable and install it
set_target_properties(MyTarget
PROPERTIES
PUBLIC_HEADER "${HEADERS}"
)
install(TARGETS MyTarget
PUBLIC_HEADER
DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/MyTarget/
)
The issue is that is doesn't respect the subdirectories and the four files are installed under MyTarget. I would like to install them under MyTarget/A for a.h and b.h and under MyTarget/B for c.h and d.h.

Answer 1

If your header directory (e.g. include) above A and B contains installable headers you could do
install(DIRECTORY include/
DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/MyTarget
FILES_MATCHING PATTERN "*.h"
PATTERN "*_p.h" EXCLUDE
)
The trailing slash on the include directory denotes that its contents (including its structure) is copied to the destination.
Otherwise the headers can be installed manually for each directory as follows.
set(HEADERS_A A/a.h A/b.h)
set(HEADERS_B B/c.h B/d.h)
install(FILES ${HEADERS_A} DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/MyTarget/A)
install(FILES ${HEADERS_B} DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/MyTarget/B)