Thinkscript Probabilty Statistics Study- Need help finishing - stock

Question

I'm trying to figure the probability that if a stock moves .05 up at the open, what are the chances it will move .50 up? Running into a few hiccups.
This idea comes from a forex trader, "TheRumpledOne." He calls it the “Buyzone.” Check him out if you don't know of him. Think of it as a probability based opening range.
Once you load up the code you can see the numbers should not be more than "barsago" length.
EDIT: figured it out. Added "crosses above" to the code. Although there must be a better, “cleaner” way? Also added "...var and..." to this portion of code which idk if it's really needed.
def countsells = Sum( var and var1, barsago);
EDIT 2:
This is my current issue.
Something else is still off. The numbers don't seem right. Now they seem low. I would expect some stocks to hit open + .50 more than 70% of the time but this indicator says differently.
# (Probabilty of XYZ FROM THE LAST / PAST XYZ BARS )
# Original/base code By XeoNoX via Usethinkscript.com
# Idea by TheRumpledOne
# By Prison Mike
input barsago = 100;
input buy= .05;
def buyzone= (open + buy);
def var = close crosses above buyzone;
def count = Sum(var, barsago);
AddLabel (yes, "COUNT " + (count) );
def pct= round(count/barsago)*100;
AddLabel (yes, "BuyZone " + (pct) );
input Sell= .50;
def sellzone= (open + sell);
def var1 =close crosses above sellzone;
def countsells = Sum(var and var1, barsago);
AddLabel (yes, "COUNT " + (countsells) );
def pct2=round (countsells/barsago)*100;
AddLabel (yes, "SellZone " + (pct2) );

Answer 1

A modification: it counts how many bars are in the displayed chart (note: TheRumpledOne's algorithm was designed for intraday trading). It places an orange up-arrow on the price chart wherever the open has gone up by 5 cents; and it places a green arrow wherever the price went up 50 cents. It then shows labels with the counts, percents, and the number of bars (highestBar value) that it used for calculating the percent values.
And, I agree: on an AAPL chart, counting approximately 360 15-minute bars, I got a little over 30% that went to 5 cents, and only about 3% that went up 50 cents. That's off the total number of bars; however, when I added the part to calculate the percent of sell count only, I still only got about 8%. Not anywhere near the suggested numbers in TheRumpledOne's Stockfetcher post.
Note: the chart I was using to test included out-of-hours bars. Perhaps if I excluded out-of-hours, the numbers would look better? Considering where I got arrows, I don't think so...
Here's the modified script:
#hint: from SO: https://stackoverflow.com/q/66232117/1107226\nThinkscript Probabilty Statistics Study- Need help finishing
def highestBar = HighestAll(BarNumber());
### buy zone ###
input buy = .05;
def buyzone = (open + buy);
plot hitBuyZone = close >= buyzone;
hitBuyZone.SetPaintingStrategy(PaintingStrategy.BOOLEAN_ARROW_UP);
hitBuyZone.setDefaultColor( Color.ORANGE );
def count = if hitBuyZone then count[1] + 1 else count[1];
AddLabel (yes, " BUY COUNT: " + count + " ", Color.YELLOW );
def pct = Round(count / highestBar) * 100;
AddLabel (yes, " BuyZone %: " + (pct) + " ", Color.YELLOW );
### sell zone ###
input Sell = .50;
def sellzone = (open + Sell);
plot hitSellZone = close >= sellzone;
hitSellZone.SetPaintingStrategy(PaintingStrategy.BOOLEAN_ARROW_DOWN);
hitSellZone.SetDefaultColor( Color.GREEN );
def countsells = if hitSellZone then countsells[1] + 1 else countsells[1];
AddLabel (yes, " SELL COUNT: " + (countsells) + " ", Color.YELLOW );
def pct2 = Round (countsells / highestBar) * 100;
AddLabel (yes, " SellZone %: " + (pct2) + " ", Color.YELLOW );
### percent of buy count that made it to the full buyzone cents ###
def pctOfBuyCount = Round (countsells / count) * 100;
AddLabel (yes, " Buy Count % of Sell Count: " + (pctOfBuyCount) + " ", Color.YELLOW );
### show bar count ###
AddLabel(BarNumber() == highestBar, " Bars Counted for %: " + BarNumber() + " ", Color.ORANGE);