System.ArgumentException: 'Argument 'NPer' is not a valid value.' - vb.net

Question

I was able to debug my coding then, when I click my "Calculate" button, the error message
System.ArgumentException: 'Argument 'NPer' is not a valid value.'
pops up (first pic). The second pic is my app. The reset button and the exit button work, but when I click the "Calculate" button it doesn't work.
Public Class Form1
Const dblMonths_Year As Double = 12
Const dblNew_Rate As Double = 0.05
Const dblUsed_Rate As Double = 0.08
Dim dblAnnualRate As Double = dblNew_Rate
Private Sub btnCalculate_Click(sender As Object, e As EventArgs) Handles btnCalculate.Click
Dim dblVehicleCost As Double
Dim dblDownPayment As Double
Dim dblMonths As Double
Dim dblLoan As Double
Dim dblMonthlyPayment As Double
Dim dblInterest As Double
Dim dblPrincipal As Double
Dim intCount As Integer
Dim strOut As String
Dim blnInputOK As Boolean = True
If blnInputOK = True Then
dblLoan = dblVehicleCost - dblDownPayment
dblMonthlyPayment = Pmt(dblAnnualRate / dblMonths_Year, dblMonths, -dblLoan)
lstOutput.Items.Clear()
For intCount = 1 To dblMonths
dblInterest = IPmt(dblAnnualRate / dblMonths_Year, intCount, dblMonths, -dblLoan)
dblPrincipal = PPmt(dblAnnualRate / dblMonths_Year, intCount, dblMonths, -dblLoan)
strOut = "Month" & intCount.ToString("d2")
strOut &= ": payment =" & dblMonthlyPayment.ToString("n2")
strOut &= ", interest =" & dblInterest.ToString("n2")
strOut &= ", principal =" & dblPrincipal.ToString("n2")
lstOutput.Items.Add(strOut)
Next
End If
End Sub
Private Sub btnReset_Click(sender As Object, e As EventArgs) Handles btnReset.Click
radNew.Checked = True
dblAnnualRate = dblNew_Rate
lblAnualRate.Text = dblNew_Rate.ToString("p")
txtCost.Clear()
txtDownPayment.Clear()
txtMonths.Clear()
lstOutput.Items.Clear()
txtCost.Focus()
End Sub
Private Sub btnExit_Click(sender As Object, e As EventArgs) Handles btnExit.Click
Close()
End Sub
Private Sub radNew_CheckedChanged(sender As Object, e As EventArgs) Handles radNew.CheckedChanged
If radNew.Checked = True Then
dblAnnualRate = dblNew_Rate
lblAnualRate.Text = dblNew_Rate.ToString("p")
lstOutput.Items.Clear()
End If
End Sub
Private Sub radUsed_CheckedChanged(sender As Object, e As EventArgs) Handles radUsed.CheckedChanged
If radUsed.Checked = True Then
dblAnnualRate = dblUsed_Rate
lblAnualRate.Text = dblUsed_Rate.ToString("p")
lstOutput.Items.Clear()
End If
End Sub
End Class

Answer 1

You need to set the variables from the input fields, preferably making sure that the user has input sensible values, for example:
Public Class Form1
Const MONTHS_PER_YEAR = 12
Const NEW_RATE = 0.05
Const USED_RATE = 0.08
Dim annualInterestRate As Double = NEW_RATE
Private Sub btnCalculate_Click(sender As Object, e As EventArgs) Handles btnCalculate.Click
Dim vehicleCost = 0.0D
Dim downPayment = 0.0D
Dim monthsToPay = 0
Dim inputOk = Decimal.TryParse(tbCost.Text, vehicleCost) AndAlso
Decimal.TryParse(tbDownPayment.Text, downPayment) AndAlso
Integer.TryParse(tbMonthsToPay.Text, monthsToPay)
If inputOk Then
lstOutput.Items.Clear()
Dim loanAmount = vehicleCost - downPayment
Dim monthlyPayment = Pmt(annualInterestRate / MONTHS_PER_YEAR, monthsToPay, -loanAmount)
For monthNumber = 1 To monthsToPay
Dim interestPayment = IPmt(annualInterestRate / MONTHS_PER_YEAR, monthNumber, monthsToPay, -loanAmount)
Dim principalPayment = PPmt(annualInterestRate / MONTHS_PER_YEAR, monthNumber, monthsToPay, -loanAmount)
Dim strOut = $"Month {monthNumber:D2}"
strOut &= $": payment = {monthlyPayment:C2}"
strOut &= $", interest = {interestPayment:C2}"
strOut &= $", principal = {principalPayment:C2}"
lstOutput.Items.Add(strOut)
Next
End If
End Sub
' other code here
End Class
It is convention to use UPPER_SNAKE_CASE for constants. Variables should (usually) be declared at the point of use.
In VB.NET, set Option Strict On and Option Infer On for an easier programming experience.
The D is a forced literal type for a Decimal value. The Decimal type should be used for money, even though the Pmt, IPmt, and PPmt functions don't (I suspect the Decimal type wasn't available when those functions were written).
I used interpolated strings to show you how they could be used in your program: they can be useful for making code more readable.