How to save the configuration on a MDI Forms Dashboard - vb.net

Question

I'm creating a dashboard (in VB.NET) with multiple modules. Every module is a different form with different functions and settings and the user can create how many and how much of these forms he want. My idea is to make possible to save the general configuration of the Dashboard (example: forms opened, position of these etc.) to be able to recall it when the main form is closed and re-opened and obtain the same situation or change between different settings (different user can load it's own custom preset).
I've tried to serialize the list of forms that are opened but serializing MDI child Forms causes trouble.
All the Forms are ok and works with its own settings. I need only the way to implement this kind of "global settings save".
How can I do this in the most elegant way? (it's ok also a rough idea than I can try getting in deep on my own)
Thanks!

Answer 1

To save the position of all opened MDIChild Windows, you can enumerate the collection of Controls of the MDIParent's MdiClient container (the Container that actually parents the MDI Child Windows).
This will give you the correct order in which these Windows are shown.
The Application.OpenForms collection won't, it just enumerates the opened Forms.
You can use the Form.Name as reference and save its Bounds Rectangle.
Here, I'm using the RectangleConverter class to serialize the Forms' Bounds.
▶ Here, I'm serializing just the Form Name and its Bounds. You can of course serialize whatever other properties / values you need.
In that case, you can build a class structure that stores the information and serialize it using a Json or XML Serializer (I suggest the former. IMO, avoid BinaryFormatter).
To also save the Bounds of the MDIParent, add it last to the list, since when you read back the list of Forms, you have to invert the order in which the Forms are created (the last created goes on top).
To recreate the Forms, you can use Activator.CreateInstance, passing the Type of the Form to create.
The file that stores this information is saved in Application.CommonAppDataPath:
Path.Combine(Application.CommonAppDataPath, "FormsLayout.txt")
It points to a ProgramData folder - dedicated to the calling app - of the drive where the System is installed. Your app always has write permissions here.
When the MDI Application is about to close (Form.FormClosing event handler), the SaveWindowsOrder() method is called. It will store the current Order and Bounds of all opened windows, MDIParent included.
When the MDI Parent is about to be shown (Form.Shown event handler), the LoadWindowsOrder() is called, to restore the previous layout.
Add these Imports:
Imports System.Drawing ' If not already defined in the Project's References
Imports System.IO
Imports System.Linq ' If not already defined in the Project's References
Imports System.Reflection
Public methods
Add to the Form, to a Module or, if you prefer, add Shared and use a dedicated helper class.
Public Sub SaveWindowsOrder(filePath As String, mdiPparent As Form)
Dim formsOrder As New List(Of String)
Dim mClient = mdiPparent.Controls.OfType(Of MdiClient).First()
For Each f As Form In mClient.Controls.OfType(Of Form).ToList()
Dim sRect = New RectangleConverter().ConvertToString(f.Bounds)
formsOrder.Add($"{f.Name};{sRect}")
Next
formsOrder.Add($"{mdiPparent.Name};{New RectangleConverter().ConvertToString(mdiPparent.Bounds)}")
File.WriteAllLines(filePath, formsOrder)
End Sub
Public Sub LoadWindowsOrder(filePath As String, parent As Form)
If Not File.Exists(filePath) Then Return
Dim orderList = File.ReadAllLines(filePath).Reverse().ToArray()
Dim appNameSpace = Assembly.GetExecutingAssembly().GetName().Name
Dim parentData = orderList(0).Split(";"c)
parent.Bounds = CType(New RectangleConverter().ConvertFromString(parentData(1)), Rectangle)
For Each formOrder As String In orderList.Skip(1).ToArray()
Dim params = formOrder.Split(";"c)
Dim formName As String = params(0)
Dim formBounds = CType(New RectangleConverter().ConvertFromString(params(1)), Rectangle)
Dim form = CType(Activator.CreateInstance(Type.GetType($"{appNameSpace}.{formName}")), Form)
form.MdiParent = parent
form.Show()
form.Bounds = formBounds
Next
End Sub
Add to the MDIParent Form:
Private Sub MDIParent1_FormClosing(sender As Object, e As FormClosingEventArgs) Handles MyBase.FormClosing
Dim layoutFile = Path.Combine(Application.CommonAppDataPath, "FormsLayout.txt")
SaveWindowsOrder(layoutFile, Me)
End Sub
Private Sub MDIParent1_Shown(sender As Object, e As EventArgs) Handles MyBase.Shown
Dim layoutFile = Path.Combine(Application.CommonAppDataPath, "FormsLayout.txt")
LoadWindowsOrder(layoutFile, Me)
End Sub