Display SQL data in TreeView - vb.net

Question

I am showing data from 1 table from SQL Server 2018 to a TreeView. I can only show the tree up to this point
Private Sub btnPopular_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnPopular.Click
Dim conexaoSQLServer As SqlConnection = Nothing
Dim cmd As SqlCommand
Dim da As New SqlDataAdapter
Dim ds As New DataSet
'DBSQLServer = "SELECT RTRIM(D.DESCRIPCION),RTRIM(P.DESCRIPCION) " +
'"FROM PROVINCIAS AS P INNER JOIN DEPARTAMENTO AS D ON P.IDDEPARTAMENTO=D.IDDEPARTAMENTO"
Dim strCon As String = "Data Source = SOPORTE-ERP\SQLEXPRESS; Initial Catalog = prueba; Integrated Security = True"
'define a consulta para obter as tabelas e suas colunas
Dim sqlConsulta As String = "SELECT RTRIM(D.DESCRIPCION),RTRIM(P.DESCRIPCION) " +
"FROM PROVINCIA AS P INNER JOIN DEPARTAMENTO AS D ON P.IDDEPARTAMENTO=D.IDDEPARTAMENTO"
'define os nodes que iremos usar no treeview
Dim NoRaiz As TreeNode = Nothing
Dim NoPrincipal As TreeNode = Nothing
Dim NoFilho As TreeNode = Nothing
Dim nieto As TreeNode = Nothing
'define algumas constanes e variaveis usadas
Dim nomePrincipal As String = String.Empty
Dim nomeFilho As String = String.Empty
Dim BancoDados As String = DBSQLServer
Try
'define e abre a conexão com o SQL Server
conexaoSQLServer = New SqlConnection(strCon)
conexaoSQLServer.Open()
'atribui o comando usado na conexão
cmd = New SqlCommand(sqlConsulta, conexaoSQLServer)
da.SelectCommand = cmd
'preenche o dataset
da.Fill(ds, "DATOS_SISTEMAS")
tvwDados.Nodes.Clear()
'inclui o node raiz
NoRaiz = tvwDados.Nodes.Add("UBIGEO")
Dim contaTabelas As Integer = 0
For Each row As DataRow In ds.Tables("DATOS_SISTEMAS").Rows
If nomePrincipal <> row(0).ToString Then
NoPrincipal = NoRaiz.Nodes.Add(row(0).ToString)
'imageIndex:=1, selectedImageIndex:=1'
nomePrincipal = row(0).ToString
contaTabelas += 1
End If
NoFilho = NoPrincipal.Nodes.Add(key:="", text:=row(1).ToString)
'nieto = NoPrincipal.Nodes.Add(key:="DISTRITOS", text:=row(2).ToString)
'imageIndex:=2, selectedImageIndex:=2
Next
lblTabelas.Text = contaTabelas.ToString & " Tabelas no arquivo"
tvwDados.Nodes(0).EnsureVisible()
Catch ex As Exception
MessageBox.Show("Erro ao realizar a operação com o arquivo : " & ex.Message)
Exit Sub
Finally
'libera os recursos da conexão usada
conexaoSQLServer.Close()
conexaoSQLServer.Dispose()
conexaoSQLServer = Nothing
End Try
End Sub
And it shows me as follows in the picture
now I want another sub-tree or item to be broken down to me where the districts are shown as follows DEPARTMENT / PROVINCE / DISTRICT

Answer 1

