Any function in DMS3.0 or later that runs in the background and allow user interaction (like FloatingModelessDialog) - dm-script

Question

In DMS3.42 or later, I am wondering if we have a function that the user is allowed to select an image to operate. Basically, the function needs to run in the background and allows user interaction, something like "FloatingModelessDialog" in the previous version (it seems "FloatingModelessDialog" is not supported in DMS3.0).
Thank you!

Answer 1

FloatingModelessDialog is still supported in GMS 3:
// $BACKGROUND$
number sem = NewSemaphore()
FloatingModelessDialog("Message", "YES", sem )
Result("\n Do continue stuff...")
// hold and wait for the dialog
number OK
Try { GrabSemaphore(sem); OK = 1; }
catch { OK = 0; break; }
Result("\n Button pressed:" + OK )
However, this is only a workaround solution and requires the script to be executed on a background thread (or GMS appears to be frozen.)
A more complete approach would be to create a dialog and have its buttons drive the actions, like in the example below:
class MyActionDialog : UIFrame{
void Launch( object self ){
// Build dialog
TagGroup DLGtgs, DLGItems
DLGtgs = DLGCreateDialog( "My Dialog", DLGItems )
TagGroup Button1 = DLGCreatePushButton( "Act on front image", "OnButtonAct" )
TagGroup Button2 = DLGCreatePushButton( "Close", "OnButtonClose" )
DLGItems.DLGAddElement( Button1 )
DLGItems.DLGAddElement( Button2 )
DLGtgs.DLGTableLayout( 2, 1, 0 )
// Create and display the modeless Dialog
self.init( DLGtgs )
self.Display( "My Dialog" )
}
void OnButtonAct( object self ){
image front
if ( !GetFrontImage(front) )
Result( "\n Please select an image first." )
else
Result("\n Acting on image [" + front.ImageGetLabel() + "]....")
}
void OnButtonClose( object self ){
Result( "\n Closing dialog actions." )
self.close()
}
}
Alloc(MyActionDialog).Launch()