How to locate the default value constraint for a column name - sql

Question

I noticed that some date columns in a database table are giving my Power App a hard time ( patching) when the default value is '0001-01-01' and the no valid date is supplied. Note I can't just set default values in my Power App as the SQL Table is used by other applications.
My current thinking is I change the default value say to '1001-01-01' using TSQL so that I can automate it as much as possible.
Get the (DF_TABLENAME_XXXX) constraint name for the column and say shove it into a variable #mytablename
Drop this constraint name
Recreate the constraint with
ALTER TABLE #MyTable DEFAULT '1001-12-31' FOR #ColumnName
I am struggling with step 1) atm . Also I am happy to adopt a better approach than the one I have outlined.

Answer 1

I wrote this code sometime ago to create a Data Dictionary of sorts. It uses all the sys tables to grab information about the tables in your database. Just change the top line and you should be all set.
USE [INSERT YOUR DATABASE NAME HERE]
GO
SELECT
DB_NAME() AS [DatabaseName]
, OBJECT_SCHEMA_NAME(TBL.[object_id],DB_ID()) AS [Schema]
, TBL.[name] AS [TableName]
, AC.[name] AS [ColumnName]
, UPPER(TY.[name]) AS [DataType]
, AC.[max_length] AS [Length]
, AC.[precision] AS [Precision]
, AC.[scale] AS [Scale]
, AC.[is_nullable] AS [IsNullable]
, ISNULL(SI.is_primary_key,0) AS [IsPrimaryKey]
, SKC.name AS [PrimaryKeyConstarint]
, CASE
WHEN SIC.index_column_id > 0
THEN 1
ELSE 0
END AS [IsIndexed]
, ISNULL(is_included_column, 0) AS [IsIncludedIndex]
, SI.name AS [IndexName]
, OBJECT_NAME(SFC.constraint_object_id) AS [ForeignKeyConstraint]
, OBJECT_SCHEMA_NAME(TBL_PRIM.[object_id],DB_ID()) AS [ParentTableSchema]
, OBJECT_NAME(SFC.referenced_object_id) AS [ParentTableName]
, COL_PRIM.name AS [ParentTableColumnName]
, OBJECT_SCHEMA_NAME(TBL.[object_id],DB_ID()) + '.' + TBL.[name] + '.' + AC.[name]
+ ' = ' + OBJECT_SCHEMA_NAME(TBL_PRIM.[object_id],DB_ID()) + '.'
+ OBJECT_NAME(SFC.referenced_object_id) + '.' + COL_PRIM.name AS [JoinCondition]
, SDC.name AS [DefaultConstraint]
, SDC.[definition] AS [DefaultValue]
, AC.collation_name AS [Collation]
, SEP.value AS [Comments]
FROM [sys].[tables] AS TBL
JOIN [sys].[all_columns] AS AC
ON TBL.[object_id] = AC.[object_id]
JOIN [sys].[types] AS TY
ON AC.[system_type_id] = TY.[system_type_id]
AND AC.[user_type_id] = TY.[user_type_id]
LEFT JOIN [sys].[index_columns] AS SIC
ON sic.[object_id] = TBL.[object_id]
AND AC.column_id = SIC.column_id
LEFT JOIN [sys].[indexes] AS SI
ON SI.[object_id] = TBL.[object_id]
AND SIC.index_id = SI.index_id
LEFT JOIN [sys].[foreign_key_columns] AS SFC
ON SFC.parent_object_id = TBL.[object_id]
AND SFC.parent_column_id = AC.column_id
LEFT JOIN [sys].[key_constraints] AS SKC
ON skc.parent_object_id = TBL.[object_id]
AND SIC.index_column_id = SKC.unique_index_id
LEFT JOIN [sys].[default_constraints] AS SDC
ON SDC.parent_column_id = AC.column_id
LEFT JOIN [sys].[extended_properties] AS SEP
ON SEP.major_id = TBL.[object_id]
AND SEP.minor_id = AC.column_id
LEFT JOIN [sys].[tables] AS TBL_PRIM
ON SFC.referenced_object_id = TBL_PRIM.[object_id]
LEFT JOIN [sys].[columns] AS COL_PRIM
ON SFC.referenced_object_id = COL_PRIM.[object_id]
AND SFC.referenced_column_id = COL_PRIM.column_id

Answer 2

Fill in the question marks in the where clause, and this will give you the name of your default constraint.
SELECT
SchemaName = SCH.[name]
,TableName = TAB.[name]
,ColumnName = COL.[name]
,DefaultConstraint = DFC.[name]
FROM sys.default_constraints AS DFC
JOIN sys.columns AS COL
ON DFC.parent_object_id = COL.[object_id]
AND DFC.parent_column_id = COL.column_id
JOIN sys.tables AS TAB
ON COL.[object_id] = TAB.[object_id]
JOIN SYS.schemas AS SCH
ON TAB.[schema_id] = SCH.[schema_id]
WHERE SCH.[name] = ?
AND TAB.[name] = ?
AND COL.[name] = ?