In essence, this is a data querying question.
I use these conceptual tables for my answer. I hope they reflect your actual table structure.
CREATE TABLE DEPARTAMENTO (
IDDEPARTAMENTO CHAR(2) NOT NULL,
DESCRIPCION VARCHAR(50) NOT NULL,
CONSTRAINT PK_DEPARTAMENTO PRIMARY KEY (IDDEPARTAMENTO),
CONSTRAINT UQ_DEPARTAMENTO UNIQUE (DESCRIPCION)
);
CREATE TABLE PROVINCIA (
IDDEPARTAMENTO CHAR(2) NOT NULL,
IDPROVINCIA CHAR(2) NOT NULL,
DESCRIPCION VARCHAR(50) NOT NULL,
CONSTRAINT PK_PROVINCIA PRIMARY KEY (IDDEPARTAMENTO, IDPROVINCIA),
CONSTRAINT UQ_PROVINCIA UNIQUE (IDDEPARTAMENTO, DESCRIPCION),
CONSTRAINT FK_PROVINCIA_DEPARTAMENTO FOREIGN KEY (IDDEPARTAMENTO) REFERENCES DEPARTAMENTO (IDDEPARTAMENTO)
);
CREATE TABLE UBIGEO (
IDUBIGEO CHAR(6) NOT NULL,
IDDEPARTAMENTO CHAR(2) NOT NULL,
IDPROVINCIA CHAR(2) NOT NULL,
DESCRIPCION VARCHAR(50) NOT NULL,
CONSTRAINT PK_UBIGEO PRIMARY KEY (IDUBIGEO),
CONSTRAINT UQ_UBIGEO UNIQUE (IDDEPARTAMENTO, IDPROVINCIA, DESCRIPCION),
CONSTRAINT FK_UBIGEO_PROVINCIA FOREIGN KEY (IDDEPARTAMENTO, IDPROVINCIA) REFERENCES PROVINCIA (IDDEPARTAMENTO, IDPROVINCIA)
);
Next, I would look at the data that is actually required for populating a treeview. Every node refers to a parent node (or a parent node contains several child nodes). I would like to reflect that in the data that I retrieve from the database.
Each of the above three tables holds node data. Instead of using JOINs, I would use UNIONs here, so that each row in the result data represents a single node. Each row should contain at least three fields:
nodeText will contain the node text that is displayed in the treeview's nodes
nodeKey will contain a unique textual key for the node
nodeParentKey will contain the key of the parent node (or an empty string if it has no parent)
So the query that I would execute to retrieve the node data would look something like this:
'define a consulta para obter as tabelas e suas colunas
Dim sqlConsulta As String = "
SELECT
D.DESCRIPCION AS nodeText,
'DEPA' + D.IDDEPARTAMENTO AS nodeKey,
'' AS nodeParentKey
FROM
DEPARTAMENTO AS D
UNION ALL
SELECT
P.DESCRIPCION AS nodeText,
'PROV' + P.IDDEPARTAMENTO + P.IDPROVINCIA AS nodeKey,
'DEPA' + P.IDDEPARTAMENTO AS nodeParentKey
FROM
PROVINCIA AS P
UNION ALL
SELECT
U.DESCRIPCION AS nodeText,
'DIST' + U.IDUBIGEO AS nodeKey,
'PROV' + U.IDDEPARTAMENTO + U.IDPROVINCIA AS nodeParentKey
FROM
UBIGEO AS U
"
I would rewrite the loop that processes your retrieved data and actually convert it to two loops.
The first loop processes the retrieved data and creates the TreeNode objects. But instead of immediately putting them in a Nodes collection in the tvwDados treeview, I would put them in a helper dictionary. Additionally, I would store the node's key in another helper dictionary as well. These helper dictionaries will be used in the second loop.
The second loop actually populates the tvwDados treeview from the nodes dictionary and add the node either to the tvwDados.Nodes collection or a parent node's Nodes collection, which depends if a parent key can be found in the nodeParents dictionary.
My data processing code would look something like this:
'Helper dictionaries
Dim nodes As New Dictionary(Of String, TreeNode) 'Holds the nodes based on their key values
Dim nodeParents As New Dictionary(Of String, String) 'Holds the parent keys of child nodes
'Create nodes from data
For Each row As DataRow In ds.Tables("DATOS_SISTEMAS").Rows
Dim nodeText As String = row.Field(Of String)("nodeText")
Dim nodeKey As String = row.Field(Of String)("nodeKey")
Dim nodeParentKey As String = row.Field(Of String)("nodeParentKey")
nodes.Add(nodeKey, New TreeNode(nodeText))
If Not String.IsNullOrEmpty(nodeParentKey) Then
nodeParents.Add(nodeKey, nodeParentKey)
End If
Next
'Add nodes to treeview (and resolve parents)
For Each kvp In nodes
Dim node As TreeNode = kvp.Value
Dim nodeKey As String = kvp.Key
Dim nodeParentKey As String = Nothing
If nodeParents.TryGetValue(nodeKey, nodeParentKey) Then
'Child node
Dim parentNode As TreeNode = nodes(nodeParentKey)
parentNode.Nodes.Add(node)
Else
'Root node
tvwDados.Nodes.Add(node)
End If
Next
I am not sure about the purpose of your contraTabelas integer and your NoRaiz, NoPrincipal and NoFilho tree nodes. For the sake of clarity I omitted them from my code. I assume that you will be able to include them in the processing logic yourself if you still need them.
Edit:
If you want to do special things when double clicking a district node, you can pass additional data in a node's Tag property.
In the above code, change this line:
nodes.Add(nodeKey, New TreeNode(nodeText))
to this:
Dim node As New TreeNode(nodeText)
node.Tag = nodeKey
nodes.Add(nodeKey, node)
Next, you can implement the tree view's NodeMouseDoubleClick event handler. It could look something like this:
Private Sub tvwDados_NodeMouseDoubleClick(sender As Object, e As TreeNodeMouseClickEventArgs) Handles tvwDados.NodeMouseDoubleClick
Dim nodeKey As String = TryCast(e.Node.Tag, String)
If nodeKey IsNot Nothing AndAlso nodeKey.StartsWith("DIST") Then
'You have double clicked a district node
Dim IDDISTRITO As Integer = Integer.Parse(nodeKey.Substring(4))
'Do something with the district id here
'...
End If
End Sub
If you need help with additional subjects, just feel free to post an entirely new question here on StackOverflow.
Edit:
I have updated my answer based on new information. I have made changes to the conceptual table structure and the SQL query in the sqlConsulta variable. As far as I can determine, it should not produce duplicate key errors anymore.
I think that the duplicate key errors came from the province nodes. So for the province nodes, I included both the department ID and the province ID in the node key.

