list containing generator expression invalid - cmake

Question

cmake_minimum_required(VERSION 3.13)
project(hello)
set(SRCS main.c hello.c )
set(HEADERS hello.h )
add_executable(hello ${SRCS} ${HEADERS})
target_include_directories(hello PRIVATE
"inc1"
"inc2"
)
target_include_directories(hello PRIVATE "headers")
set(var3)
list(APPEND var3 "inc3")
list(APPEND var3 "inc4")
list(APPEND var3 "$<TARGET_PROPERTY:hello,INCLUDE_DIRECTORIES>")
message(STATUS "var3:${var3}")
list(LENGTH var3 list_len1)
message(STATUS "list_len1 :${list_len1}")
#file(GENERATE OUTPUT f.txt CONTENT ${list_len1})
file(GENERATE OUTPUT f.txt CONTENT ${var3})
it displays:
-- var3:inc3;inc4;$<TARGET_PROPERTY:hello,INCLUDE_DIRECTORIES>
-- list_len1 :3
CMake Error at CMakeLists.txt:29 (file):
file Unknown argument to GENERATE subcommand.
the line : file(GENERATE OUTPUT f.txt CONTENT ${var3})
generates the error. why?
we normally have a list of 3 elements, inc3, inc4 concatenated with the generator expression, which is when expanded :
/Users/windev/works/proj/inc1;/Users/windev/works/proj/inc2;/Users/windev/works/proj/headers
so why don't we have inc3,inc4,/Users/windev/works/proj/inc1;/Users/windev/works/proj/inc2;/Users/windev/works/proj/headers
printed in my f.txt
thanks

Answer 1

Specification of file(GENERATE) command
file(GENERATE OUTPUT output-file
<INPUT input-file|CONTENT content>
[CONDITION expression] [TARGET target])
implies, that content is exactly a single argument.
Because your variable var3 contains more than one value, then ${var3} is expanded to more than one value. This is what the error message about.
Proper call to file(GENERATE) would be
file(GENERATE OUTPUT f.txt CONTENT "${var3}")
With that call list elements in the generated file will be separated by a semicolon(;).
If you want space separator between the elements, then you need to join the list elements before generating a file:
string(JOIN " " var3_string ${var3})
file(GENERATE OUTPUT f.txt CONTENT "${var3_string}")
or use $<JOIN> generator expression:
file(GENERATE OUTPUT f.txt CONTENT "$<JOIN:${var3}, >")
The advantage of the latter variant is that it joins content of the generator expression too. (The string command treats the whole generator expression as a single value).