How to rename suffix of all files in listbox? - vb.net

Question

I have a windows form that contains two list boxes and two tool strip labels (buttons).
On pressing the first button (Open folder), a file browser opens and you can select multiple files, these are then loaded into listbox 1 (ListFilesLoaded), now what I want to do is display converted file names in Listbox 2 (ConvertedNames). for example...
apple_001.jpg > apple_Ambrosia.jpg
apple_002.jpg > apple_Melba.jpg
apple_003.jpg > apple_Granny.jpg
Then press my second button (Rename Files) to save the renamed files in their original directory (removing the old files / names).
So far I have gotten the loading listbox1 (ListFilesLoaded) working fine. I'm just not sure how to go about changing their display names in listbox 2 (ConvertedNames) and saving them out as the new file names.
Imports System.IO
Public Class Form1
Private openFile As OpenFileDialog 'window to open files
Private Sub ToolStripLabel1_Click(sender As Object, e As EventArgs) Handles ToolStripLabel1.Click
Try
openFile = New OpenFileDialog
openFile.Title = "Select files."
openFile.CheckFileExists = True
openFile.Multiselect = True
openFile.RestoreDirectory = False
If openFile.ShowDialog = Windows.Forms.DialogResult.OK Then
openFile.SafeFileNames.Count()
For i As Integer = 0 To openFile.SafeFileNames.Count() - 1
ListFilesLoaded.Items.Add(openFile.SafeFileNames(i))
ConvertedNames.Items.Add(openFile.SafeFileNames(i))
Next
End If
Catch ex As Exception
MessageBox.Show(ex.Message, "Message", MessageBoxButtons.OK, MessageBoxIcon.Exclamation)
End Try
End Sub
Private Sub ToolStripLabel2_Click(sender As Object, e As EventArgs) Handles ToolStripLabel2.Click
End Sub
So essentially I think I need something like...
If ConvertedNames.Items.string.contains "_001" then
ConvertedNames.Items.string = ConvertedNames.Items.string -4 + _Ambrosia
else if
ConvertedNames.Items.string.contains "_002" then
ConvertedNames.Items.string = ConvertedNames.Items.string -4 + _Melba
else if
ConvertedNames.loaded.name.contains "_003" then
ConvertedNames.Items.string = ConvertedNames.Items.string -4 + _Granny
End If
When it comes to the saving names part, I have no idea at all.
Thanks for taking the time too look.

Answer 1

I changed the names of your controls to match my test program.
I used a List(Of Tuple(Of String, String) to store the path and file name of the original files. https://learn.microsoft.com/en-us/dotnet/visual-basic/programming-guide/language-features/data-types/tuples and https://learn.microsoft.com/en-us/dotnet/api/system.tuple?view=net-5.0 Without named items, the Tuple elements are referred to as Item1 for the first string and Item2 as the second string. Since our method is small, I felt that naming the elements or using a structure or class was not necessary.
Item1 is the full path (with file name and extension)
Item2 is the file name only with extension
Next, we bind the list to the first list box setting the display and value members. Now we can loop through the list box. Remember that each item in the list box is a Tuple(Of String, String) and we can refer to its elements with Item1 and Item2. We send the file name off to a function that returns the new file name
To actually change the file name on disk we can use the Visual Basic specific FileIO.FileSystem.Rename method. https://learn.microsoft.com/en-us/dotnet/api/microsoft.visualbasic.fileio.filesystem.renamefile?view=net-5.0 This method takes as parameters, the full path of the original file and the new file name.
Finally, the new name is added to the second list box.
The GetNewName function uses a Select Case and the String.Replace method to do the job.https://learn.microsoft.com/en-us/dotnet/api/system.string.replace?view=net-5.0
Private Sub ToolStripLabel1_Click(sender As Object, e As EventArgs) Handles ToolStripLabel1.Click
Dim openFile = New OpenFileDialog
openFile.Title = "Select files."
openFile.CheckFileExists = True
openFile.Multiselect = True
openFile.RestoreDirectory = False
If openFile.ShowDialog = Windows.Forms.DialogResult.OK Then
Dim lstPathAndFile As New List(Of Tuple(Of String, String))
For Each filePath In openFile.FileNames
lstPathAndFile.Add(Tuple.Create(filePath, Path.GetFileName(filePath)))
Next
ListBox1.DisplayMember = "Item2"
ListBox1.ValueMember = "Item1"
ListBox1.DataSource = lstPathAndFile
For Each t As Tuple(Of String, String) In ListBox1.Items
Dim NewName = GetNewName(t.Item2)
FileIO.FileSystem.RenameFile(t.Item1, NewName)
ListBox2.Items.Add(NewName)
Next
End If
End Sub
Private Function GetNewName(OriginalFileName As String) As String
Dim NewFileName As String = ""
Select Case True
Case OriginalFileName.Contains("001")
NewFileName = OriginalFileName.Replace("001", "Ambrosia")
Case OriginalFileName.Contains("002")
NewFileName = OriginalFileName.Replace("002", "Melba")
Case OriginalFileName.Contains("003")
NewFileName = OriginalFileName.Replace("003", "Granny")
End Select
Return NewFileName
End Function