Antlr not producing a visit method for some reason - antlr

Question

The following grammar, in Java, does not produce a visitor with "visitExpr" and I have no idea why... I added valueExpression and it DOES produce visitValueExpression, but this doesn't make it easy to get an expr out of all the math expressions.
grammar Txml;
program: statement (NEWLINE statement)* NEWLINE? EOF;
statement: require # Condition
| entry # CreateEntry
| assignment # Assign
;
require: REQUIRE valueExpression;
valueExpression: expr;
expr: lhs=expr ('*' | '/') rhs=expr # MulDiv
| lhs=expr ('+' | '-') rhs=expr # AddSub
| lhs=expr '%' rhs=expr # Mod
| lhs=expr '^' rhs=expr # Pow
| '(' expr ')' # Parens
| NUMBER # NumberLiteral
| IDENT '(' args ')' # FunctionCall
| IDENT # Identifier
| STRING_LITERAL # StringLiteral
;
functionArgument: expr;
args: (functionArgument (',' functionArgument)*)?;
// Reserved words
REQUIRE: 'require';
// Whitespace and line break
NEWLINE : [\r\n];
WS: [ \t] + -> skip;
// Entities
NUMBER: ('0' .. '9') + ('.' ('0' .. '9') +)?;
IDENT: [a-zA-Z]+[0-9a-zA-Z]*;
STRING_LITERAL : '"' (~('"' | '\\' | '\r' | '\n') | '\\' ('"' | '\\'))* '"';
Also, I don't quite see how to visit a "generic" node in the base visitor - how do I get a RuleNode out of a specific context?

Answer 1

[...] does not produce a visitor with "visitExpr" and I have no idea why
When labelling a parser rule r, no visitR(...) will be generated. Only the visit...() methods of the alternatives will be generated.
So without alt labels:
r
: a
| b
;
// Only 1 method:
// - visitR(...)
With alt labels:
r
: a #altA
| b #altB
;
// Two methods:
// - visitAltA(...)
// - visitAltB(...)
Also, I don't quite see how to visit a "generic" node in the base visitor - how do I get a RuleNode out of a specific context?
You could override the AbstractParseTreeVisitor<T>#visitChildren(...) method to listen to any rule. A quick demo:
public class Main {
public static void main(String[] args) throws Exception {
String source = "require a + b";
TxmlLexer lexer = new TxmlLexer(CharStreams.fromString(source));
TxmlParser parser = new TxmlParser(new CommonTokenStream(lexer));
ParseTree root = parser.program();
new TestTXmlVisitor().visit(root);
}
}
class TestTXmlVisitor extends TxmlBaseVisitor<Object> {
#Override
public Object visitChildren(RuleNode node) {
System.out.println("visited: " + node.getClass().getSimpleName() + " -> " + node.getText());
return super.visitChildren(node);
}
}
will print:
visited: ProgramContext -> requirea+b<EOF>
visited: ConditionContext -> requirea+b
visited: RequireContext -> requirea+b
visited: ValueExpressionContext -> a+b
visited: AddSubContext -> a+b
visited: IdentifierContext -> a
visited: IdentifierContext -> b