Answer 2

the structure of my database is the same as what you are proposing, executing the query with a small change shows me as follows.
SELECT D.DESCRIPCION AS nodetext,CAST(D.IDDEPARTAMENTO AS VARCHAR) AS nodeKey,'' AS nodeParentKey
FROM DEPARTAMENTO AS D UNION ALL
SELECT P.DESCRIPCION AS nodeText,CAST(P.IDPROVINCIA AS VARCHAR) AS nodeKey,CAST(P.IDDEPARTAMENTO AS VARCHAR) AS nodeParentKey
FROM PROVINCIA AS P UNION ALL
SELECT U.DESCRIPCION AS nodeText,CAST(U.IDUBIGEO AS VARCHAR) AS nodeKey,CAST(U.IDPROVINCIA AS VARCHAR) AS nodeParentKey
FROM ubigeo AS U SELECT * FROM ubigeo
UBIGEO IS A DISTRICT
AND IT SHOWS SO
when executing the code that you published it shows me this error message
Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
Dim conexaoSQLServer As SqlConnection = Nothing
Dim cmd As SqlCommand
Dim da As New SqlDataAdapter
Dim ds As New DataSet
DBSQLServer = "prueba"
Dim strCon As String = "Data Source = DESKTOP-2IM88ST\SQLEXPRESS; Initial Catalog = " & DBSQLServer & "; Integrated Security = True"
'define a consulta para obter as tabelas e suas colunas
Dim sqlConsulta As String = "SELECT D.DESCRIPCION AS nodeText,CAST(D.IDDEPARTAMENTO AS VARCHAR) AS nodeKey,'' AS nodeParentKey FROM DEPARTAMENTO AS D UNION ALL " +
"SELECT P.DESCRIPCION AS nodeText,CAST(P.IDPROVINCIA AS VARCHAR) AS nodeKey,CAST(P.IDDEPARTAMENTO AS VARCHAR) AS nodeParentKey FROM PROVINCIA AS P UNION ALL " +
"SELECT U.DESCRIPCION AS nodeText,CAST(U.IDUBIGEO AS VARCHAR) AS nodeKey,CAST(U.IDPROVINCIA AS VARCHAR) AS nodeParentKey FROM ubigeo AS U"
Try
'define e abre a conexão com o SQL Server
conexaoSQLServer = New SqlConnection(strCon)
conexaoSQLServer.Open()
'atribui o comando usado na conexão
cmd = New SqlCommand(sqlConsulta, conexaoSQLServer)
da.SelectCommand = cmd
'preenche o dataset
da.Fill(ds, "DATOS_SISTEMAS")
'Helper dictionaries
Dim nodes As New Dictionary(Of String, TreeNode) 'Holds the nodes based on their key values
Dim nodeParents As New Dictionary(Of String, String) 'Holds the parent keys of child nodes
'Create nodes from data
TreeView1.Nodes.Clear()
For Each row As DataRow In ds.Tables("DATOS_SISTEMAS").Rows
Dim nodeText As String = row.Field(Of String)("nodeText")
Dim nodeKey As String = row.Field(Of String)("nodeKey")
Dim nodeParentKey As String = row.Field(Of String)("nodeParentKey")
nodes.Add(nodeKey, New TreeNode(nodeText))
If Not String.IsNullOrEmpty(nodeParentKey) Then
nodeParents.Add(nodeKey, nodeParentKey)
End If
Next
'Add nodes to treeview (and resolve parents)
For Each kvp In nodes
Dim node As TreeNode = kvp.Value
Dim nodeKey As String = kvp.Key
Dim nodeParentKey As String = Nothing
If nodeParents.TryGetValue(nodeKey, nodeParentKey) Then
'Child node
Dim parentNode As TreeNode = nodes(nodeParentKey)
parentNode.Nodes.Add(node)
Else
'Root node
TreeView1.Nodes.Add(node)
End If
Next
Catch ex As Exception
MessageBox.Show("Erro ao realizar a operação com o arquivo : " & ex.Message)
Exit Sub
Finally
'libera os recursos da conexão usada
conexaoSQLServer.Close()
conexaoSQLServer.Dispose()
conexaoSQLServer = Nothing
End Try
End Sub
End Class
error when performing this operation: an element with the same key has already been added

Answer 3

Bart Hofland,
the query to verify, it shows me this information in the new database.
this is the ubigeo or district table