Evaluate input to a VBA function before executing the function - vba

Question

I have created a VBA function to calculate a weighted average. The function has optional parameters ("criterias") that allow to restrict the weighted average calculation to a subset of rows only (all Apple rows in the example below).
The function works fine for inputs of the form :
weightedAverage([5 2 5],[2 3 4], [Apple Orange Apple], Apple)
If I change the input on the "criterias" as follows, the function returns an error:
weightedAverage([5 2 5],[2 3 4], ([Apple Orange Apple]=Apple), TRUE)
Is there a way that the function first evaluates the third input and translates it to [TRUE FALSE TRUE]?
(The workbook function sumproduct is able to handle inputs of the form sumproduct(--([Apple Orange Apple]=Apple),...), which is why I am wondering whether is also possible for my function)
Function weightedAverage(vals As Range, weight As Range, ParamArray criterias() As Variant) As Double
' Calcualted Weighted Average of "vals" weighted by "weight"
' Optionally the weighted average can be constrained to certain "vals" only by using "criterias"
Dim totalweight As Double 'sum up weights where "vals" is a number and "criterias" is true
Dim result As Double 'sum up vals(i) * weights(i)
Dim takevalue As Boolean 'temporary variable store whether "vals" is a number and "criterias" are met
' Init
result = 0
totalweight = 0
' Loop over vals
For i = 1 To vals.Count
' Check whether vals is a numeric and not empty
takevalue = IsNumeric(vals.Cells(i).Value) And Not (IsEmpty(vals.Cells(i).Value))
' Check whether criterias are satisfied
For ii = 0 To UBound(criterias) - 1 Step 2
' Exit loop if condition is not satisfied
If takevalue = False Then Exit For
' Test whether condition is true
takevalue = ((LCase(criterias(ii).Cells(i).Value) = LCase(criterias(ii + 1).Cells(1).Value)) And takevalue)
Next ii
' If all conditions are satisfied, add value to results and totalweight
If takevalue Then
result = result + vals(i) * weight(i)
totalweight = totalweight + weight(i)
End If
Next i
' Calculate weighted average
weightedAverage = result / totalweight
End Function

Answer 1

Thank you, Tim, for your help. The function needs to be executed using Ctrl+Shift+Enter and the fourth input needs to be dropped.
The below weightedAverage function works with the following input:
weightedAverage([5 2 5],[2 3 4], ([Apple Orange Apple]=Apple))
Function weightedAverage(vals As Range, weight As Range, ParamArray criterias() As Variant) As Double
' Calcualted Weighted Average of "vals" weighted by "weight"
' Optionally the weighted average can be constrained to certain "vals" only by using "criterias"
Dim totalweight As Double 'sum up weights where "vals" is a number and "criterias" is true
Dim result As Double 'sum up vals(i) * weights(i)
Dim takevalue As Boolean 'temporary variable store whether "vals" is a number and "criterias" are met
' Init
result = 0
totalweight = 0
' Loop over vals
For i = 1 To vals.Count
' Check whether vals is a numeric and not empty
takevalue = IsNumeric(vals.Cells(i).Value) And Not (IsEmpty(vals.Cells(i).Value))
' Check whether criterias are satisfied
For ii = 0 To UBound(criterias)
' Exit loop if condition is not satisfied
If takevalue = False Then Exit For
' Test whether condition is true
takevalue = (criterias(ii)(i, 1) And takevalue)
Next ii
' If all conditions are satisfied, add value to results and totalweight
If takevalue Then
result = result + vals(i) * weight(i)
totalweight = totalweight + weight(i)
End If
Next i
' Calculate weighted average
weightedAverage = result / totalweight
End Function